Cita:
Iniciado por lebiatan123 
HOLA FOTO. NECESITO SU AYUDA. NO SE COMO HACER PARA RESTAURAR LA BASE DE DATOS DEL SISTEMA. ESTE CODIGO LO UTILIZO PARA RESPALDAR :
Y CUANDO RESPALDO ME SALE ESTE MENSAJE :
ADODC1
NO ES UNA CONTRASEÑA VALIDA...
...
GRACIAS. ESPERO ME PUEDAN A YUDAR PARA SOLUCIONAR EL MENSAJE ESE QUE ME SALE Y A RESTAURAR.
Bueno, me parece demasiado código para restaurar una base de datos. Con esta función puedes hacer copias y restauraciones de la BD, tenga o no password.
Código:
Public Function CopiaBDPwd(sOrigen As String, sDestino As String, Optional sPwd As String) As Boolean
' en Proyecto->Referencias: Microsof Jet and Replication objects 2.6 Library
Dim je As JRO.JetEngine
On Error GoTo hErr
Set je = New JRO.JetEngine
If Len(Dir$(sDestino)) Then Kill sDestino
If IsMissing(sPwd) Then sPwd = ""
je.CompactDatabase "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & sOrigen & _
";Jet OLEDB:Database Password=" & sPwd, "Data Source=" & sDestino & _
";Jet OLEDB:Database Password=" & sPwd
CopiaBDPwd = True
Exit Function
hErr:
MsgBox Err.Number & " - " & Err.Description
CopiaBDPwd = False
End Function
Para hacer la copia:
Código:
Private Sub HacerCopia_Click()
Dim b As Boolean
b = CopiaBDPwd(App.Path & "\bd1.mdb", App.Path & "\BackUp\Copia de bd1.mdb", "miContraseña")
If b Then
MsgBox "Copia realizada con éxito"
' ... instrucciones
Else
' otras instrucciones
End If
End Sub
Para restaurar llamamos a la misma función, pero invirtiendo el orden de las BDs.
Código:
Private Sub RestaurarCopia_Click()
Dim b As Boolean
b = CopiaBDPwd(App.Path & "\BackUp\Copia de bd1.mdb", App.Path & "\bd1.mdb", "miContraseña")
If b Then
MsgBox "Se restauró con éxito"
' ... instrucciones
Else
' otras instrucciones
End If
End Sub
Mira a ver si lo puedes adecuar a tus necesidades.
