SubFolders

[(Pato)²]

Hola. Estoy haciendo una aplicacion que maneja los archvios de mi computadora.
Para esto necesito sabes cuantos archivos (bmp por ejemplo) hay en X carpeta.
Para eso estoy haciendo lo siguiente:

Código:

        Dim Files As Integer
        Dim BMPFile as String
        Files = 0
        BMPFile = Dir$(CarpetaX & "*.bmp")
        Do While BMPFile <> ""
                Files = Files + 1
                BMPFile = Dir$
        Loop

Eso si no me equivoco anda bien (aunque tengo la duda de si suma o no uno de mas).

Bueno, pero el gran problema esta en que no se como hace para poder contar tambien todos los que estan incluidos en las subcarpetas de X, necesito alguna forma de hacerlo automatico sin que el usuario tenga que poner una por una.

Alguien sabe como hacer?

MUCHAS GRACIAS!

Pato!

[luciano]

te paso un ejemplo:

Código:

Private Declare Function FindFirstFile Lib "kernel32" Alias "FindFirstFileA" (ByVal lpFileName As String, lpFindFileData As WIN32_FIND_DATA) As Long
Private Declare Function FindNextFile Lib "kernel32" Alias "FindNextFileA" (ByVal hFindFile As Long, lpFindFileData As WIN32_FIND_DATA) As Long
Private Declare Function GetFileAttributes Lib "kernel32" Alias "GetFileAttributesA" (ByVal lpFileName As String) As Long
Private Declare Function FindClose Lib "kernel32" (ByVal hFindFile As Long) As Long

Const MAX_PATH = 260
Const MAXDWORD = &HFFFF
Const INVALID_HANDLE_VALUE = -1
Const FILE_ATTRIBUTE_ARCHIVE = &H20
Const FILE_ATTRIBUTE_DIRECTORY = &H10
Const FILE_ATTRIBUTE_HIDDEN = &H2
Const FILE_ATTRIBUTE_NORMAL = &H80
Const FILE_ATTRIBUTE_READONLY = &H1
Const FILE_ATTRIBUTE_SYSTEM = &H4
Const FILE_ATTRIBUTE_TEMPORARY = &H100

Private Type FILETIME
    dwLowDateTime As Long
    dwHighDateTime As Long
End Type

Private Type WIN32_FIND_DATA
    dwFileAttributes As Long
    ftCreationTime As FILETIME
    ftLastAccessTime As FILETIME
    ftLastWriteTime As FILETIME
    nFileSizeHigh As Long
    nFileSizeLow As Long
    dwReserved0 As Long
    dwReserved1 As Long
    cFileName As String * MAX_PATH
    cAlternate As String * 14
End Type
Function StripNulls(OriginalStr As String) As String
    If (InStr(OriginalStr, Chr(0)) > 0) Then
        OriginalStr = Left(OriginalStr, InStr(OriginalStr, Chr(0)) - 1)
    End If
    StripNulls = OriginalStr
End Function

Function Contar(path As String, SearchStr As String, FileCount As Integer, DirCount As Integer)


    Dim FileName As String, DirName As String, dirNames() As String, Cont As Integer
    Dim nDir As Integer, i As Integer, hSearch As Long, WFD As WIN32_FIND_DATA
    
    If Right(path, 1) <> "\" Then path = path & "\"
    nDir = 0
    ReDim dirNames(nDir)
    Cont = True
    hSearch = FindFirstFile(path & "*", WFD)
    If hSearch <> INVALID_HANDLE_VALUE Then
        Do While Cont
        DirName = StripNulls(WFD.cFileName)
        
        If (DirName <> ".") And (DirName <> "..") Then
            
            If GetFileAttributes(path & DirName) And FILE_ATTRIBUTE_DIRECTORY Then
                dirNames(nDir) = DirName
                DirCount = DirCount + 1
                nDir = nDir + 1
                ReDim Preserve dirNames(nDir)
            End If
        End If
        Cont = FindNextFile(hSearch, WFD)
        Loop
        Cont = FindClose(hSearch)
    End If
    
    hSearch = FindFirstFile(path & SearchStr, WFD)
    Cont = True
    If hSearch <> INVALID_HANDLE_VALUE Then
        While Cont
            FileName = StripNulls(WFD.cFileName)
            If (FileName <> ".") And (FileName <> "..") Then
                Contar = Contar + (WFD.nFileSizeHigh * MAXDWORD) + WFD.nFileSizeLow
                FileCount = FileCount + 1
            End If
            Cont = FindNextFile(hSearch, WFD)
        Wend
        Cont = FindClose(hSearch)
    End If
    
    If nDir > 0 Then
        
        For i = 0 To nDir - 1
            Contar = Contar + Contar(path & dirNames(i) & "\", SearchStr, FileCount, DirCount)
        Next i
    End If
End Function
Sub Command1_Click()

    Dim FileSize As Long, NumFiles As Integer, NumDirs As Integer
    
    

    FileSize = Contar("c:\windows", "*.bmp", NumFiles, NumDirs)
    MsgBox NumFiles & " archivos"
    
    
End Sub

---------------

[(Pato)²]

Lei mas o menos pro arriba ese codigo, y no se si me funcionaria... ya que tambien necesito poder controlar cada archivo copiandolos y moviendolos de carpetas.
Tal vez sea que me estoy confundiendo yo... soy muy newbie programando :P

[luciano]

Cuando te referis a controlar, a que te referis ?? si te referis a tambien obtener los paths de los ficheros, por ejemplo poder visualizarlos en un control List, podes hacerlo asi,

..modifica en el bucle esto: ..salu2

Código:

        While Cont
            FileName = StripNulls(WFD.cFileName)
            If (FileName <> ".") And (FileName <> "..") Then
                Contar = Contar + (WFD.nFileSizeHigh * MAXDWORD) + WFD.nFileSizeLow
                FileCount = FileCount + 1
                
                List1.AddItem path & FileName
                
            End If
            Cont = FindNextFile(hSearch, WFD)
        Wend

-------