leer archivos de un directorio en xlm y asp

[u_goldman]

Hola tonimoran, trata algo como esto:

Código ASP:

<&#37;
Function ArchivoEnArray(archivo, esteArray)
    Dim archivoExiste, i
    archivoExiste = false
    
    if isArray(esteArray) then
        for i = 0 to uBound(esteArray)
            if archivo = esteArray(i) then
                archivoExiste = true
                exit for
            end if
        next
    end if
    ArchivoEnArray = archivoExiste
End Function
 
 
 
Dim fso, folder, archivo, dir
'Aqui van los nombres de los archivos que no quieres mostrar
noArray = Array("index.asp", "imagenes.html", "subir.swf")
 
'Aqui va la ruta al folder
dir = Server.Mappath(".\unfolder")
Set fso = Server.CreateObject("Scripting.FileSystemObject")
Set folder = fso.GetFolder(dir)
 
Response.ContentType = "text/xml" 
Response.Write("<?xml version='1.0' ?>")
Response.write("<files>")
for each archivo in folder.files
    if not ArchivoEnArray(archivo.name, noArray) then
        Response.write("<files2>")
        Response.write(archivo.name)
        Response.write("</files2>")
    end if
next
Response.Write("</files>")
Set fso = Nothing
Set folder = Nothing
%>
 

Saludos