Hola de nuevo,
bueno, veo que los interrogantes están ya en el propio código fuente, por eso no se soluciona con el juego de caracteres si ya llegan así.
También he visto que es una pregunta bastante planteada en la red y poco resuelta. Pero encontré un foro brasileño en donde un moderador encontró la forma de resolverlo (lo he probado y funciona perfecto)
http://scriptbrasil.com.br/forum/ind...howtopic=61259
Código:
Function BinaryToString(xBinary)
Dim Binary
Dim RS, LBinary
If VarType(xBinary)=8 Then Binary = MultiByteToBinary(xBinary) Else Binary = xBinary
Const adLongVarChar = 201
Set RS = CreateObject("ADODB.Recordset")
LBinary = LenB(Binary)
If LBinary>0 Then
RS.Fields.Append "mBinary", adLongVarChar, LBinary
RS.Open
RS.AddNew
RS("mBinary").AppendChunk Binary
RS.Update
BinaryToString = RS("mBinary")
Else
BinaryToString = ""
End If
Set RS=Nothing
End Function
Function MultiByteToBinary(MultiByte)
Dim RS, LMultiByte, Binary
Const adLongVarBinary = 205
Set RS = CreateObject("ADODB.Recordset")
LMultiByte = LenB(MultiByte)
If LMultiByte>0 Then
RS.Fields.Append "mBinary", adLongVarBinary, LMultiByte
RS.Open
RS.AddNew
RS("mBinary").AppendChunk MultiByte & ChrB(0)
RS.Update
Binary = RS("mBinary").GetChunk(LMultiByte)
End If
Set RS = Nothing
MultiByteToBinary = Binary
End Function
dim objXMLHTTP
Set objXMLHTTP = Server.CreateObject("Microsoft.XMLHTTP")
Url = "http://www.scriptbrasil.com.br/"
objXMLHTTP.Open "GET", URL, FALSE
objXMLHTTP.Send
sai=objXMLHTTP.responsebody
set objXMLHTTP=nothing
response.write BinaryToString(sai)
Úsalo de referencia para adaptarlo al tuyo o úsalo tal cual.
Un saludo
