Buscar y mostrar resultados en Listview

[jeaguiar25]

Hola a todos!!!!
Mi problema es el siguiente:
Tengo una agenda hecha con VB6, pero al tratar de instalarla en otro pc, por más que haga un paquete de instalación con el "Asistente de empaqutado" , me da un error con los ocx del DataGrid. Por lo cual opté por cambiar el DataGrid por un Listview. El Listview se encuentra en un Form donde solo hay además de él un Textbox llamado TextBuscar. Mi intención es que al ir rellenando el texbox en el Listview se muestren las coincidencias. La sentencia que realice busca en una columna de un (.mdb) llamada "Nombres", tabla "Personas" y archivo "datos". Mi sentencia es la siguiente:

Public Sub RellenarLista()

Dim strVALOR_BuscarNombre As String
Dim Consulta01 As ADODB.Recordset
Dim li As ListItem

Set Consulta01 = New ADODB.Recordset

strVALOR_BuscarNombre = TextBuscar.Text

If TipoBusqueda = "Nombre" Then
Consulta01.Open "SELECT * FROM Personas WHERE Nombre like '%" & strVALOR_BuscarNombre & "%'", cnn, adOpenStatic, adLockReadOnly

Do Until Consulta01.EOF
Set li = ListView1.ListItems.Add(, , Consulta01("ID_Agenda"))
li.ListSubItems.Add , , Consulta01("Nombre")
li.ListSubItems.Add , , Consulta01("Domicilio")
li.ListSubItems.Add , , Consulta01("Num")
li.ListSubItems.Add , , Consulta01("Apto")
li.ListSubItems.Add , , Consulta01("Telefono")
li.ListSubItems.Add , , Consulta01("Celular")
li.ListSubItems.Add , , Consulta01("Departamento")
li.ListSubItems.Add , , Consulta01("Observaciones")

Consulta01.MovePrevious

Loop
End If
End Sub
Mi problema: Al digitar en el Textbox me muestra la coincidencia tantas veces como coincidencia de caracteres.
Ej:
Si digito juan en el textbox, me muestra en el listview:

juan
juan
juan
juan
julio
julio
justo
justo
josé
Espero puedan ayudarme, un abrazo a todos......

[lokoman]

Y si usas la consulta:
"SELECT DISTINCT * FROM Personas WHERE Nombre like '%" & strVALOR_BuscarNombre & "%'"

[jeaguiar25]

Me da el mismo resultado que el SELECT solo.

[lokoman]

Confirma:
• Cambia el "Consulta01.MovePrevious" por "Consulta01.MoveNext"
• Que no estes llamando el Sub "RellenarLista" varias veces
• Que no tienes varios "Juanes" en la base de datos (Juan Pablo, Juan Perez, José Juan, etc.). El Distinct deberia traer los Distintos elementos de la Base de Datos...

[jeaguiar25]

Te paso el codigo completo:

Desde aquí llamo al form
_________________________
Private Sub Buscar_Click(Index As Integer)
Call Buscar1
End Sub

Private Sub Buscar1()
With Form_Buscar
.TipoBusqueda = "Nombre"
.LblBuscarPor.Caption = "Buscar Usuario Por: Nombre"
.Caption = "Busqueda por Nombre"
.Show 1
End With
End Sub
______________________________
y este es el codigo completo del form (en el cual tengo solo el listview y con textbox)

Option Compare Text
Public TipoBusqueda As String

Private Sub Form_Load()
Move (Screen.Width - Width) \ 2, (Screen.Height - Height) \ 2
Const sPathBase As String = "C:\Genexis\Datos.mdb"
Set cnn = New ADODB.Connection
Set rst = New ADODB.Recordset
With cnn
.ConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;" & "Data Source=" & sPathBase & ";"
.Open
End With
End Sub

Public Sub RellenarLista()
Dim strVALOR_BuscarNombre As String
Dim Consulta01 As ADODB.Recordset
Dim li As ListItem
Set Consulta01 = New ADODB.Recordset
strVALOR_BuscarNombre = TextBuscar.Text
If TipoBusqueda = "Nombre" Then
Consulta01.Open "SELECT DISTINCT * FROM Personas WHERE Nombre like '%" & strVALOR_BuscarNombre & "%'", cnn, adOpenStatic, adLockReadOnly
Do Until Consulta01.EOF
Set li = ListView1.ListItems.Add(, , Consulta01("ID_Agenda"))
li.ListSubItems.Add , , Consulta01("Nombre")
li.ListSubItems.Add , , Consulta01("Domicilio")
li.ListSubItems.Add , , Consulta01("Num")
li.ListSubItems.Add , , Consulta01("Apto")
li.ListSubItems.Add , , Consulta01("Telefono")
li.ListSubItems.Add , , Consulta01("Celular")
li.ListSubItems.Add , , Consulta01("Departamento")
li.ListSubItems.Add , , Consulta01("Observaciones")
Consulta01.MoveNext
Loop
End If
End Sub

Private Sub TextBuscar_Change()
Call RellenarLista
End Sub

Private Sub TextBuscar_KeyPress(KeyAscii As Integer)
If KeyAscii = Asc("'") Then KeyAscii = 0
End Sub

Private Sub Cerrar_Click()
Unload Me
End Sub
Me sigue dando el mismo problema. Como siempre gracias por tu preocupación y ayuda

[lokoman]

AAHH!! Debes de limpiar el ListView antes de cargarlo con los datos:

Código vb:

If Consulta01.EOF = False Then ListView1.ListItems.Clear
 

Aqui esta el codigo:

Código vb:

Public Sub RellenarLista()
 
    Dim strVALOR_BuscarNombre As String
    Dim Consulta01 As ADODB.Recordset
    Dim li As ListItem
    
    Set Consulta01 = New ADODB.Recordset
    strVALOR_BuscarNombre = TextBuscar.Text
    
    If TipoBusqueda = "Nombre" Then
        Consulta01.Open "SELECT DISTINCT * FROM Personas WHERE Nombre like '%" & strVALOR_BuscarNombre & "%'", cnn, adOpenStatic, adLockReadOnly
        
        If Consulta01.EOF = False Then lsvList.ListItems.Clear
        
        Do Until Consulta01.EOF
            Set li = ListView1.ListItems.Add(, , Consulta01("ID_Agenda"))
            li.ListSubItems.Add , , Consulta01("Nombre")
            li.ListSubItems.Add , , Consulta01("Domicilio")
            li.ListSubItems.Add , , Consulta01("Num")
            li.ListSubItems.Add , , Consulta01("Apto")
            li.ListSubItems.Add , , Consulta01("Telefono")
            li.ListSubItems.Add , , Consulta01("Celular")
            li.ListSubItems.Add , , Consulta01("Departamento")
            li.ListSubItems.Add , , Consulta01("Observaciones")
 
            Consulta01.MoveNext
        Loop
    End If
End Sub
 

[jeaguiar25]

De más!!! Me funciono bárbaro, mil gracias Lokoman..... Siempre sos de gran ayuda

[lokoman]