Nesesito hacer un explorador de windows para abrir un archivo.

[gndark]

Hola:

Tengo un problema, estoy haciendo una aplicacion en acces para crear copias de seguridad y nesesito una forma para crear una formulario para que me de la ruta y el nombre de archivos por el explorador ( es decir asi como cuando en word, o excel se da archivo-abrir), o aunque sea una forma de obtener algo como la herramienta Cuadro de lista de archivos de Visual Basic.

[kortiz]

Usa el CommoDialog, con este podes abrir, guardar, ver impresoras, paleta de colores, etc.

[gndark]

Oye gracias, pero al intentar usar esta herramienta en acces me pide un licencia, imagino que esta licencia vendra al instalar visual basic pero es que es para la empresa en que trabajo y aqui me toca programar todo bajo acces y no tienen licencia para usar visual studio,¿ Sabes alguna forma de conseguir esta licencia si instalar visual estudio?, o que dias vi en un foro un codigo para abrir un explorador de directorios, pero solo muestra el valor del directorio, y sacaban este directorio con solo codigo (si quieres te lo paso), te agradezco tu ayduda pues es praticamente lo unico que me falta para terminar mi aplicacion..

[LeandroA]

no te vallas por las nuves, es mas facil con las apis que intentar conseguir licencias, pones esto en un formulario y adecualo a Access

Private Declare Function GetOpenFileName Lib "comdlg32.dll" Alias "GetOpenFileNameA" (pOpenfilename As OPENFILENAME) As Long
Private Type OPENFILENAME
lStructSize As Long
hwndOwner As Long
hInstance As Long
lpstrFilter As String
lpstrCustomFilter As String
nMaxCustFilter As Long
nFilterIndex As Long
lpstrFile As String
nMaxFile As Long
lpstrFileTitle As String
nMaxFileTitle As Long
lpstrInitialDir As String
lpstrTitle As String
flags As Long
nFileOffset As Integer
nFileExtension As Integer
lpstrDefExt As String
lCustData As Long
lpfnHook As Long
lpTemplateName As String
End Type
Private Sub Form_Load()
'KPD-Team 1998
'URL: http://www.allapi.net/
'E-Mail: [email protected]
Dim OFName As OPENFILENAME
OFName.lStructSize = Len(OFName)
'Set the parent window
OFName.hwndOwner = Me.hWnd
'Set the application's instance
OFName.hInstance = App.hInstance
'Select a filter
OFName.lpstrFilter = "Text Files (*.txt)" + Chr$(0) + "*.txt" + Chr$(0) + "All Files (*.*)" + Chr$(0) + "*.*" + Chr$(0)
'create a buffer for the file
OFName.lpstrFile = Space$(254)
'set the maximum length of a returned file
OFName.nMaxFile = 255
'Create a buffer for the file title
OFName.lpstrFileTitle = Space$(254)
'Set the maximum length of a returned file title
OFName.nMaxFileTitle = 255
'Set the initial directory
OFName.lpstrInitialDir = "C:\"
'Set the title
OFName.lpstrTitle = "Open File - KPD-Team 1998"
'No flags
OFName.flags = 0

'Show the 'Open File'-dialog
If GetOpenFileName(OFName) Then
MsgBox "File to Open: " + Trim$(OFName.lpstrFile)
Else
MsgBox "Cancel was pressed"
End If
End Sub

[gndark]

Oye muchas gracias que Dios te bendiga, de verdad que este foro es fabuloso. Me sirvio de maravilla