2 preguntitas...

[jc_moty]

lo que ahora me pasa es que cuando quiero crear un nuevo usuario me tira un error de que esta mal la sintaxis del INSRT INTO, y mira que prove hasta ahciendo copy and paste del que pusiste vos :S no sé que pasa...

Y, ya probaste quitando el parentesis al llamar al metodo:

Código:

' En lugar de:
Data.Execute("Insert Into Users (User, Clave, Recordar) VALUES ('" & Usuar & "',"  & Contr & ", 'False')")
' Proba asi:
Data.Execute "Insert Into Users (User, Clave, Recordar) VALUES ('" & Usuar & "',"  & Contr & ", 'False')"

1º)Alguien tiene idea de como ahcer para que un form del programa se vea en el Systray (creo que se llama así el cosito donde aparece la hora), y que si le das doblde click se abra, y con click\click derecho aparesca un menu...???

Fijate que yo tengo un ejemplo que hace esto; aqui dejo las instrucciones y el codigo fuente:
En el form debes pegar un PictureBox y en la propiedad Picture debes poner un Icono; tambien debes de crear un menu (mnuEmergente) con el Editor de Menus y la propiedad Visible de este menu debe ser False, el menu debe incluir 3 Opciones: Mostrar, Ocultar y Salir.

Código:

' En un modulo:
Public Const VER_ICONO As Long = &H0&
Public Const OCULTAR_ICONO As Long = &H2&
Public Const CLICKDERECHO As Long = &H205
Public Const DOBLECLICK = &H203
Type ConfigurarIcono
    Tamaño As Long
    hWnd As Long
    Id As Long
    Bandera As Long
    Mensaje As Long
    Icono As Long
    strTip As String * 10
End Type
Public config As ConfigurarIcono
Global cancelar As Boolean
Declare Function Shell_NotifyIconA Lib "SHELL32" (ByVal dwMessage As Long, lpData As ConfigurarIcono) As Long

Public Sub sysTrayIcon(imagen As PictureBox, visibilidad As Long, cadena As String)
' Procedimiento para colocar el Icono en el SysTray de Windows
config.Tamaño = Len(config)
config.hWnd = imagen.hWnd
config.Id = 1
config.Bandera = &H1 Or &H2 Or &H4
config.Mensaje = &H200
config.Icono = imagen.Picture
config.strTip = cadena & Chr$(0)
Shell_NotifyIconA visibilidad, config
End Sub

' En el evento Load del Form
Private Sub Form_Load()
' Para que la Aplicacion se ejecute solo una vez
If App.PrevInstance Then End: Exit Sub
' Colocamos el icono en el SysTray
sysTrayIcon Picture1, VER_ICONO, "Mi aplicacion"
cancelar = True
End Sub

' En el Unload
Private Sub Form_Unload(Cancel As Integer)
Cancel = cancelar
Visible = False
If Cancel = False Then sysTrayIcon Picture1, OCULTAR_ICONO, "Mi aplicacion"
End Sub

'En el MouseMove del Picture
Private Sub Picture1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
' Mostramos el Formulario desde el icono en el SysTray
Select Case (X / Screen.TwipsPerPixelX)
Case DOBLECLICK
    ' Usamos este evento para mostrar el formulario
    Visible = True
    SetFocus
Case CLICKDERECHO
    ' Usamos este evento para mostrar un Menu Emergente
    PopupMenu mnuEmergente
End Select
End Sub

' El menu Mostrar
Private Sub mnuShow_Click()
Visible = True
SetFocus
End Sub

' El menu Ocultar
Private Sub mnuHide_Click()
Visible = False
End Sub

' El menu Salir
Private Sub mnuExit_Click()
cancelar = False
Unload Me
End Sub

Para descargar este ejemplo hace clic aqui

Espero te sirva