Foros del Web » Creando para Internet » Flash y Actionscript »

CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Estas en el tema de CheckBox: Busco ejemplo claro de como usarlo con Flash AS3 en el foro de Flash y Actionscript en Foros del Web. Llevo varias horas buscando la manera de usar CheckBox en Flash con AS3 y no doy con el ejemplo que me clarifique el tema. Tengo ...
  #1 (permalink)  
Antiguo 11/03/2009, 11:16
Avatar de jovix777  
Fecha de Ingreso: abril-2008
Ubicación: Córdoba - Argentina
Mensajes: 151
Antigüedad: 9 años, 7 meses
Puntos: 2
CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Llevo varias horas buscando la manera de usar CheckBox en Flash con AS3 y no doy con el ejemplo que me clarifique el tema. Tengo que hacer un formulario con un monton de opciones para que el usuario elija con CheckBoxs, mas tipico imposible!! y no encuentro ningun ejemplo claro y sencillo para hacer esto en AS3.
Los datos de cada CheckBox iran a una base de datos, alguien tiene un ejemplo para ver???? o tutorial etc etc???

Debe ser muy basico el tema, tanto que lo dan por sabido parece, pero los que no somos programadores se nos escapan estas cosas,¿no hay forma de usar un simple checkbox sin tener que escribir tanto codigo???????? ayuuuudaaa porfa!

Gracias!!!!
  #2 (permalink)  
Antiguo 11/03/2009, 14:11
Avatar de jahepi
Colaborador
 
Fecha de Ingreso: diciembre-2004
Ubicación: Querétaro
Mensajes: 1.124
Antigüedad: 13 años
Puntos: 43
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Hola jovix777 !

Para utilizar un checkbox en As3.0 lo haces de la siguiente forma, supongamos que tienes 2 instancias del componente checkbox en el proyecto:

Código actionscript:
Ver original
  1. cb1.addEventListener(MouseEvent.CLICK, onClick);
  2. cb2.addEventListener(MouseEvent.CLICK, onClick);
  3.  
  4. function onClick(evt:MouseEvent):void {
  5.     trace(evt.target.label + ", está seleccionado: " + evt.target.selected);
  6. }

Un saludote !
__________________
Una contraseña es como la ropa interior. No deberías dejarlas afuera a la vista de otras personas, deberías cambiarla regularmente, y ni se te ocurra prestarla a extraños.
  #3 (permalink)  
Antiguo 11/03/2009, 16:13
Avatar de jovix777  
Fecha de Ingreso: abril-2008
Ubicación: Córdoba - Argentina
Mensajes: 151
Antigüedad: 9 años, 7 meses
Puntos: 2
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Ahora, una preguntita mas (ya que estamos... jeje) ¿si tengo 10 cb y quiero mandar el dato de cada uno de ellos a una base de datos, tengo que hacer una funcion para cada uno?,

Gracias otra vez, creo que a varios le va servir tu repuesta, es algo que se usa mucho y ahora que con el AS3 hay que aprender todo de nuevo... viene de lujo.
  #4 (permalink)  
Antiguo 11/03/2009, 16:38
Avatar de jahepi
Colaborador
 
Fecha de Ingreso: diciembre-2004
Ubicación: Querétaro
Mensajes: 1.124
Antigüedad: 13 años
Puntos: 43
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Hola jovix777 !

Si quieres ahorrarte líneas de código podrías hacer lo siguiente:

En cada una de las instancias checkbox asignarles un nombre cb1, cb2, cb3, etc...
De esta forma podremos hacer un ciclo para registrar que nos sea notificado cuando le damos click a uno de ellos:

Código actionscript:
Ver original
  1. //En esta caso son 10 componentes checkbox (cb1, cb2..cb10).
  2. for(var i:int = 1; i <= 10; i++) {
  3.     this["cb"+i].addEventListener(MouseEvent.CLICK, onClick);
  4. }
  5.  
  6. function onClick(evt:MouseEvent):void {
  7.     trace(evt.target.label + ", está seleccionado: " + evt.target.selected);
  8. }

Ahora un problemilla, como podría ir almacenando cada uno de los valores seleccionados para mandarlos después.

Lo que podemos hacer aquí es utilizar un objeto y emular un arreglo asociativo, si seleccionan un checkbox almacenarlo en el arreglo, si se le quita la selección quitarlo del arreglo:

Código actionscript:
Ver original
  1. var selectedValues:Object = new Object();
  2. //En esta caso son 10 componentes checkbox (cb1, cb2..cb10).
  3. for(var i:int = 1; i <= 10; i++) {
  4.     this["cb"+i].addEventListener(MouseEvent.CLICK, onClick);
  5. }
  6.  
  7. function onClick(evt:MouseEvent):void {
  8.     if(evt.target.selected) {
  9.         selectedValues[evt.target.name] = evt.target.label;
  10.     } else {
  11.         delete selectedValues[evt.target.name];
  12.     }
  13. }

Utilizo el nombre de instancia como clave y la etiqueta como valor, de esta forma el objeto selectedValues contendrá los valores seleccionados.

Un saludote !
__________________
Una contraseña es como la ropa interior. No deberías dejarlas afuera a la vista de otras personas, deberías cambiarla regularmente, y ni se te ocurra prestarla a extraños.
  #5 (permalink)  
Antiguo 12/03/2009, 08:43
Avatar de jovix777  
Fecha de Ingreso: abril-2008
Ubicación: Córdoba - Argentina
Mensajes: 151
Antigüedad: 9 años, 7 meses
Puntos: 2
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Buenisimo! Genio total... no se porque los manuales oficiales no son claros asi.

Mil gracias!!!

PD: muy bueno tu blog tambien.
  #6 (permalink)  
Antiguo 12/03/2009, 16:02
Avatar de Kronos_Corp  
Fecha de Ingreso: marzo-2009
Mensajes: 61
Antigüedad: 8 años, 9 meses
Puntos: 1
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Muchas Gracis compa Japehi...muy buena la ayuda justamente andaba buscando algun toturial bueno para el componente checkbox...ahora tengo una duda


quiero que al estar seleccionado el componente checkbox tenga un valor.
Ejemplo: 2

y al no estarlo tenga otro.
Ejemplo: 3

para asi al pulsar otro boton me muestre la suma de los dos valores en un Texto Dinamico...espero haberme dado a entender
  #7 (permalink)  
Antiguo 12/03/2009, 16:55
Avatar de jahepi
Colaborador
 
Fecha de Ingreso: diciembre-2004
Ubicación: Querétaro
Mensajes: 1.124
Antigüedad: 13 años
Puntos: 43
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Cita:
Iniciado por Kronos_Corp Ver Mensaje
Muchas Gracis compa Japehi...muy buena la ayuda justamente andaba buscando algun toturial bueno para el componente checkbox...ahora tengo una duda


quiero que al estar seleccionado el componente checkbox tenga un valor.
Ejemplo: 2

y al no estarlo tenga otro.
Ejemplo: 3

para asi al pulsar otro boton me muestre la suma de los dos valores en un Texto Dinamico...espero haberme dado a entender
Hola Kronos_Corp !

Aquí hay un pequeño incoveniente, los componentes checkbox no pueden almacenar valores, solo podemos obtener el valor de la etiqueta por medio del atributo label, y también saber su estado si está seleccionado o no.

Lo que quieres es que el checkbox almacene un valor interno, y este sea variable de acuerdo al estado del checkbox, para esto vamos a tener que extender la funcionalidad del componente para agregarle esos comportamientos.

Para hacer esto debemos heredar de la clase checkbox y definir los comportamientos nuevos:

MyCheckBox.as
Código actionscript:
Ver original
  1. package
  2. {
  3.     import fl.controls.CheckBox;
  4.    
  5.     public class MyCheckBox extends CheckBox
  6.     {
  7.        
  8.         private var _selectedValue:Number;
  9.         private var _noselectedValue:Number;
  10.        
  11.         public function MyCheckBox(selectedValue, noselectedValue) {
  12.             _selectedValue = selectedValue;
  13.             _noselectedValue = noselectedValue;
  14.         }
  15.        
  16.         public function get value():Number {
  17.             if(selected) {
  18.                 return _selectedValue;
  19.             }
  20.             return _noselectedValue;
  21.         }
  22.     }
  23. }

Definí mi clase MyCheckBox, agregué 2 nuevos atributos que contendrán los valores cuando está seleccionado o no, estos valores los vamos a pasar al constructor cuando creemos el componente.

El método get value, se encarga de devolverme el valor correcto, dependiendo si el checkbox está seleccionado o no, me devuelve un valor u otro.

Ahora veamos un ejemplo con código de como usarla:

Código actionscript:
Ver original
  1. var cb1:MyCheckBox = new MyCheckBox(5, 10);
  2. cb1.label = "Opción 1";
  3. addChild(cb1);
  4.  
  5. var cb2:MyCheckBox = new MyCheckBox(8, 4);
  6. cb2.label = "Opción 2";
  7. addChild(cb2);
  8. cb2.y = 50;
  9.  
  10. cb1.addEventListener(MouseEvent.CLICK, onClick);
  11. cb2.addEventListener(MouseEvent.CLICK, onClick);
  12.  
  13. function onClick(evt:MouseEvent):void {
  14.     trace(evt.target.value);
  15. }


Vas a ver que el checkbox devuelve un valor de acuerdo a su estado.

Nota:
La clase MyCheckBox.as debe estar en la misma carpeta del .fla
También debes arratrar el componente checkbox al espacio de trabajo y depués borrarlo, esto con la finalidad de quede en la librería y no de errores de compilación a la hora de crear los componentes dinámicamente.


Un saludote !
__________________
Una contraseña es como la ropa interior. No deberías dejarlas afuera a la vista de otras personas, deberías cambiarla regularmente, y ni se te ocurra prestarla a extraños.
  #8 (permalink)  
Antiguo 12/03/2009, 16:56
Avatar de jahepi
Colaborador
 
Fecha de Ingreso: diciembre-2004
Ubicación: Querétaro
Mensajes: 1.124
Antigüedad: 13 años
Puntos: 43
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Cita:
Iniciado por jovix777 Ver Mensaje
Buenisimo! Genio total... no se porque los manuales oficiales no son claros asi.

Mil gracias!!!

PD: muy bueno tu blog tambien.
Hola jovix777 !

Que bueno que te haya servido todo.

Un saludote !
__________________
Una contraseña es como la ropa interior. No deberías dejarlas afuera a la vista de otras personas, deberías cambiarla regularmente, y ni se te ocurra prestarla a extraños.
  #9 (permalink)  
Antiguo 12/03/2009, 17:40
Avatar de Kronos_Corp  
Fecha de Ingreso: marzo-2009
Mensajes: 61
Antigüedad: 8 años, 9 meses
Puntos: 1
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Gracias japehi por la ayuda....

pero entonces como paso los valores aun texto dinamico???

dices que no se puede con Checkbox...que me dices con un RadioButton...se puede..como hacerlo??


Gracias por tu ayuda de antemano...y disculpa que soy nuevo en esto ymas aun en AS3, si de por si apenas ando aprendiendo AS2 imaginate el As3...agradeceria mucho tu respuesta
  #10 (permalink)  
Antiguo 13/03/2009, 01:09
Avatar de Kronos_Corp  
Fecha de Ingreso: marzo-2009
Mensajes: 61
Antigüedad: 8 años, 9 meses
Puntos: 1
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Gracias compa jahepi...pues estudiando el codigo que me enviaste lo comprendi todo...muchas gracias..tambien supe poner ya los valores en un texto dinamico.....ojala muchos compañeros fueran como tu, me refiero a la manera de ayudar y explicar las dudas...gracias de nuevo
  #11 (permalink)  
Antiguo 13/03/2009, 07:12
Avatar de jovix777  
Fecha de Ingreso: abril-2008
Ubicación: Córdoba - Argentina
Mensajes: 151
Antigüedad: 9 años, 7 meses
Puntos: 2
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

¿y si se usa el estado selected para cargar una variable??? yo asi hago q me devuelva yes o no, supongo q si se hace una variable int puede devolver numeros.

var resultado:String = new String();

cb.addEventListener(MouseEvent.CLICK, click_cb);

function click_cb(evt:MouseEvent):void {
if (evt.target.selected == true) {
resutado = "YES";
} else {
resultado = "NO";
}
}
  #12 (permalink)  
Antiguo 13/03/2009, 18:13
Avatar de jahepi
Colaborador
 
Fecha de Ingreso: diciembre-2004
Ubicación: Querétaro
Mensajes: 1.124
Antigüedad: 13 años
Puntos: 43
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Cita:
Iniciado por Kronos_Corp Ver Mensaje
Gracias compa jahepi...pues estudiando el codigo que me enviaste lo comprendi todo...muchas gracias..tambien supe poner ya los valores en un texto dinamico.....ojala muchos compañeros fueran como tu, me refiero a la manera de ayudar y explicar las dudas...gracias de nuevo
Hola Kronos_Corp !

Que bueno que te haya servido.
Cualquier duda aqui andamos.

No sé si te habías fíjado pero los códigos están saliendo mal, como que se agrega la etiqueta </textarea> en los saltos de línea.

Un saludote !
__________________
Una contraseña es como la ropa interior. No deberías dejarlas afuera a la vista de otras personas, deberías cambiarla regularmente, y ni se te ocurra prestarla a extraños.
  #13 (permalink)  
Antiguo 13/03/2009, 18:32
Avatar de jahepi
Colaborador
 
Fecha de Ingreso: diciembre-2004
Ubicación: Querétaro
Mensajes: 1.124
Antigüedad: 13 años
Puntos: 43
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Cita:
Iniciado por jovix777 Ver Mensaje
¿y si se usa el estado selected para cargar una variable??? yo asi hago q me devuelva yes o no, supongo q si se hace una variable int puede devolver numeros.

var resultado:String = new String();

cb.addEventListener(MouseEvent.CLICK, click_cb);

function click_cb(evt:MouseEvent):void {
if (evt.target.selected == true) {
resutado = "YES";
} else {
resultado = "NO";
}
}
Hola jovix777 !

Es válido lo que comentas, pero es mejor centralizar esos comportamientos dentro de la clase.

Lo que Kronos necesitaba era que cada checkbox tuviera un valor entero si esta activo o otro valor si esta desactivo, estos valores pueden variar en cada una de las instancias checkbox.

Por ejemplo tengo 2 instancias checkbox.
La primera instancia cuando está desactivada devuelve valor 11 y cuando no 5.
La segunda instancia cuando está desactivada devuelve valor 6 y cuando no 8.

Si lo hacemos con el método que planteas, duplicariamos código, tendríamos que crear 2 variables resultado para almacenar los valores de acuerdo al estado de cada instancia, añadir bloques condicionales por cada instancia para asignarle los valores correctos de acuerdo a su estado. Esto a la larga haría mucho más complicado mantener el programa.

En cambio si esos comportamientos los defino en la clase, está se encargará de hacer todo lo necesario, decidir que valor devolverme de acuerdo a su estado (método get value), inicializar el checkbox con sus valores en estado activo y desactivo (constructor).

Un saludote !
__________________
Una contraseña es como la ropa interior. No deberías dejarlas afuera a la vista de otras personas, deberías cambiarla regularmente, y ni se te ocurra prestarla a extraños.
  #14 (permalink)  
Antiguo 13/03/2009, 20:30
Avatar de Kronos_Corp  
Fecha de Ingreso: marzo-2009
Mensajes: 61
Antigüedad: 8 años, 9 meses
Puntos: 1
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Bueno compa tuve un problema....el codigo que me diste me funciona perfecto, pero ahora quiero agregar otra funcion mas.....


Quiero que el valor de cada CheckBox, me lo muestre en un texto dinamico, pero separados...por ejemplo: el valor de CheckBox 1 en un texto y el del 2 en otro ,etc.

Copeo el codigo y pongo el mismo codigo por cada CheckBox, pero me marca que la funcion esta Repetida...espero y me haya dado a entender...

se que hay que cambiar la funcion, pero no se que poner..bueno espero tu respuesta, para ya de una vez por todas terminar mi proyecto Flash
  #15 (permalink)  
Antiguo 18/03/2009, 13:57
Avatar de jovix777  
Fecha de Ingreso: abril-2008
Ubicación: Córdoba - Argentina
Mensajes: 151
Antigüedad: 9 años, 7 meses
Puntos: 2
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Sigo jugando con los CheckBoxs. Tengo otro embrollo, la cantidad de ellos, son 110. Con la funcion "for" que me pasaste jahepi, consigo obtener el label de cada uno, obviamente instancie cada checkbox con cb1, cb2, ... cb110.
Lo que mi mente de diseñador grafico no entiende es como hacer para pasar el resultado de cada cb a una variable que despues se mande al php que termina poniendola en un campo de la base de datos.
Simplificando, tengo dos cb, cb1 dice Agua y cb2 Luz. El resultado de cada uno de ellos es SI o NO, como hago para que se grabe la variable agua_in que sera igual a SI o NO, y la variable luz_in que tambien sera igual a SI o NO???? como es una sola funcion para todos los cb, necesito que cuando se seleccione un cb devuelva una variable con el nombre del cb (agua o luz) para finalmente llenar los campos de la base de datos Agua y Luz con un SI o NO respectivamente... es dificil de explicar, lo se...
Ya se que lo explicaste en tu ejemplo jahepi, pero estoy trabado ahi... un empujoncito hace falta.

Gracias a todos

Última edición por jovix777; 18/03/2009 a las 14:05
  #16 (permalink)  
Antiguo 19/03/2009, 22:24
Avatar de Kronos_Corp  
Fecha de Ingreso: marzo-2009
Mensajes: 61
Antigüedad: 8 años, 9 meses
Puntos: 1
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Que ondas haber si alguien me ayuda con mi ultima pregunta que postee
  #17 (permalink)  
Antiguo 20/03/2009, 21:31
Avatar de Kronos_Corp  
Fecha de Ingreso: marzo-2009
Mensajes: 61
Antigüedad: 8 años, 9 meses
Puntos: 1
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Chales nadie que sepa hacer esto...espero que algun maestro de Flash me ayude con esto de seguro sera algo sencillo para el
  #18 (permalink)  
Antiguo 21/03/2009, 21:06
Avatar de jahepi
Colaborador
 
Fecha de Ingreso: diciembre-2004
Ubicación: Querétaro
Mensajes: 1.124
Antigüedad: 13 años
Puntos: 43
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Cita:
Iniciado por jovix777 Ver Mensaje
Sigo jugando con los CheckBoxs. Tengo otro embrollo, la cantidad de ellos, son 110. Con la funcion "for" que me pasaste jahepi, consigo obtener el label de cada uno, obviamente instancie cada checkbox con cb1, cb2, ... cb110.
Lo que mi mente de diseñador grafico no entiende es como hacer para pasar el resultado de cada cb a una variable que despues se mande al php que termina poniendola en un campo de la base de datos.
Simplificando, tengo dos cb, cb1 dice Agua y cb2 Luz. El resultado de cada uno de ellos es SI o NO, como hago para que se grabe la variable agua_in que sera igual a SI o NO, y la variable luz_in que tambien sera igual a SI o NO???? como es una sola funcion para todos los cb, necesito que cuando se seleccione un cb devuelva una variable con el nombre del cb (agua o luz) para finalmente llenar los campos de la base de datos Agua y Luz con un SI o NO respectivamente... es dificil de explicar, lo se...
Ya se que lo explicaste en tu ejemplo jahepi, pero estoy trabado ahi... un empujoncito hace falta.

Gracias a todos
Hola jovix777 !

En la clase URLVariables se guardan los datos que se van a madar al servidor, así que podemos hacer lo siguiente:

Código actionscript:
Ver original
  1. import flash.net.*;
  2.  
  3. var requestValues:URLVariables = new URLVariables();
  4. requestValues["agua"] = "no";
  5. requestValues["luz"] = "no";
  6.  
  7. cb1.addEventListener(Event.CHANGE, onChange);
  8. cb2.addEventListener(Event.CHANGE, onChange);
  9.  
  10. function onChange(evt:Event):void {
  11.     if(evt.target.selected) {
  12.         requestValues[evt.target.label] = "si";
  13.     } else {
  14.         requestValues[evt.target.label] = "no";
  15.     }
  16. }

Los valores de las etiquetas de los componentes checkbox deben ser iguales a los nombres de atributo en requestValues.

Ahora para mandarlos al servidor:
Código actionscript:
Ver original
  1. sendBtn.addEventListener(MouseEvent.CLICK, onClick);
  2.  
  3. var request:URLRequest = new URLRequest("http://www.misitio.com/receiver.php");
  4. request.method = URLRequestMethod.POST;
  5. request.data = requestValues;
  6. var sender:URLLoader = new URLLoader();
  7. function onClick(evt:MouseEvent):void {
  8.     sender.load(request);
  9. }

Tenemos un botón sendBtn que al darle click manda los datos al servidor.

Y por último el script PHP que recibe los datos:

receiver.php
Código php:
Ver original
  1. $output = "";
  2. foreach($_POST as $key => $value) {
  3.     $output .= $key . "=" . $value . "\r\n";
  4. }
  5.  
  6. $file = fopen("resultado.txt", "w");
  7. fwrite($file, $output, strlen($output));

Se va a crear un archivo de texto en la raiz del servidor con los valores enviados desde Flash.

Un saludote !
__________________
Una contraseña es como la ropa interior. No deberías dejarlas afuera a la vista de otras personas, deberías cambiarla regularmente, y ni se te ocurra prestarla a extraños.
  #19 (permalink)  
Antiguo 21/03/2009, 21:28
Avatar de jahepi
Colaborador
 
Fecha de Ingreso: diciembre-2004
Ubicación: Querétaro
Mensajes: 1.124
Antigüedad: 13 años
Puntos: 43
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Cita:
Iniciado por Kronos_Corp Ver Mensaje
Bueno compa tuve un problema....el codigo que me diste me funciona perfecto, pero ahora quiero agregar otra funcion mas.....


Quiero que el valor de cada CheckBox, me lo muestre en un texto dinamico, pero separados...por ejemplo: el valor de CheckBox 1 en un texto y el del 2 en otro ,etc.

Copeo el codigo y pongo el mismo codigo por cada CheckBox, pero me marca que la funcion esta Repetida...espero y me haya dado a entender...

se que hay que cambiar la funcion, pero no se que poner..bueno espero tu respuesta, para ya de una vez por todas terminar mi proyecto Flash
Hola Kronos_Corp !

Lo que pasa es que estás duplicando la función, si lo que quieres es meter diferente lógica en cada una de las opciones, vas a tener que definir diferentes funciones ó una función que sea responsable de preguntar que instancia fue presionada y en base a eso hacer lo necesario.

Vamos a realizarlo de la segunda forma:

Código actionscript:
Ver original
  1. cb1.addEventListener(Event.CHANGE, onChange);
  2. cb2.addEventListener(Event.CHANGE, onChange);
  3. cb3.addEventListener(Event.CHANGE, onChange);
  4.  
  5. function onChange(evt:MouseEvent):void {
  6.     if(evt.target.name == "cb1") {
  7.         texto1.text = evt.target.value;
  8.         //Otras instrucciones
  9.     } else if(evt.target.name == "cb2") {
  10.         texto2.text = evt.target.value;
  11.         //Otras instrucciones
  12.     } else if(evt.target.name == "cb3") {
  13.         texto3.text = evt.target.value;
  14.         //Otras instrucciones
  15.     }
  16. }

Un saludote !
__________________
Una contraseña es como la ropa interior. No deberías dejarlas afuera a la vista de otras personas, deberías cambiarla regularmente, y ni se te ocurra prestarla a extraños.
  #20 (permalink)  
Antiguo 21/03/2009, 22:21
Avatar de Kronos_Corp  
Fecha de Ingreso: marzo-2009
Mensajes: 61
Antigüedad: 8 años, 9 meses
Puntos: 1
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Gracias japehi por responder.....y respecto a lo que dices de la funcion, si me imaginaba eso.pero no sabia la forma de ponerla de manera separada...espero que con este coidgo ahora si lo logre...lo pruebo y te cuento que tal me fue..y otra vez gracias por la respuesta
  #21 (permalink)  
Antiguo 23/03/2009, 15:18
Avatar de Kronos_Corp  
Fecha de Ingreso: marzo-2009
Mensajes: 61
Antigüedad: 8 años, 9 meses
Puntos: 1
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Ok compa...mira...modifique el codigo al siguiente...admas inserte 3 cuadros de texto dinamicos con variables texto1, text2 y texto 3

Código ActionScript:
Ver original
  1. var cb1:MyCheckBox = new MyCheckBox(5, 10);
  2. cb1.label = "Opción 1";
  3. addChild(cb1);
  4.  
  5. var cb2:MyCheckBox = new MyCheckBox(8, 4);
  6. cb2.label = "Opción 2";
  7. addChild(cb2);
  8. cb2.y = 50;
  9.  
  10. var cb3:MyCheckBox = new MyCheckBox(16, 20);
  11. cb2.label = "Opción 3";
  12. addChild(cb3);
  13. cb3.y = 100;
  14.  
  15. cb1.addEventListener(Event.CHANGE, onChange);
  16. cb2.addEventListener(Event.CHANGE, onChange);
  17. cb3.addEventListener(Event.CHANGE, onChange);
  18.  
  19. function onChange(evt:MouseEvent):void {
  20.     if(evt.target.name == "cb1") {
  21.         texto1.text = evt.target.value;
  22.         //Otras instrucciones
  23.     } else if(evt.target.name == "cb2") {
  24.         texto2.text = evt.target.value;
  25.         //Otras instrucciones
  26.     } else if(evt.target.name == "cb3") {
  27.         texto3.text = evt.target.value;
  28.         //Otras instrucciones
  29.     }
  30. }


Ademas tengo guardado el archivo MyCheckBox.as que me diste al principio....al momento de seleccionar un checkbox me da elsiguiente error

Código ActionScript:
Ver original
  1. TypeError: Error #1034: Error de conversión forzada: no se puede convertir flash.events::[email protected] en flash.events.MouseEvent.
  2.     at flash.events::EventDispatcher/flash.events:EventDispatcher::dispatchEventFunction()
  3.     at flash.events::EventDispatcher/dispatchEvent()
  4.     at fl.controls::LabelButton/fl.controls:LabelButton::toggleSelected()


Espero y me dirigas en esto gracias

Última edición por Kronos_Corp; 23/03/2009 a las 22:42
  #22 (permalink)  
Antiguo 23/03/2009, 15:44
Avatar de jahepi
Colaborador
 
Fecha de Ingreso: diciembre-2004
Ubicación: Querétaro
Mensajes: 1.124
Antigüedad: 13 años
Puntos: 43
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Cita:
Iniciado por Kronos_Corp Ver Mensaje
Ok compa...mira...modifique el codigo al siguiente...admas inserte 3 cuadros de texto dinamicos con variables texto1, text2 y texto 3

Código Codigo Action Script:
Ver original
  1. var cb1:MyCheckBox = new MyCheckBox(5, 10);
  2. cb1.label = "Opción 1";
  3. addChild(cb1);
  4.  
  5. var cb2:MyCheckBox = new MyCheckBox(8, 4);
  6. cb2.label = "Opción 2";
  7. addChild(cb2);
  8. cb2.y = 50;
  9.  
  10. var cb3:MyCheckBox = new MyCheckBox(16, 20);
  11. cb2.label = "Opción 3";
  12. addChild(cb3);
  13. cb3.y = 100;
  14.  
  15. cb1.addEventListener(Event.CHANGE, onChange);
  16. cb2.addEventListener(Event.CHANGE, onChange);
  17. cb3.addEventListener(Event.CHANGE, onChange);
  18.  
  19. function onChange(evt:MouseEvent):void {
  20.     if(evt.target.name == "cb1") {
  21.         texto1.text = evt.target.value;
  22.         //Otras instrucciones
  23.     } else if(evt.target.name == "cb2") {
  24.         texto2.text = evt.target.value;
  25.         //Otras instrucciones
  26.     } else if(evt.target.name == "cb3") {
  27.         texto3.text = evt.target.value;
  28.         //Otras instrucciones
  29.     }
  30. }


Ademas tengo guardado el archivo MyCheckBox.as que me diste al principio....al momento de seleccionar un checkbox me da elsiguiente error

Código Error:
Ver original
  1. TypeError: Error #1034: Error de conversión forzada: no se puede convertir flash.events::[email protected] en flash.events.MouseEvent.
  2.     at flash.events::EventDispatcher/flash.events:EventDispatcher::dispatchEventFunction()
  3.     at flash.events::EventDispatcher/dispatchEvent()
  4.     at fl.controls::LabelButton/fl.controls:LabelButton::toggleSelected()


Espero y me dirigas en esto gracias
Hola Kronos_Corp !

Tuve un pequeño error.
En la parte que dice MouseEvent cambialo por Event:

Código actionscript:
Ver original
  1. function onChange(evt:Event):void {
  2.     //etc...
  3. }

Un saludote !
__________________
Una contraseña es como la ropa interior. No deberías dejarlas afuera a la vista de otras personas, deberías cambiarla regularmente, y ni se te ocurra prestarla a extraños.
  #23 (permalink)  
Antiguo 26/03/2009, 08:00
Avatar de jovix777  
Fecha de Ingreso: abril-2008
Ubicación: Córdoba - Argentina
Mensajes: 151
Antigüedad: 9 años, 7 meses
Puntos: 2
Respuesta: CheckBox: Busco ejemplo claro de como usarlo con Flash AS3

Gracias Jahepi...! deberias escribir un libro, explicas mejor que muchos tutoriales oficiales.
Atención: Estás leyendo un tema que no tiene actividad desde hace más de 6 MESES, te recomendamos abrir un Nuevo tema en lugar de responder al actual.
Respuesta




La zona horaria es GMT -6. Ahora son las 08:55.