Obtener datos de un archivo de texto

[llovio]

Quisiera saber si alguien dispone de codigo en visual basic 6.0 para poder acceder a un archivo de texto con numeros en filas y columnas (es un documento de excell salvado en formato de texto separado por tabuladores) que me lo proporciona un dispositivo al que no se puede cambiar este formato.

Se puede hacer manualmente pero necesito automatizar este proceso ya que hay que abrir muchos archivos de texto y lleva mucho tiempo.

Me gustaria poder acceder mediante el numero de fila y columna a los valores deseados del archivo, pero no se si sera posible. Tampoco importa que descargue todos los valores pero individualizados.



Muchas Gracias

[pkj]

No lo he probado, pero creo que debería funcionar:

Código vb:

Function LeerRegistroTxt(ByVal NombreArchivo As String, ByVal Línea As Long, Optional ByVal Columna As Long) As String
  Dim NumFichero As Integer
  Dim Linea As String
  On Error GoTo ErrorLectura
  Open NombreArchivo For Input As #NumFichero
  Do Until EOF(NumFichero)
    If Linea = 0 Then Exit Do
    Line Input #NumFichero, Linea
    Linea = Linea - 1
  Loop
  If Columna > 0 Then
    Dim Matriz() As String
    Matriz = Split(Linea, vbTab)
    Linea = Matriz(Columna - 1)
  End If
  LeerRegistroTxt = Linea
  Exit Function
 
ErrorLectura:
  MsgBox Err.Description
  Err.Clear
  
End Function
 

Solo tienes que ir llamando a la función con los parámetros adecuados. Para eso lo más básico sería un form con 4 textbox, y un boton con el código:

Text4.Text = LeerRegistroTxt Text1, Text2, Text3

Donde text1 contendría el camino y nombre del fichero a leer y text2 y text3 la línea y columna. El valor buscado se mostrará como ya imaginarás en el text4.

Linea y Columna deben ser valores mayores que cero.

La columna la pongo como opcional y si no la incluyes debería devolver toda la línea

El camino al fichero de texto lo puedes evitar si copias el programa que has creado en la carpeta de los textos y ahí lo ejecutas. De ese modo solo tienes que poner los nombres de los textos en el text1.

Coméntame si falla el invento.

Saludos

[llovio]

En primer lugar, muchas gracias PKJ por molestarte. De momento me da varios errores que quizas me ayudes a solucionar, pero parece que tiene buena pinta.

Empece cambiando el nombre de una de las variables que defines en la funcion "Línea", supongo que sera un error al intentar acentuar la palabra "linea" (por cierto, perdon porque yo no acentuo ninguna porque no se que problema tengo en el teclado que me sale algo as¨¨i).

Al definir esta variable con el nombre "linea" me da el error: "declaracion duplicada en el alcance actual" ya que en la linea 3 del programa se vuelve a definir la variable "linea" como string.

Si la cambio en la funcion por el nuevo nombre de fila1, me surge otro error:

"nombre o numero de archivo incorrecto"

Y por mas que modifico "#NumFichero" en la linea 5 del programa "Open NombreArchivo For Input As #NumFichero" me sigue dando el mismo error.

Muchas gracias y un saludo.

[pkj]

Tienes toda la razón. He metido un acento y repetido el nombre a 2 variables. Que borrico
Aquí te lo dejo revisado. Comentame si funciona, ya que como no tengo ficheros de texto de ese tipo no puedo probarlo.

Código vb:

Function LeerRegistroTxt(ByVal NombreArchivo As String, ByVal numLinea As Long, Optional ByVal numColumna As Long) As String
  Dim NumFichero As Integer
  Dim Linea As String
  On Error GoTo ErrorLectura
  Open NombreArchivo For Input As #NumFichero
  Do Until EOF(NumFichero)
    If numLinea = 0 Then Exit Do
    Line Input #NumFichero, Linea
    numLinea = numLinea - 1
  Loop
  Close #NumFichero
 
  If numColumna > 0 Then
    Dim Matriz() As String
    Matriz = Split(Linea, vbTab)
    Linea = Matriz(numColumna - 1)
  End If
  LeerRegistroTxt = Linea
  Exit Function
 
ErrorLectura:
  MsgBox Err.Description
  Err.Clear
  
End Function
 

Saludos

PD: Tampoco cerraba el fichero despues de abrirlo. Estoy pasmao

[llovio]

Sigue dando el error "Nombre o numero de archivo incorrecto". La ruta que le pongo en el textbox supongo que esta bien. La copio en el portapapeles desde las propiedades del archivo:

C:\Documents and Settings\Escritorio\libro1.txt

Supongo PKJ que la prueba se puede hacer con cualquier archivo de texto. Con el excell introducimos por ejemplo nueve numeros en tres filas y tres columnas salvamos como archivo de texto separado por tabuladores y ya tenemos el archivo para probar.

[pkj]

Perdona, he visto otro fallo. No asigno valor a numfichero, y seguramente cuando vale 0 no es apto para usar como lo uso.
Añade esta línea antes del Open

NumFichero=Freefile

Puede que sea la solución.

Mientras tanto voy a ver si creo un texto de esos.

[pkj]

Ya lo he probado y con la línea que te he comentado se soluciona el problema.

[llovio]

Eureka. Ya funciona bien. No sabes como te lo agradezco PKJ. Aqui dejo el codigo que funciona. He añadido un bucle para leer todos los datos del archivo de forma, creo que mas rapida, que a traves del textbox.

De nuevo mil gracias PKJ


Function LeerRegistroTxt(ByVal NombreArchivo As String, ByVal numLinea As Long, Optional ByVal numColumna As Long) As String
Dim NumFichero As Integer
Dim Linea As String
On Error GoTo ErrorLectura
NumFichero = FreeFile
Open NombreArchivo For Input As #NumFichero
Do Until EOF(NumFichero)
If numLinea = 0 Then Exit Do
Line Input #NumFichero, Linea
numLinea = numLinea - 1
Loop
Close #NumFichero

If numColumna > 0 Then
Dim Matriz() As String
Matriz = Split(Linea, vbTab)
Linea = Matriz(numColumna - 1)
End If
LeerRegistroTxt = Linea
Exit Function

ErrorLectura:
MsgBox Err.Description
Err.Clear

End Function

dim resultado(1000,1000)

Private Sub Command1_Click()
For i = 1 To 3
For j = 1 To 3
resultado(i,j) = LeerRegistroTxt(Form1.Text1, i, j)
Debug.Print resultado
Next
Next
End Sub

[pkj]

En ese caso deberías modificar el código para leer todos los registros de una vez, ya que la función está diseñada para leer registros sueltos y aumenta mucho el trabajo si lo que quieres es cargar todo.
Puedes hacerlo todo en el propio command1:

Código vb:

Dim NumFichero As Integer
Dim Linea As String
Dim Matriz() As String
On Error GoTo ErrorLectura
NumFichero = FreeFile
Open Text1.Text For Input As #NumFichero
Do Until EOF(NumFichero)
  Line Input #NumFichero, Linea
  Matriz=Split(Linea,vbTab)
  i=i+1
  For j = 0 To 2
     resultado(i,j+1)=Matriz(j)
  Next j
Loop
Close #NumFichero
 
Exit Sub
 
ErrorLectura:
MsgBox Err.Description
Err.Clear
 

Algo así...

En este caso es innecesario dado que solo hay 3 líneas y 3 datos, pero si automatizas el tema para manipular muchos ficheros o usas la función con ficheros con muchos datos, el proceso se comenzará a hacer pesado.

[llovio]

Pues fenomenal PKJ, como me lo sigas mejorando me voy a quedar con las ganas de mandarte un jamon...

Otras mil Gracias y Salud.