[SOLUCIONADO] seleccionar y almacenar ruta

[eatornini]

Amigos, este es mi primer tema, les cuento estoy diseñando un programa. La idea es poder abrir un .exe y almacenar la ruta. Para no tener que buscar el .exe cada ves que se abre el programa.

Tengo este código que funciona bien, hace lo que quiero, pero el problema es que ya almacenada la ruta, sigue abriendo la opción para seleccionar el .exe. Como hago para que no aparezca más, después de almacenar la ruta?

Código

Código:

Private Sub Command1_Click()
Dim Respuesta

'Verificar si existe
If Dir("C:\Program Files\KONAMI\Pro Evolution Soccer 6\PES6.exe", vbArchive) = vbNullString Then



'Si el usuario elige "Si", con el "CommonDialog" usamos "CommonDialog1.ShowOpen" para que el usuario busque el ejecutable
    If Respuesta = vbNullString Then

        CommonDialog1.Filter = "Archivos Ejecutables (*.exe)|*.exe"
        CommonDialog1.ShowOpen

'si el usuario selecciona cancelar que salga del sub
        If CommonDialog1.FileName = "" Then Exit Sub

'Si selecciona un ejecutable que lo abra
        Shell CommonDialog1.FileName, vbNormalFocus
        
    End If
Else
'En caso de que en la comprobación si exista el ejecutable que lo abra.
    Shell "C:\Windows\notepad.exe", vbNormalFocus
End If

Open "C:\RutaApp.txt" For Output As #1
      Print #1, CommonDialog1.FileName
Close #1

Me.WindowState = 1
End Sub

Muchas gracias amigos

[pkj]

Creo que esto es lo que pides:

Código vb:

Private Sub Command1_Click()
 
Static Respuesta as string ' creamos una variable que no se pierde
' NOTA; esta variable la deberias hacer global y cargarla con el contenido
' del fichero rutaapp.txt antes de entrar en esta sub.
' de todas formas asi sirve.
 
 
'Verificar si existe
' si la variable no se ha cargado la cargamos
if respuesta="" then respuesta="C:\Program Files\KONAMI\Pro Evolution Soccer 6\PES6.exe"
' y si no es valida pedimos la nueva ruta
If Dir(respuesta, vbArchive) = vbNullString Then
 
 
 
'Si el usuario elige "Si", con el "CommonDialog" usamos "CommonDialog1.ShowOpen" para que el usuario busque el ejecutable
    If Respuesta = vbNullString Then
 
        CommonDialog1.Filter = "Archivos Ejecutables (*.exe)|*.exe"
        CommonDialog1.ShowOpen
 
'si el usuario selecciona cancelar que salga del sub
        If CommonDialog1.FileName = "" Then Exit Sub
 
'Si selecciona un ejecutable que lo abra
        Shell CommonDialog1.FileName, vbNormalFocus
 
' Y ESTO SOLO SE GUARDA AQUI, SI LO GUARDAS DONDE ESTABA
' SE GUARDA SIEMPRE AUNQUE LA RUTA QUE CONTIENE YA SEA VALIDA
Open "C:\RutaApp.txt" For Output As #1
      Print #1, CommonDialog1.FileName
Close #1
 
        
    End If
 
Else
'En caso de que en la comprobación si exista el ejecutable que lo abra.
    Shell respuesta, vbNormalFocus
End If
 
 
Me.WindowState = 1
End Sub
 

[eatornini]

Muchas gracias por la respuesta.
Amigo, lo coloque tal cual, y no hace nada, solo minimiza, pero no da la opción de encontrar el .exe

[pkj]

Es que no he probado el codigo. Te sobra una comparacion y no habiamos cargado Respuesta con el camino al fichero.
Esto si funciona:

Código vb:

Private Sub Command1_Click()
 
 
 
Static Respuesta As String ' creamos una variable que no se pierde
 
' NOTA; esta variable la deberias hacer global y cargarla con el contenido
 
' del fichero rutaapp.txt antes de entrar en esta sub.
 
' de todas formas asi sirve.
 
 
 
 
 
'Verificar si existe
 
' si la variable no se ha cargado la cargamos
 
If Respuesta = "" Then Respuesta = "C:\Program Files\KONAMI\Pro Evolution Soccer 6\PES6.exe"
 
' y si no es valida pedimos la nueva ruta
 
If Dir(Respuesta, vbArchive) = vbNullString Then
 
 
        CommonDialog1.Filter = "Archivos Ejecutables (*.exe)|*.exe"
 
        CommonDialog1.ShowOpen
 
 
 
'si el usuario selecciona cancelar que salga del sub
 
        If CommonDialog1.FileName = "" Then Exit Sub
 
        Respuesta = CommonDialog1.FileName
    
 
' Y ESTO SOLO SE GUARDA AQUI, SI LO GUARDAS DONDE ESTABA
 
' SE GUARDA SIEMPRE AUNQUE LA RUTA QUE CONTIENE YA SEA VALIDA
 
      Open "C:\RutaApp.txt" For Output As #1
 
         Print #1, CommonDialog1.FileName
 
      Close #1
'Si selecciona un ejecutable que lo abra
 
        Shell CommonDialog1.FileName, vbNormalFocus
 
 
 
Else
 
'En caso de que en la comprobación si exista el ejecutable que lo abra.
 
    Shell Respuesta, vbNormalFocus
 
End If
 
 
 
 
 
Me.WindowState = 1
 
End Sub
 

De todas formas tendras que cargar con el contenido del fichero RutaApp la variable Respuesta (cambiale el nombre) al comienzo de la sub o al arrancar el programa porque si no te lo va a preguntar siempre que lo ejecutes.

Saludos

[eatornini]

Gracias amigo, no entendí lo ultimo, la verdad es que llevo apenas 1 semana en vb6 y no tengo mucho conocimiento.

ahora me funciona, se almacena la ruta, pero al cerrar y abrir la aplicación, vuelve a pedir la ruta :S

aquí dejo el proyecto, amigo podrías revisarlo por favor

https://www.dropbox.com/s/adbbntscbkpgxzs/Ayuda.rar

saludos y gracias

[pkj]

Eso era lo que yo te decia que te pasaria.

Y esta es basicamente la solucion que te daba.

Código vb:

Private Sub Command1_Click()
 
Static Respuesta As String ' creamos una variable que no se pierde
 
If Respuesta = "" Then
  If Dir("C:\RutaApp.txt", vbArchive) <> vbNullString Then
    Open "C:\RutaApp.txt" For Input As #1
      Line Input #1, Respuesta
    Close #1
  Else
    Respuesta = "C:\Program Files\KONAMI\Pro Evolution Soccer 6\PES6.exe"
  End If
End If
 
If Dir(Respuesta, vbArchive) = vbNullString Then
 
        CommonDialog1.Filter = "Archivos Ejecutables (*.exe)|*.exe"
 
        CommonDialog1.ShowOpen
 
'si el usuario selecciona cancelar que salga del sub
 
        If CommonDialog1.FileName = "" Then Exit Sub
 
        Respuesta = CommonDialog1.FileName
    
        Open "C:\RutaApp.txt" For Output As #1
 
          Print #1, CommonDialog1.FileName
 
        Close #1
 
'Si selecciona un ejecutable que lo abra
 
        Shell CommonDialog1.FileName, vbNormalFocus
 
Else
 
'En caso de que en la comprobación si exista el ejecutable que lo abra.
 
    Shell Respuesta, vbNormalFocus
 
End If
 
Me.WindowState = 1
 
End Sub
 

Se puede hacer de muchas formas y esta no es la mejor, pero tendras que aprender equivocandote como todos.

[eatornini]

Me funciona bien, salvo un pequeño error, al volver abrir el programa y colocar que vuelva a ejecutar el .exe, lo hace, pero en forma independiente. y el programa lanzar error, señalando que faltan algunos archivos para iniciarse :S

esto me tiene de cabeza :(

[eatornini]

Iniciado por eatornini

Me funciona bien, salvo un pequeño error, al volver abrir el programa y colocar que vuelva a ejecutar el .exe, lo hace, pero en forma independiente. y el programa lanzar error, señalando que faltan algunos archivos para iniciarse :S es como si lo ejecutara de forma distinta, a como lo hace normalmente

esto me tiene de cabeza :(

Lo que me llama la atención, es que al eliminar el archivo rutaapp del disco local c, me sigue abriendo el .exe, pero me lanza error :(

[pkj]

No se, a mi me funciona perfectamente.
Como no tengo el juego, cuando no existe el fichero rutaapp.txt me hace buscar el exe y guarda la ruta.
La siguiente vez arranca sin problemas (otro exe, claro, el juego no lo tengo).
Si es el juego el que te da error prueba este codigo.
Hacemos que el programa cambie el directorio de trabajo al del juego a ver si asi pita.

Código vb:

Private Sub Command1_Click()
 
Static Respuesta As String ' creamos una variable que no se pierde
 
If Respuesta = "" Then
  If Dir("C:\RutaApp.txt", vbArchive) <> vbNullString Then
    Open "C:\RutaApp.txt" For Input As #1
      Line Input #1, Respuesta
    Close #1
  Else
    Respuesta = "C:\Program Files\KONAMI\Pro Evolution Soccer 6\PES6.exe"
  End If
End If
 
If Dir(Respuesta, vbArchive) = vbNullString Then
 
        CommonDialog1.Filter = "Archivos Ejecutables (*.exe)|*.exe"
 
        CommonDialog1.ShowOpen
 
'si el usuario selecciona cancelar que salga del sub
 
        If CommonDialog1.FileName = "" Then Exit Sub
 
        Respuesta = CommonDialog1.FileName
    
        Open "C:\RutaApp.txt" For Output As #1
 
          Print #1, CommonDialog1.FileName
 
        Close #1
 
 
End If
 
 
ChDir Left$(Respuesta, Len(Respuesta) - Len(Dir$(Respuesta)))
 
Shell Respuesta, vbNormalFocus
 
 
Me.WindowState = 1
 
End Sub
 

[eatornini]

te pasaste :D ahora si que si amigo, un millon de gracias por tu ayuda, quedo perfecto, marco como solucionado :D

gracias (Y)