Decodificar URL

[TomaHawkk]

Hola a todos,

tengo una página asp que lee información de una biblioteca de documentos de Sharepoint.

El problema está en que cuando obtengo la Url del documento y realizo un Response.Write de la misma, me aparece con caracteres raros: %20 en lugar de un espacio, etc...

Buscando por internet lo único que encuentro es la función "Server.Urlencode" pero lo que necesito es lo contrario. En javascript es "unescape" pero necesito una función de servidor no de cliente.

Espero puedan ayudarme, gracias!
Un saludo.

[trasgukabi]

replace("%20"," ") o
replace("%20"," ")
%3A --> :
%2F --> /
%2E --> .
%3F --> ?
.
.
.
Igual hay algo mejor....

[TomaHawkk]

Hola,

me aparecen muchos más que el espacio, acentos y otros caracteres, no puedo saber todos los que son.

Un saludo

[trasgukabi]

' An inverse to Server.URLEncode
function URLDecode(str)
dim re
set re = new RegExp

str = Replace(str, "+", " ")

re.Pattern = "%([0-9a-fA-F]{2})"
re.Global = True
URLDecode = re.Replace(str, GetRef("URLDecodeHex"))
end function

' Replacement function for the above
function URLDecodeHex(match, hex_digits, pos, source)
URLDecodeHex = chr("&H" & hex_digits)
end function

[trasgukabi]

purpose:

The URLDecode function decodes a URL encoded string back into the original text.

syntax:

string = URLDecode(encodedstring)

example usage:

<% = URLDecode( Server.URLEncode( "@ can't find ... that & this?" ) ) %>

source code:

Código:

<%
Private Function URLDecode(byVal encodedstring)
	Dim strIn, strOut, intPos, strLeft
	Dim strRight, intLoop
	strIn  = encodedstring : strOut = _
		 "" : intPos = Instr(strIn, "+")
	Do While intPos
		strLeft = "" : strRight = ""
		If intPos > 1 then _
			strLeft = Left(strIn, intPos - 1)
		If intPos < len(strIn) then _
			strRight = Mid(strIn, intPos + 1)
		strIn = strLeft & " " & strRight
		intPos = InStr(strIn, "+")
		intLoop = intLoop + 1
	Loop
	intPos = InStr(strIn, "%")
	Do while intPos
		If intPos > 1 then _
			strOut = strOut & _
				Left(strIn, intPos - 1)
		strOut = strOut & _
			Chr(CInt("&H" & _
				mid(strIn, intPos + 1, 2)))
		If intPos > (len(strIn) - 3) then
			strIn = ""
		Else
			strIn = Mid(strIn, intPos + 3)
		End If
		intPos = InStr(strIn, "%")
	Loop
	URLDecode = strOut & strIn
End Function
%>