Msflexgrid

[Neverhood]

No es algo sencillo, pero aquí lo tienes:

El código del FLEX:

Código:

Private Sub Flex1_KeyPress(KeyAscii As Integer)
    Dim LeftCel As Long, LeftFlx As Long
    Dim TopCel As Long, TopFlx As Long
    Dim WidthCel As Long, HeightCel As Long
    Dim Contenido As String
    Dim Fila As Long, Columna As Long

    If KeyAscii = vbKeyReturn Then
        Fila = Flex1.Row: Columna = Flex1.Col
        Contenido = Flex1.Text
        ContenidoAnterior = Flex1.Text
        If Fila > 0 And Columna = 1 Then 'solo si quieres limitar cual columna es editable, si no, elimina esta linea
            With Flex1
                LeftCel = .CellLeft
                TopCel = .CellTop
                WidthCel = .CellWidth
                HeightCel = .CellHeight
                LeftFlx = .Left
                TopFlx = .Top
                Contenido = .Text
                .Enabled = False
            End With

            With TxtDecim
                .Height = HeightCel
                .Width = WidthCel
                .Left = LeftCel + LeftFlx
                .Top = TopCel + TopFlx
                .Text = Contenido
                .Visible = True
                .SetFocus
            End With
        End If

        KeyAscii = 0
    End If
End Sub

Ahora el código del TEXT:

Código:

Private Sub TxtDecim_KeyPress(KeyAscii As Integer)
    Dim ContenidoText As String
    
    If KeyAscii = vbKeyReturn Then
        With TxtDecim
            ContenidoText = .Text
            .Visible = False
        End With
        With Flex1
            .Text = ContenidoText
            .Enabled = True
            .SetFocus
        End With
    End If
End Sub

Espero te sirva!!! Y cualquier duda, estoy a tus órdenes