¿Hacer funcionar el xelupload?

[Julcar]

Hola, agradezco a gorka 22 por recomendarme el xelupload. Lo subí a Somee y cuando llama a las páginas, éstas se cargan correctamente, sin embargo, cuando intento subir el archivo al servidor, carga normalmente la página del uptest.asp, pero cuando ingreso al FTP o al filemanager de mi web, no veo ninguno de los archivos que subí, ya puse carpetas como uploads e images pero no logro ver los archivos.

Puse una página que llama a la base de datos en la que se guarda el fichero pero tampoco aparece, ¿qué puedo hacer?

[Myakire]

pero cuando ingreso al FTP o al filemanager de mi web, no veo ninguno de los archivos que subí
...
una página que llama a la base de datos en la que se guarda el fichero

a ver vamos a ponernos de acuerdo .... el archivo que subes al servidor ¿se guarda físicamente en el directorio o en algún campo de la BD?

[Julcar]

El proceso es así: Cuando subes el archivo mediante el formulario, éste se guarda dentro de una carpeta llamada imagenes, y el nombre del archivo se guarda en la Base de datos, el nombre del archivo debería aparecer tanto en la base de datos como en el disco duro del servidor, pero en ninguno aparece.

[gorka_22]

Buenas, agradezco tu agradecimiento (que redundancia). Un par de cosas, la carpeta donde se guardan los archivos subidos, tiene permisos de escritura? Esta es mi, siempre, mayor lacra a la hora de subir archivos, nunca recuerdo de darle permisos de escritura y me da error. Si no es esto, que error te da? O no te de error?

[Julcar]

La carpeta tiene los permisos de escritura, pues si no me diera error. Lo que pasa es que ¡NO SE CARGA NINGÚN ARCHIVOOOOOOO!!!!

Y necesito que se suban los archivos y aparezcan dentro de la carpeta del servidor, no solo de palabra dentro la página uptest.asp.

[Myakire]

Sería útil ver el segmento de código que supuestamente sube el archivo, en una de esas no tienes el obj_xelUpload.Upload()

[AlZuwaga]

Guarda que hay un comentario que hay que eliminar en el xelupload para que funcione... ¿revisaste eso?

[Julcar]

ah si, pero cuál es ese comentario??

[gorka_22]

postea el codigo que has utilizado y nos será más util ver donde puede estar el fallo. Postea el form para subir el archivo y el que hace el upload.

[AlZuwaga]

Iniciado por Julcar

ah si, pero cuál es ese comentario??

Leíste el código? Incluyendo las partes comentadas que en castellano lo explican?

[Myakire]

Si no postea el código, solo estamos adivinando, hasta que no lo haga no hay nada que hacer

[Julcar]

Éste es el código del index.htm

<form action="recibir.asp" method="post" enctype="multipart/form-data">
Nombre: <input type="text" name="nombreusuario" size="20"><br />
Edad: <input type="text" name="edad" size="5"><br />
Fichero: <br />
<input type="file" name="fichero"><br />
<input type="submit" value="Enviar">
</form>

Éste es el código de la página recibir.asp

<!--#include file="xelupload.asp"-->
<%
Dim objUpload, objFich, strNombreFichero
Dim strNombre, strEdad

'Creamos el objeto
set objUpload = new xelUpload

'Recibimos el formulario
objUpload.Upload()

'Mostramos total de ficheros recibidos
Response.Write ( objUpload.Ficheros.Count & " ficheros recibidos.")

'Mostramos los campos del formulario de texto:
Response.Write ("<p>Tu nombre es " & objUpload.Form("nombreusuario") & "<br>")
Response.Write ("<p>Tu edad es " & objUpload.Form("edad") & "<br>")

'Y ahora mostramos los datos del fichero enviado:
'Lo sacamos a una variable por comodidad
set objFich = objUpload.Ficheros("fichero")

Response.Write ("<p>" & objFich.Nombre & "<br>")
Response.Write("Tamaño: " & objFich.Tamano & "<br>")
Response.Write("Tipo de contenido: " & objFich.TipoContenido & "</p>")

'Guardamos el fichero, con su nombre, en el directorio
'en el que se encuentra esta página

objFich.Guardar(Server.MapPath("."))

'Y guardamos una copia, con nombre "subido.bin"

objFich.GuardarComo("subido.bin", Server.MapPath("."))

'Abrimos una conexión a una base de datos
Dim oConn, rs, SQL

set oConn = Server.CreateObject("ADODB.Connection")
set rs = Server.CreateObject("ADODB.Recordset")

'Nos conectamos con un DSN
oConn.Open "DSN=Pruebas"

'Y abrimos la tabla Datos
SQL = "SELECT * FROM Datos"

'Abrimos el Recordset con cerrojo 2 (adLockPessimiestic)
'que permite modificaciones

rs.Open SQL, oConn, 0, 2

'Añadimos un nuevo registro
rs.AddNew

rs.Fields("nombre") = objUpload.Form("nombreusuario")
rs.Fields("edad") = objUpload.Form("edad")

'Guardamos el contenido del fichero en la base de datos:
'el nombre del fichero, su tipo
rs.Fields("nombrefichero") = objFich.Nombre
rs.Fields("contenido") = objFich.TipoContenido

'y los datos binarios
objFich.GuardarBD rs.Fields("datos")

rs.Update
rs.Close

Response.Write("Fichero guardado en base de datos.")

'Limpiamos objetos
set oFich = nothing
set objUpload = nothing
rs.Close
set rs = nothing
oConn.Close
set oConn = nothing

%>

[Julcar]

Ojo, ésta es otra prueba que me da el mismo resultado, aquí se omite la página uptest.asp

Se conecta con una base access, en donde se guarda la información del archivo subido en una base de datos, mientras que el archivo subido se guarda en una carpeta del servidor.

En la página recibir.asp una vez que se ha procesado el formulario, dice que se ha subido exitosamente el archivo, pero cuando ingreso al ftp, éste no aparece.

[AlZuwaga]

Iniciado por Myakire

Si no postea el código, solo estamos adivinando, hasta que no lo haga no hay nada que hacer

Hola master, lo digo por esto:

Lo que pasa es que ¡NO SE CARGA NINGÚN ARCHIVOOOOOOO!!!!

Y necesito que se suban los archivos y aparezcan dentro de la carpeta del servidor, no solo de palabra dentro la página uptest.asp.

uptest.asp:

Código:

<!--#include file="xelupload.asp"-->
<%
Dim up, fich
set up = new xelUpload
up.Upload()

Response.Write("Número de ficheros subidos: " & up.Ficheros.Count & "<br>")
Response.Flush	
For each fich in up.Ficheros.Items
Response.Write("<ul>")
Response.Write("<li>Nombre: <b>" & fich.Nombre & "</b></li>")
Response.Write("<li>Tamaño: <b>" & fich.Tamano & "</b> bytes (" & FormatNumber(fich.Tamano / (1024*1024)) & " Mb)</li>")
Response.Write("<li>Tipo MIME: <b>" & fich.TipoContenido & "</b></li>")
Response.Write("</ul>")

'Para guardarlo
'	Con el nombre de fichero original:
'	fich.Guardar Server.MapPath("rutavirtual")
'	Con otro nombre:
'	fich.GuardarComo nombrefichero, Server.MapPath("rutavirtual")
'----------------------------------------------------------------
Next

'Limpiamos objeto
set up = nothing
%>
Powered by <b>xelUpload</b> ;-)

Los response.write son lo que el llama "de palabra dentro la página", lo marcado en bold son los comentarios que hay que eliminar (no todos, claro) y lo marcado en rojo son los comentarios explicativos en castellano acerca de qué hay que hacer... pero claro, hay que poner un poco de voluntad y leer.

Saludos

[gorka_22]

Por cierto, ahora una pregunta de novatillo...
Yo creía que cuando subías un fichero con multipart/form-data, no podías abrir ninguna conexion a la base de datos, vamos, ami siempre me fallaba... o era pasar un texto en otro input?
Ahora no recuerdo, lo que si se es que siempre guardaba las variables en una session, el nombre, el texto, el nombre del archivo, etc, primero lo subía en un .asp y luego redireccionaba a otro que me hacia la conexion a la base de datos con la variables de sesion... voy errado?

[Myakire]

pues creo que si, vas errado

Lo que no puedes es llamar al método form del Request sino leer los bytes recibidos del formulario de una forma ordenada (más información) pero fuera de eso, puedes hacer lo que te venga en gana (conexiones a BD's por ejemplo)