Leer archivo .ini

[JonathanB]

Saludos, puedes probar una clase que usaba hace bastante tiempo para leer archivos INI.

A tu proyeco agregale la referencia a Microsoft Scripting Runtime (Menú Proyecto>Referencias>Selecciona Microsoft Scripting Runtime).


Crea un modulo "Declaraciones"y añade el siguente código

Código vb:

Option Explicit
 
' API que recupera información de un archivo INI
' ==============================================
Public Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" ( _
    ByVal lpApplicationName As String, _
    ByVal lpKeyName As String, _
    ByVal lpDefault As String, _
    ByVal lpReturnedString As String, _
    ByVal nSize As Long, _
    ByVal lpFileName As String) As Long
  
' API que guarda información a un archivo INI
' ===========================================
Public Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" ( _
    ByVal lpApplicationName As String, _
    ByVal lpKeyName As Any, _
    ByVal lpString As Any, _
    ByVal lpFileName As String) As Long
 

Crea una nueva clase "ArchivoIni" y añade el siguiente código.

Código vb:

' =========================================================
' Jonathan Búcaro
' =========================================================
' Clase para el manejo de configuraciones por medio de
' archivos INI.
' =========================================================
' 25/09/2009 - Creación
' =========================================================
 
Option Explicit
 
Private m_Ruta As String
Private m_Nombre As String
Private m_Seccion As String
Private m_Llave As String
Private m_Valor As String
 
' Clase ArchivoINI
' =================
Private Sub Class_Initialize()
    m_Ruta = App.Path
    m_Nombre = ""
    m_Seccion = ""
    m_Llave = ""
    m_Valor = ""
End Sub
 
' Ruta donde se encuentra el Archivo INI
' ======================================
Public Property Get Ruta() As String
    Ruta = m_Ruta
End Property
 
Public Property Let Ruta(ByVal strValue As String)
    If Not Len(Trim(strValue)) = 0 Then
        m_Ruta = strValue
    End If
End Property
 
' Nombre del archivo INI
' ======================
Public Property Get Nombre() As String
    Nombre = m_Nombre
End Property
 
Public Property Let Nombre(ByVal strValue As String)
    If Not Len(Trim(strValue)) = 0 Then
        m_Nombre = strValue
    End If
End Property
 
' Sección del Archivo INI donde se encuentra la información
' =========================================================
Public Property Get Seccion() As String
    Seccion = m_Seccion
End Property
 
Public Property Let Seccion(ByVal strValue As String)
    If Not Len(Trim(strValue)) = 0 Then
        m_Seccion = strValue
    End If
End Property
 
' Sección del Archivo INI donde se encuentra la información
' =========================================================
Public Property Get Llave() As String
    Llave = m_Llave
End Property
 
Public Property Let Llave(ByVal strValue As String)
    If Not Len(Trim(strValue)) = 0 Then
        m_Llave = strValue
    End If
End Property
 
' Valor de la Llave que se encuentra dentro de una Sección en un Archivo INI
' ==========================================================================
Public Property Get Valor() As String
    Valor = m_Valor
End Property
 
Public Property Let Valor(ByVal strValue As String)
    If Not Len(Trim(strValue)) = 0 Then
        m_Valor = strValue
    End If
End Property
 
' Guarda la información al Archivo INI
' ====================================
Public Function GrabarLlave() As Boolean
    Dim lRet As Long
    Dim strPath As String
    Dim fso As FileSystemObject
    
    Set fso = New FileSystemObject
    
    ' Verificar que exista el Directorio
    If Not fso.FolderExists(m_Ruta) Then GoTo ErrHandler
    
    ' Armar la ruta completa, incluyendo el nombre del Archivo
    If Right(m_Ruta, 1) = "\" Then
        strPath = m_Ruta & m_Nombre
    Else
        strPath = m_Ruta & "\" & m_Nombre
    End If
 
    ' Grabar la información al Archivo INI
    lRet = WritePrivateProfileString(m_Seccion, m_Llave, m_Valor, strPath)
    If lRet = 0 Then GoTo ErrHandler
    
    If Not fso Is Nothing Then Set fso = Nothing
    GrabarLlave = True
    
    Exit Function
    
ErrHandler:
    If Not fso Is Nothing Then Set fso = Nothing
    GrabarLlave = False
End Function
 
' Borra una Llave dentro de una Sección del Archivo INI
' =====================================================
Public Function BorrarLlave() As Boolean
    Dim lRet As Long
    Dim strPath As String
    Dim fso As FileSystemObject
    
    Set fso = New FileSystemObject
    
    ' Verificar que se hayan establecido los valores Sección y Llave
    If Len(Trim(m_Seccion)) = 0 Then GoTo ErrHandler
    If Len(Trim(m_Llave)) = 0 Then GoTo ErrHandler
    
    ' Verificar que exista el Directorio
    If Not fso.FolderExists(m_Ruta) Then GoTo ErrHandler
    
    ' Armar la ruta completa, incluyendo el nombre del Archivo
    If Right(m_Ruta, 1) = "\" Then
        strPath = m_Ruta & m_Nombre
    Else
        strPath = m_Ruta & "\" & m_Nombre
    End If
    
    ' Borra una llave dentro de una Sección del Archivo INI
    lRet = WritePrivateProfileString(m_Seccion, m_Llave, vbNullString, strPath)
    If lRet = 0 Then GoTo ErrHandler
    
    If Not fso Is Nothing Then Set fso = Nothing
    BorrarLlave = True
    
    Exit Function
    
ErrHandler:
    If Not fso Is Nothing Then Set fso = Nothing
    BorrarLlave = False
End Function
 
' Borra una Sección del Archivo INI
' =================================
Public Function BorrarSeccion() As Boolean
    Dim lRet As Long
    Dim strPath As String
    Dim fso As FileSystemObject
    
    Set fso = New FileSystemObject
    
    If Len(Trim(m_Seccion)) = 0 Then GoTo ErrHandler
    
    ' Verificar que exista el Directorio
    If Not fso.FolderExists(m_Ruta) Then GoTo ErrHandler
    
    ' Armar la ruta completa, incluyendo el nombre del Archivo
    If Right(m_Ruta, 1) = "\" Then
        strPath = m_Ruta & m_Nombre
    Else
        strPath = m_Ruta & "\" & m_Nombre
    End If
    
    ' Borra una seccion del Archivo INI
    lRet = WritePrivateProfileString(m_Seccion, vbNullString, vbNullString, strPath)
    If lRet = 0 Then GoTo ErrHandler
    
    If Not fso Is Nothing Then Set fso = Nothing
    BorrarSeccion = True
    
    Exit Function
    
ErrHandler:
    If Not fso Is Nothing Then Set fso = Nothing
    BorrarSeccion = False
End Function
 
' Lee la información de una Llave dentro de una Sección del Archivo INI
' =====================================================================
Public Function LeerLlave() As Boolean
    Dim lRet As Long
    Dim sDefault As String
    Dim sRetValue As String * 256
    Dim strPath As String
    Dim fso As FileSystemObject
    
    Set fso = New FileSystemObject
    
    ' Verificar que se hayan establecido los valores Sección y Llave
    If Len(Trim(m_Seccion)) = 0 Then GoTo ErrHandler
    If Len(Trim(m_Llave)) = 0 Then GoTo ErrHandler
    
    ' Verificar que exista el Directorio
    If Not fso.FolderExists(m_Ruta) Then GoTo ErrHandler
    
    ' Armar la ruta completa, incluyendo el nombre del Archivo
    If Right(m_Ruta, 1) = "\" Then
        strPath = m_Ruta & m_Nombre
    Else
        strPath = m_Ruta & "\" & m_Nombre
    End If
    
    sDefault = ""
    lRet = GetPrivateProfileString(m_Seccion, m_Llave, sDefault, sRetValue, Len(sRetValue), strPath)
    
    If lRet = 0 Then GoTo ErrHandler
 
    Valor = Left(sRetValue, lRet)
    LeerLlave = True
    If Not fso Is Nothing Then Set fso = Nothing
    
    Exit Function
    
ErrHandler:
    If Not fso Is Nothing Then Set fso = Nothing
    Valor = sDefault
    LeerLlave = False
End Function
 

Para utilizarlo:

Código vb:

Dim Contenido as String
 
' Crear el objeto
Private Configuracion As ArchivoINI
Set Configuracion = New ArchivoINI
 
With Configuracion
    ' Nombre del archivo. Si no se especifica ruta, tomara default el app.path
    .Nombre = "miArchivo.ini"
 
    .Seccion = "miSeccion"
    .Llave = "miLlave"
 
    ' Si no existe la llave dentro de la sección, generar error 380
    If Not .LeerLlave Then Err.Raise 380, "miLlave"
    Contenido = .Valor
 
End With
 
' Limpiar el objeto
If Not Configuracion Is Nothing Then Set Configuracion = Nothing
 

Recuerda que un archivo INI esta compuesto por secciones y llaves

Ejemplo de sección:
[Seccion1]
[ConfigBD]

Ejemplo de Sección y Llave:
[ConfigBD]
Servidor=125.2.204.52
Usuario=sa

Espero que te sea de utilidad.