duda sobre organizar elementos

[charlygarcia]

hola a todos

tengo en un programa un arreglo (@elementos) con el siguiente formato:

1::pedro::
2::julio::
3::alvaro::
4::andres::
5::zapata::
6::yamile::

como puedo crear un arreglo (@elementos2) que tenga los elementos arreglados por la segunda columna en orden alfabetico ?

de la siguiente manera:


3::alvaro::
4::andres::
2::julio::
1::pedro::
6::yamile::
5::zapata::


Gracias por la colaboracion (en perl )

[monoswim]

Una pregunta, no sería mejor tenés un hash ? de la forma

my %elementos = (1 => 'pedro', 2 => 'julio'...);

así puedes fácilmente ordenarlo por nombre o por valor...

Espero que te sirva

Saludos

[jferrero]

Usando una transformada de Schwartz:

Código:

#!/usr/bin/perl
use warnings;
use strict;

my @elementos = qw(
    1::pedro::
    2::julio::
    3::alvaro::
    4::andres::
    5::zapata::
    6::yamile::
);

my @elementos2
    =  map  { $_->[1]                 }
       sort { $a->[0] cmp $b->[0]     }
       map  { [ (split q{:})[2], $_ ] }
       @elementos;

print "@elementos\n";
print "@elementos2\n";

Sale:

Código:

1::pedro:: 2::julio:: 3::alvaro:: 4::andres:: 5::zapata:: 6::yamile::
3::alvaro:: 4::andres:: 2::julio:: 1::pedro:: 6::yamile:: 5::zapata::

[charlygarcia]

gracias jferrero, se nota que eres un gran experto en esto de perl, tratare de probar el codigo que das, y nuevamente te agradezco mucho.

Pero te hago otra pregunta:



veo que en este codigo empleas dos modulos, son estrictamente necesarios ?

use warnings;
use strict;

Como lo harias sin modulos ?

[charlygarcia]

jferrero:

en realidad eres un gran programador y respondes las dudas, sin plantear nuevas dudas, el codigo que me diste me funciono de maravilla, ademas me enseñaste algo nuevo sobre organización, algo que no sabia que existia, la

transformada de Schwartz, no tengo palabras para agradecerte nuevamente, tal vez la unica manera sea demostrarte mi admiracion publica por ser tan excelente programador, mi programa funciona correctamente gracias a tu ayuda.

Carlos A

[monoswim]

use warnings;
use strict;

Sin esos módulos te funcionaría igual, pero es preferible usarlos, el strict es para estar obligado a declarar correctamente las variables con my...entre otras cosas...

http://perlenespanol.baboonsoftware....se_strict.html

Más info...

Saludos

[jferrero]

Iniciado por charlygarcia

el codigo que me diste me funciono de maravilla, ademas me enseñaste algo nuevo sobre organización, algo que no sabia que existia, la transformada de Schwartz

Si no entiendes algo del código, pregúntalo. Pero no lo uses tal cual te lo he dado, porque entonces no podrás aprovecharlo para otros casos que se te presenten en el futuro.

[charlygarcia]

Hola a todos

El codigo me funciono muy bien (gracias) pero tengo una pregunticas:

my @elementos2
= map { $_->[1] }
sort { $a->[0] cmp $b->[0] }
map { [ (split q{:})[2], $_ ] }
@elementos;


el primer map dice que vamos a trabajar con la segunda columna si o no ?

el segundo map usa un split con split q{:})[2] quiere decir que se parte por donde encuentre '::' ?

Mejor dicho ya me funciono, pero si jferrero pudiera regalarnos una explicadita seria muy bueno para poder utilizarlo luego en otras cirscunstancias.


Gracias

[jferrero]

Código:

my @elementos2
    =  map  { $_->[1]                 }
       sort { $a->[0] cmp $b->[0]     }
       map  { [ (split q{:})[2], $_ ] }
       @elementos;

Hay que leer la transformada de abajo hacia arriba.

Los @elementos son pasados, uno a uno, al conjunto map-sort-map.

El primer map (empezando por abajo), lo que hace es mapear cada elemento ($_) en algo muy extraño: un array anónimo ([]) que contiene dos elementos. El segundo elemento de este array es el propio elemento $_. El primer elemento es algo más complicado.

Ese primer elemento, lo que hace es un split() usando ':' como separador. El resultado de un split es una lista de valores. Esos valores quedan encerrados entre los paréntesis, convirtiéndolos en un "array". De ese array ficticio, solo nos quedamos con el tercer elemento (2). Es decir, nos quedamos con el tercer campo de cada elemento $_, que son los nombres por los que queremos ordenar.

Cada mapeo resulta entonces en algo como

Código:

[ 'pedro', '1::pedro::' ]

El siguiente paso es pasar todos estos nuevos arrays al sort. En el sort, se reciben en $a y $b los elementos a comparar, y nosotros tenemos que decir cómo se comparan esos elementos.

Como $a y $b son arrays anónimos, no podemos compararles tal cual. Solo queremos comparar el primer elemento de cada array. Por eso escribimos

Código:

$a->[0]

La indirección '->' nos mete dentro del array anónimo referenciado por $a. Y de ese array, nos quedamos con el primer elemento ([0]). Que son, justamente, los nombres.

La comparación entre esos dos nombres, la haremos alfanuméricamente, por lo que usaremos 'cmp'.

El resultado después del sort son todos los arrays anónimos, ordenados por los nombres.

Ahora hay que hacer el proceso inverso del primer map, con un segundo map. Este map recibe los arrays anónimos, en el orden que nos interesa, pero de los que solo nos interesa el segundo elemento ([1]) que, al final, eran los elementos originales de los que partíamos.

Uno a uno, se van guardando en @elemento2.