Como enviar pulsaciones de teclas con Sendmessage (VB)

[coadlr]

Hola que tal.

Actualmente utilizo sendkey para realizar ciertas operaciones con una aplicacion de Java, pero la gran limitante de que solo se puede hacer con la ventana activa me ha traido muchos problemas; encontre que esto se puede hacer con Sendmessage, no tengo mucho conocimiento de programacion, pero por mas que he leido e intentado, no he podido realizar esto....

Actualmente tengo...

AppActivate "Titulo de la aplicacion"

SendKeys "%(VRI)", True 'Enviar combinacion ALT + R + I
SendKeys "{TAB 3}", True 'TAB 3 veces
SendKeys "{DOWN 4}", True 'DOWN 4 veces
SendKeys "Print SR-24", True 'Enviar texto Print SR-24
SendKeys "{ENTER}", True ' Enter

si por alguna razon se desactiva la pantalla pues se siguen enviando las pulsaciones a la nueva ventana activa, y eso es lo quiero evitar.


con Sendmessage llevo:

Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long

Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long

Const WM_SETTEXT = &HC
Const WM_KEYDOWN = &H100

Sub AbrirReporte()

Dim hwnd As Long
hwnd = FindWindow("sunawtframe", vbNullString)

SendMessage(hwnd ... y hasta aqui

he visto algunos ejemplos con WM_Keydown, WM_Settext pero no he logrado hacer nada....

Asi que necesito hacer lo mismo que hace sendkeys con sendmessage... Si alguien puediera orientarme, se lo agradeceria.

[totigo]

Para ello debes hacer uso de la API SendMessageBynum .

La cual recibe el num ascii, en este ejemplo estoy enviando el mensaje "hola mundo" a un cuadro de texto y seguidamente envio la tecla ENTER (13) a ese cuadro de texto.

Analiza el ejemplo, cualquier duda estaré atento!

Código vb:

Private Declare Function SendMessage Lib "user32" Alias _
        "SendMessageA" (ByVal hwnd As Long, ByVal wMsg _
        As Long, ByVal wParam As Long, lParam As Any) As Long
 
Private Declare Function SendMessageBynum Lib "user32" Alias _
        "SendMessageA" (ByVal hwnd As Long, ByVal wMsg _
        As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
 
Private Declare Function FindWindowEx Lib "user32" Alias "FindWindowExA" ( _
    ByVal hWnd1 As Long, _
    ByVal hWnd2 As Long, _
    ByVal lpsz1 As String, _
    ByVal lpsz2 As String) As Long
 
Private Declare Function FindWindow Lib "user32" Alias "FindWindowA" ( _
    ByVal lpClassName As String, _
    ByVal lpWindowName As String) As Long
 
' La constante:
Private Const WM_CHAR = &H102
Private Const WM_SETTEXT = &HC
 
' Hwnd de la ventana
Dim ret As Long
Dim retV  As Long
 
 
Private Sub Command1_Click()
    retV = FindWindow("nomVentana", vbNullString)
    ret = FindWindowEx(retV, 0, "nomControlTextBox", vbNullString)
    Call SendMessage(ret, WM_SETTEXT, 0, ByVal CStr("hola mundo..."))
    Call SendMessageBynum(ret, WM_CHAR, 13, ByVal 0)
End Sub
 

[coadlr]

Muchisimas gracias!!!!!, justo lo que buscaba.