Subir Imagen a una base de datos

[AlZuwaga]

Bueno, primero bajate el xElUpload desde http://www.aspfacil.com/codigo/xelupload.zip , y colocá el archivo xelupload.asp (los otros no son necesarios) en la misma carpeta que el ASP que va a hacer la subida de la imagen y va a guardar la noticia en la BD.

Luego, en ese ASP, hacés más o menos esto:

Código:

<!--#include file="xelupload.asp"-->
<%
' Subida de imágenes
set objUpload = new xelUpload
objUpload.Upload()

'Solo se instancia el objeto si se ha subido al menos una imagen, de lo contrario da errores
If objUpload.Ficheros.Count > 0 then
	'accedemos al fichero por su nombre en el formulario
	Set objFich = objUpload.Ficheros("file")
	
	'La guardo en el directorio images_noticias, con la fecha y hora de hoy, completa, como nombre:
	'lo siguiente es el nombre original del archivo:
	Nombre = Split(objFich.Nombre, ".")
	'y aquí obtengo la extensión del archivo original:
	Extension = Nombre(Ubound(Nombre))
	'Compongo el nuevo nombre de archivo para evitar duplicados y le agrego la extensión:
	strNombreFichero = Year(Now()) & Month(Now()) & Day(Now()) & Hour(Now()) & Minute(Now()) & Second(Now()) & "." & Extension
	'finalmente, lo guardo
	objFich.GuardarComo strNombreFichero, Server.MapPath("/images_noticias/")
End if

'ahora, almaceno en variables los datos a guardar en la BD
'IMPORTANTE: No se puede usar request.form. En su lugar, se usa el método Form de la clase objUpload
fecha = Replace(objUpload.Form("fecha"), "'", "''")
titulo = Replace(objUpload.Form("titulo"), "'", "''")
copete = Replace(objUpload.Form("copete"), "'", "''")
noticia = Replace(objUpload.Form("noticia"), "'", "''")

' hacés tu conexión a la BD...
'luego, insertás todo:
SQL = "INSERT INTO Noticias (fecha, titulo, copete, notica, imagen) VALUES ('"& fecha &"', '" & titulo & "', '" & copete & "', '" & noticia & "', '" & strNombreFichero & "')"
oConn.Execute (SQL)
%>

Saludos