Ventanas PopUp

[TMeister]

Buenas gente.. aqui dejo una clase para la creacion de ventanas popup.
Al ser una clase solo funcionara en la version MX 2004 para versiones anteriores a la MX 2004 mas abajo esta la explicacion

windowUtils.as

Código PHP:

  /** 
* @class windowUtils 
* @author Enrique Chavez aka Tmeister 
* @version 0.1 
* @description Set de utilerias para la creacion de Popups 
* @usage   <pre>import windowUtils</pre> 
*/; 
class windowUtils{ 
    /** 
    * @method make 
    * @description  Genera una ventana Popup 
    * @usage <code>windowUtils.make(ancho, alto, url, [winName])</code> 
    * @param ancho (Number) El ancho de la ventana que se creara 
    * @param alto (Number) El alto de la ventana que se creara 
    * @param url (String) El url de la pagina que se mostrara en el Popup 
    * @param winName (String) Opcional el nombre de la ventana Popup 
    */;     
    public static function make(ancho:Number, alto:Number, url:String, winName:String):Void{ 
        var winName = (winName == undefined) ? "PopUp" : winName; 
        var carac:String = "width="+ancho+",height="+alto+","; 
        carac += "toolbar=0,scrollbars=0,location=0,statusbar=0,menubar=0,resizable=0"; 
        getURL("javascript:void(window.open('"+url+"','"+winName+"','"+carac+"'));"); 
    } 
    /** 
    * @method make 
    * @description  Genera una ventana Popup centrada en la pantalla 
    * @usage <code>windowUtils.makeCenter(ancho, alto, url, [winName])</code> 
    * @param ancho (Number) El ancho de la ventana que se creara 
    * @param alto (Number) El alto de la ventana que se creara 
    * @param url (String) El url de la pagina que se mostrara en el Popup 
    * @param winName (String) Opcional el nombre de la ventana Popup 
    */;     
    public static function makeCenter(ancho:Number, alto:Number, url:String, winName:String):Void{ 
        var winName = (winName == undefined) ? "PopUp" : winName; 
        var left = (System.capabilities.screenResolutionX-ancho)/2 
        var top = (System.capabilities.screenResolutionY-alto)/2 
        var carac:String = "width="+ancho+",height="+alto+","; 
        carac += "toolbar=0,scrollbars=0,location=0,statusbar=0,menubar=0,resizable=0,"; 
        carac += "top="+top+",left="+left; 
        getURL("javascript:void(window.open('"+url+"','"+winName+"','"+carac+"'));"); 
    } 
}  
   

Este archivo .as tiene que se salvaldo con el nombre windowUtils.as y estar en el mismo directorio que su FLA.

Ahora desde su pelicula FLA

Código:

import windowUtils;
windowUtils.make(350, 150, "http://www.google.com", "miPop");

Si quieren que la accion se ejecute al dar click en un boton

Código:

import windowUtils;
mi_btn.onRelease = function() {
	windowUtils.makeCenter(350, 150, "http://www.google.com", "miPop");
};

Esta Clase cuenta con 2 metodos make y makeCenter, la unica direfencia entre estos metodos es que makeCenter crea la ventana popUp y la centra con respecto a la resolucion del usuario.

Version MX

En lugar de Clases aqui vamos a usar funciones comunes

Código:

function make(ancho, alto, url, winName) {
	var winName = (winName == undefined) ? "PopUp" : winName;
	var carac = "width="+ancho+",height="+alto+",";
	carac += "toolbar=0,scrollbars=0,location=0,statusbar=0,menubar=0,resizable=0";
	getURL("javascript:void(window.open('"+url+"','"+winName+"','"+carac+"'));");
}
function makeCenter(ancho, alto, url, winName) {
	var winName = (winName == undefined) ? "PopUp" : winName;
	var left = (System.capabilities.screenResolutionX-ancho)/2;
	var top = (System.capabilities.screenResolutionY-alto)/2;
	var carac = "width="+ancho+",height="+alto+",";
	carac += "toolbar=0,scrollbars=0,location=0,statusbar=0,menubar=0,resizable=0,";
	carac += "top="+top+",left="+left;
	getURL("javascript:void(window.open('"+url+"','"+winName+"','"+carac+"'));");
}

y las llamamos asi

Código:

mi_btn.onRelease = function() {
	makeCenter(350, 150, "http://www.google.com", "miPop");
};

tan tan..

Saludos!!