Ayuda con Validar

vamp_02 · #1 (**permalink**) 30/01/2003, 18:11

Hola a todos, tengo una duda, tengo un formulario, el cual me pide en uno de sus textbox, un codigo que el codigo del cliente, ahora, mi consulta se supone en teoria, que el usuario, no sabe si el cliente esta ingresado en la tabla del maestro de clientes, como puedo hacer para que cuando el usuario ingrese el codigo del cliente, asp lo busque primero en la tabla, y despues si esta que pase a la otra pagina, pero si no esta, que le diga al usuario que hay que crearlo en el maestro.

Si alguien me puede ayudar. gracias

Hotaru · #2 (**permalink**) 30/01/2003, 18:30

hahahahaha!!!!... ashis!!... no se si te entendi bien pero:

quieres que al momento de que el usuario introduzca un codigo, cheque en una tabla X si esta dado de alta y en caso de que no esté le mande un mensaje de que hay que darlo de alta en la tabla X? ...

Weno de ser asi...

SQL = "select codigo_usuario from TablaX where Codigo_usuario= ' "& Request("codigo capturado") &" ' "
'Ejecutas la consulta
set rs=Conn.Execute(SQL)
if rs.EOF then 'Quiere decir que el codigo no esta en la tablaX
Response.Write "Tiene que darse de alta antes en la TablaX"
else
Response.Redirect ("paginaquesigue.asp")
end if

Si entendi bien seria algo como eso...

Saludos!!!

PD: Si te puedo ayudar en algo más ps me dices...

vamp_02 · #3 (**permalink**) 31/01/2003, 05:23

Hotaru, primero que nada, muchas gracias por tu disposicion, ahora es algo parecido lo que quiero hacer.

Es:

un form, con tres textbox, uno de ellos es el Id_Clie, el cual, cuando lo ingreso, y doy enter, vaya priemero a la tabla, verifique si el cliente existe en el maestro, si existe, que pase, si no que me devuelva a la pagina donde estaba, y que me marque el error.

Eso

Si me puedes ayudar

Gracias

Hotaru · #4 (**permalink**) 31/01/2003, 11:57

Holap!...

Sip mira...

lo que puedes hacer es algo como esto:
<% @Language=VBScript %>
<%
Option Explicit
Dim oConn, rs, SQL, Clte_ID, Acceso, focus
'Acceso es para ver si el CLTE_ID esta en la tabla
'Focus es para que en caso de ser la primera vez que entra
'el foco se vaya al primer campo de captura, pero cuando ya
'esta validado el CLTE_ID entonces que se vaya al siguiente.
Clte_ID=Replace(UCASE(Request("Clte_ID")),"'","") 'Para prevenir el caso de que
'te capturen sentencias SQL en el Text
if Clte_ID="" then
focus="document.form1.Clte_ID.focus();"
else
'checamos que exista....
Set oConn = Server.CreateObject("ADODB.Connection")
oConn.Open "DSN=DNSxx;database=xx;UID=x;PWD=xxx;"
SQL = "select id_cli from tablaX where id_cli='"& Clte_ID & "'"
'Ejecutamos consulta
set rs=oConn.Execute(SQL)
if rs.EOF then 'No existe ese usuario
Response.Write("<b>Lo siento, no existe ese usuario...</b>")
Acceso="Denied"
focus="document.form1.Clte_ID.focus();"
else
Acceso="OK"
focus="document.form2.Clte_ID.focus();"
End if
End if
MostrarFormulario

Sub MostrarFormulario
%>
<link rel="stylesheet" href="menu/ccs23.css" type="text/css">
<BODY bgcolor="#0000cc" onload="<% =focus %>">
<table width="147" height="182" cellspacing="0" cellpadding="0" border="0" bgcolor="#0000">
<table width="128" bgcolor="#999999" align="center" height="170">
<tr>
<td width="164" align="center">
<% if Clte_ID="" or Acceso="Denied" then %>
<form name="form1 " method=post action="Form1.asp">
ID de Usuario:<br>
<input type=Text name="Clte_ID" maxlength="6" size="8" >
<br>
<input type=submit value="Continuar" name="submit"> </form>
<% elseif Clte_ID<>"" and Acceso="OK" Then %>
<form name="form2" method=post action="OtraPag.asp" > <br>ID de Usuario:<br> <input type=Text name="Clte_ID" maxlength="6" size="8" class="textousuario" value="<% =Clte_ID %>" ReadOnly OnFocus="document.form2.otro1.focus();"> <br>
Otro campo1 : <br>
<input type=Text name=otro1 maxlength="10" size="7" class="textopassword" >
<br>
Otro campo2 : <br>
<input type=Text name=otro2 maxlength="10" size="7" class="textopassword" >
<br><br>
<input type=submit value="Continuar2" name="submit" class="textonegro" >
</form>
<% End if %>
</td>
</tr>
</table>
</body>
<%
End Sub 'MostrarFormulario
%>

Ya lo probé y si funciona, solo sustituye la conexión por la que acceda a tu tabla... espero que te sirva...

SALUDOS!!!

PD: Si quieres que te explique algo me avisas...