Capturar pantalla

[piojoman]

Queria saber si existe la posibilidad en vb6 poder capturar una imagen pero omitiendo a nuestra aplicación, o sea, sacar una foto pero que no salga nuestra aplicacion... logico sería poner el form en visible = false, pero lo que queria es cargar la imagen que obtenemos en un picturebox, o sea que no puedo usarlo... y todos los ejemplos que encontre obtienen una imagen completa incluyendo a mi programa y si cargo esa foto y de forma constante se forma un ciclo horrible de mi propio programa...

alguien me entendio??? y se podria lograr lo que suguiro?? ideas??

[seba123neo]

Hola, ¿ y porque no podes ocultarlo y mostrar depues el form y cargar la imagen en el picturebox ? algo asi:

Código vb:

Option Explicit
 
Private Declare Sub keybd_event Lib "user32" (ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)
 
Private Sub Capturar()
    Me.Visible = False
    Clipboard.Clear
    Call Pausa
    Call keybd_event(44, 2, 0, 0)
    DoEvents
    Me.Show
    If Clipboard.GetFormat(vbCFBitmap) Then
        Picture1.Picture = Clipboard.GetData(vbCFBitmap)
    Else
        MsgBox " Error ", vbCritical
    End If
End Sub
 
Private Sub Command1_Click()
    Call Capturar
End Sub
 
Private Sub Pausa()
   Dim vPausa As Long
   vPausa = 1 + Timer
 
    While vPausa >= Timer
        DoEvents
    Wend
End Sub
 

saludos.

[LeandroA]

hola poniendo atributos LAYERED al formulario BitBlt no lo captura.

Código:

Option Explicit
Private Declare Function GetWindowLong Lib "user32" Alias "GetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long) As Long
Private Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hwnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Private Declare Function SetLayeredWindowAttributes Lib "user32" (ByVal hwnd As Long, ByVal crKey As Long, ByVal bAlpha As Byte, ByVal dwFlags As Long) As Long
Private Declare Function GetDC Lib "user32.dll" (ByVal hwnd As Long) As Long
Private Declare Function DeleteDC Lib "gdi32" (ByVal hdc As Long) As Long
Private Declare Function BitBlt Lib "gdi32.dll" (ByVal hDestDC As Long, ByVal x As Long, ByVal y As Long, ByVal nWidth As Long, ByVal nHeight As Long, ByVal hSrcDC As Long, ByVal xSrc As Long, ByVal ySrc As Long, ByVal dwRop As Long) As Long

Const LWA_ALPHA         As Long = &H2
Const GWL_EXSTYLE       As Long = (-20)
Const WS_EX_LAYERED     As Long = &H80000

Private Sub Command1_Click()
    Dim DC As Long
    DC = GetDC(0)
    BitBlt Picture1.hdc, 0, 0, Screen.Width / 15, Screen.Height / 15, DC, 0, 0, vbSrcCopy
    Picture1 = Picture1.Image
    DeleteDC DC
End Sub

Private Sub Form_Load()
    With Picture1
        .AutoRedraw = True
        .Move 0, 0, Screen.Width, Screen.Height
    End With
    Command1.ZOrder 0
    SetWindowLong Me.hwnd, GWL_EXSTYLE, GetWindowLong(Me.hwnd, GWL_EXSTYLE) Or WS_EX_LAYERED
    SetLayeredWindowAttributes Me.hwnd, 0, 255, LWA_ALPHA
End Sub

Saludos

[piojoman]

bueno muchas gracias a ambos por las respuestas y fueron ambas muy satisfactorias...
seba123neo el codigo esta correctisimo de hecho hace todo como lo necesitaba pero tambien provoca un efecto como reapertura de la aplicacion en la barra de tareas si uno lo ejecuta constantemente como por ejemplo en un timer.
LeandroA el codigo que colocaste funciona tambien funciona de 10 y desconocia la funcion BitBlt lo que hizo que me ponga a leer un poco mas....
bueno gracias por la ayuda!