Añadir una fila a un datagrid

[franko1809]

• Cargo los registros de una tabla en un datagrid con un recordset y quiero agregarle mas filas al datagrid mediante otro recordset pero este es temporal, es decir existen 2 recordset
• Con el command1 cargo los registros del tabla al datagrid1 y quiero que con el command2 se agrege una o mas filas con otro recordset pero en la grilla deben mantenerse los registros de l primero.

En resumen como le sumo los datos del RsTemporal al RsDetalle algo asi
cargo la grilla asi :
Set DataGrid1.DataSource = rsDetalle
y quiero agregarle filas a la grilla con este otro recordset :
Set DataGrid1.DataSource = RsTemporal

De todos modos dejo el codigo:

Código:

Dim RsTemporal As New Recordset
Dim rsDetalle As New Recordset

Sub ActivaTemporal()
    'Creando recordset temporal
    RsTemporal.CursorType = adOpenStatic
    RsTemporal.Fields.Append "CodProd", adVarChar, 4, adFldIsNullable
    RsTemporal.Fields.Append "NomProd", adVarChar, 250, adFldIsNullable
    RsTemporal.Fields.Append "PrecioVenta", adDouble, 10.2, adFldIsNullable
    RsTemporal.Open
    'Cargamos el datagrid
    Set DataGrid1.DataSource = RsTemporal
End Sub

Sub GrabaTemporal()
  RsTemporal.AddNew
  RsTemporal.Fields(0) = Text1.Text
  RsTemporal.Fields(1) = Text2.Text
  RsTemporal.Fields(2) = Text3.Text
  RsTemporal.Update
End Sub

Private Sub Form_Load()
ActivaTemporal
End Sub

Private Sub Command1_Click()
  'Cargamos la grilla con la tabla detalle
   Set rsDetalle = New Recordset
   rsDetalle.Open "SELECT * FROM Detalle", dbConex, adOpenStatic, adLockOptimistic
   Set DataGrid1.DataSource = rsDetalle
End Sub

Private Sub Command2_Click()
  GrabaTemporal
End Sub 

[Avellaneda]

Eso no lo puedes hacer con un DataGrid, tendría que ser con otro control como FlexGrid o ListView.

Si tiene que ser con un DataGrid, tendrías que unir ambas tablas en una sola, p.e.

1º Copiar la Tabla Detalle a una tabla temporal

"INSERT INTO Temporal SELECT Detalle.* FROM Detalle"

2º Añadir 3 nuevos campos a la tabla Temporal

"ALTER TABLE Temporal ADD COLUMN CodProd VARCHAR(4)"
.... igual para los otros dos campos

3º Abrir un recordset a la tabla Temporal para insertar los valores mediante el método AddNew o insertarlos directamente en la tabla con una instrucción INSERT INTO

y 4º Mostrar el resultado en el control DataGrid

Pero como digo al principio, es mas sencillo con cualquier otro control de los indicados.

[franko1809]

ummh, no entiendo del todo, pero te explico mejor, solo existe una tabla llamada detalle con 3 campos(CodProd,NomProd,PrecioVenta), estos datos los carga al grid mediante el rsDetalle.
El rsTemporal tiene los mismos campos pero es creado en tiempo de ejecucion para poder añadirle mas filas ala tabla detalle, el codigo lo he reducido para q capten la idea, bueno por otro lado voy a averiguar sobre
"INSERT INTO Temporal SELECT Detalle.* FROM Detalle"
"ALTER TABLE Temporal ADD COLUMN CodProd VARCHAR(4)"
Por que nunca habia hecho algo asi?, si tienes algo mas q agregar para ayudarme

saludos y gracias por tu tiempo

[franko1809]

Bueno aqui la solucion q utilize

Código vb:

Dim RsTemporal As New Recordset
Dim rsDetalle As New Recordset
 
Sub ActivaTemporal()
    'Creando recordset temporal
    RsTemporal.CursorType = adOpenStatic
    RsTemporal.Fields.Append "CodProd", adVarChar, 4, adFldIsNullable
    RsTemporal.Fields.Append "NomProd", adVarChar, 250, adFldIsNullable
    RsTemporal.Fields.Append "PrecioVenta", adDouble, 10.2, adFldIsNullable
    RsTemporal.Open
    'Cargamos el datagrid
    Set DataGrid1.DataSource = RsTemporal
End Sub
 
Sub GrabaTemporal()
  RsTemporal.AddNew
  RsTemporal.Fields(0) = Text1.Text
  RsTemporal.Fields(1) = Text2.Text
  RsTemporal.Fields(2) = Text3.Text
  RsTemporal.Update
End Sub
 
Private Sub Form_Load()
ActivaTemporal
End Sub
 
Private Sub Command1_Click()
   '123456: Aqui le aplicas un WHERE con el ID de tu tabla maestro para que no te filtre toda la tabla.
   rsDetalle.Open "SELECT codprod,nomprod,precioventa FROM Detalle", dbConex, adOpenStatic, adLockOptimistic
  
  'Añadimos los datos del rsDetalle al rsTemporal
  Do While Not rsDetalle.EOF
     RsTemporal.AddNew
     RsTemporal.Fields("CodProd") = rsDetalle.Fields("CodProd")
     RsTemporal.Fields("NomProd") = rsDetalle.Fields("NomProd")
     RsTemporal.Fields("PrecioVenta") = rsDetalle.Fields("PrecioVenta")
     RsTemporal.Update
     rsDetalle.MoveNext
  Loop
 
   
End Sub
 
Private Sub Command2_Click()
'Los registros que se ingresen con este sub se guardan en el rstemporal por lo
'tanto la tabla detalle queda intacta, al final si quieres lo vuelves a recorrer e ingresar los nuevos registros.
GrabaTemporal
End Sub