Foros del Web » Programando para Internet » ASP Clásico »

Agregar campos nuevos en el mismo form segun seleccion

Estas en el tema de Agregar campos nuevos en el mismo form segun seleccion en el foro de ASP Clásico en Foros del Web. Saludos a todos, les explico: Tengo que hacer un formulario donde tengo tres select, donde el tercero es diferente para cada una de las opciones ...
  #1 (permalink)  
Antiguo 28/04/2005, 14:23
 
Fecha de Ingreso: marzo-2005
Mensajes: 7
Antigüedad: 19 años, 2 meses
Puntos: 0
Agregar campos nuevos en el mismo form segun seleccion

Saludos a todos, les explico:
Tengo que hacer un formulario donde tengo tres select, donde el tercero es diferente para cada una de las opciones del segundo.
En pocas palabras que el formulario me cargue un nuevo campo de entrada segun la seleccion del segundo select.
No tengo idea de como hacerlo , les agradezco su ayuda y si tienen un ejemplito por ahy mejor aun.
Muchas gracias.
  #2 (permalink)  
Antiguo 28/04/2005, 14:44
 
Fecha de Ingreso: abril-2005
Mensajes: 92
Antigüedad: 19 años, 1 mes
Puntos: 0
por lo que entendi de lo que escribistes quieres hacer un select de otro select o algo asi... trata de explicar mejor para poder tener mejor idea de que ejemplo poner...

Saludos
  #3 (permalink)  
Antiguo 28/04/2005, 15:32
 
Fecha de Ingreso: marzo-2005
Mensajes: 7
Antigüedad: 19 años, 2 meses
Puntos: 0
Tres select
1= año (no hay problema)
2= criterio1 (rango de edades, universidades, estado, etc...)
3= si es edades mostrar rango disponibles para seleccion, si el 2 es universidades mostrar las univ. registradas, estados mostrar estados de venezuela)

todo esto para seleccion para llamar a un query que espera estos tres parametros.

espero que ahora se entienda .... de verdad no tengo ni idea como hacerlo...
  #4 (permalink)  
Antiguo 28/04/2005, 16:57
Avatar de wamoretti  
Fecha de Ingreso: febrero-2002
Ubicación: Lima
Mensajes: 34
Antigüedad: 22 años, 4 meses
Puntos: 0
Tengo un Ejemplo de tres combos dinamicos:
Departamento, Povincia y Distrito

las tablas son:
TDepartamento
coddepar char(2)
descripcion varchar(50)
TProvincia
coddepar char(2)
codprovin char(2)
descripcion varchar(50)
TDistrito
coddepar char(2
codprovin char(2
coddistri char(2
descripcion varchar(50)
Aquí va el código

localidad.asp
<%
Function CadenaODBC()
servidor = "10.100.9.75"
basedato = "PACA"
usuario = "u_paca"
password = "paca"
CadenaODBC = "Provider=SQLOLEDB.1;User ID=" & usuario & ";Password=" & password & ";Initial Catalog=" & basedato & ";Data Source=" & servidor & ";Connect Timeout=15;"
End Function

Response.Expires = -2000
coddepar = Request("selDep")
codprovin = Request("selPro")
coddistri = Request("selDis")
foco = Request("hdnFoco")
Set Cn = Server.CreateObject("ADODB.Connection")
Set Rs = Server.CreateObject("ADODB.Recordset")
Cn.Open CadenaODBC%>
<html>
<head>
<title>Localidad</title>
<style>
body {background-color: #E9F3FF;}
td {font: normal 11px Tahoma, Arial; color: #003399;}
.text {font: normal 11px Tahoma, Arial; color: #003399; background-color: #FFFFFF; border: 1px solid #003399;}
</style>
<script language="Javascript">
function act_combo(obj, objNext){
objNext.selectedIndex = 0
if (obj.value == "")
frmLocalidad.hdnFoco.value = obj.name
else
frmLocalidad.hdnFoco.value = objNext.name
frmLocalidad.submit()
}
</script>
</head>
<body topmargin=0 leftmargin=0 <%If foco <> "" Then%>onload="frmLocalidad.<% = foco%>.focus()"<%End If%>>
<form name="frmLocalidad" method="post" action="localidad.asp">
<input type="hidden" name="hdnFoco">
<table width=400 align=center cellspacing="0" cellpadding="1">
<tr>
<td>Departamento</td>
<td>
<select name="selDep" id="Departamento" class="text" onchange="act_combo(this, selPro)" style="width: 200px">
<option value="">--</option><%
sSql = "SELECT * FROM TDepartamento ORDER BY descripcion"
Rs.Open sSql, Cn
Do Until Rs.EOF%>
<option value="<%= Rs("coddepar") %>"<%If coddepar = Rs("coddepar") Then%> selected<%End If%>><%= Trim(Rs("descripcion")) %></option><%
Rs.MoveNext
Loop
Rs.Close%>
</select></td>
</tr>
<tr>
<td>Provincia</td>
<td>
<select name="selPro" id="Provincia" class="text" onchange="act_combo(this, selDis)" style="width: 200px">
<option value="">--</option><%
If coddepar <> "" Then
sSql = "SELECT * FROM TProvincia WHERE coddepar = '" & coddepar & "' ORDER BY descripcion"
Rs.Open sSql, Cn
Do Until Rs.EOF%>
<option value="<%= Rs("codprovin") %>"<%If codprovin = Rs("codprovin") Then%> selected<%End If%>><%= Trim(Rs("descripcion")) %></option><%
Rs.MoveNext
Loop
Rs.Close
End If%>
</select></td>
</tr>
<tr>
<td>Distrito</td>
<td>
<select name="selDis" id="Distrito" class="text" style="width: 200px">
<option value="">--</option><%
If codprovin <> "" Then
sSql = "SELECT * FROM TDistrito WHERE coddepar = '" & coddepar & "' AND codprovin = '" & codprovin & "' ORDER BY descripcion"
Rs.Open sSql, Cn
Do Until Rs.EOF%>
<option value="<%= Rs("coddistri") %>"<%If coddistri = Rs("coddistri") Then%> selected<%End If%>><%= Trim(Rs("descripcion")) %></option><%
Rs.MoveNext
Loop
Rs.Close
End If%>
</select></td>
</tr>
</table>
</form>
</body>
</html><%
Cn.Close
Set Rs = Nothing
Set Cn = Nothing
%>


Última edición por wamoretti; 28/04/2005 a las 18:41
Atención: Estás leyendo un tema que no tiene actividad desde hace más de 6 MESES, te recomendamos abrir un Nuevo tema en lugar de responder al actual.
Respuesta




La zona horaria es GMT -6. Ahora son las 11:42.