Mostrar una imagen de access en asp

asarte82 · #1 (**permalink**) 29/03/2007, 07:56

Como hago para mostrar una imagen de objeto ole con extension jpg en un
ASP.

E probado varias pero nada, me dice k no coinciden los tipos:

- if not RS.EOF then Response.BinaryWrite(RS("foto"))
- response.BinaryWrite(rs("foto"))
- response.write RS("foto").value

- Response.Write "<IMG SRC="""&RS("foto")&""">"
- Response.Write Server.HTMLencode(rs.Fields("foto") & "")

Ninguna me funciona

LinosINK · #2 (**permalink**) 29/03/2007, 08:02

Hola asarte82;

puedes en vez de un objeto ole en la base de datos poner un campo texto en el que guardes la dirección URL de donde esta esa imagen.

y así con: <img src="<% Response.Write rs("foto") %>"> te funcionaria.

asarte82 · #3 (**permalink**) 29/03/2007, 08:20

vale pero en la base de datos, si le pongo formato txt como meto una foto ahi. que tengo k ir a alguna web de estas k subes fotos y te dan la url? o me estoy perdiendo.
Esque me gustaria poner la foto yo desde la base de datos y que se actualizara en la web pero no se como poner entonces un foto en un campo texto.

tammander · #4 (**permalink**) 29/03/2007, 10:26

Necesitas tres cosas:

1 - Una tabla con un campo tipo OLE donde esten guardas las imagenes.

2 - Una página ASP que actue de IMAGEN. Este sería su contenido (mas o menos)

Código:

<%@ LANGUAGE="VBSCRIPT" %>
<!--#include file="../Connections/fotos.asp" -->

<% 
    
    response.Expires = 0
    response.Buffer  = True
    response.Clear

    dim id
    id = request("id")
    
    if id <> "" then
    
        Set rs = Server.CreateObject("adodb.recordset")

        strSQL = "select FileData,ContentTyped from fotos where id = " & id

        rs.Open strSQL, MM_fotos_STRING

        response.contentType = rs("ContentTyped")
        response.BinaryWrite rs("FileData")
        rs.Close
    end if
    response.End
%

3 - La página ASP desde la que es llamada la anterior:

Código:

<%@LANGUAGE="VBSCRIPT" CODEPAGE="1252"%>
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1" />
<title>Imagenes</title>
</head>

<body>
....

 <img src="paginaaspparaimagenes.asp?id=<%=rs("fotoid")%>" width="150" height="150" border="0" />
.....
</body>
</html>

Un saludo

Shiryu_Libra · #5 (**permalink**) 29/03/2007, 13:07

tammander(), en este post
, puso su codigo anteriormente, pero intente realizar previamente a este post, ese metodo que usas... pero aparecer el error de que los encabezados ya estan definidos previamente.... como podriamos solucionar eso?

Error de encabezado
/pruebas/index.asp, line 58
Los encabezados HTTP ya están escritos en el explorador cliente. Cualquier cambio en los encabezados HTTP se debe hacer antes de escribir el contenido de la página.

tammander · #6 (**permalink**) 30/03/2007, 00:36

Hola Shiryu_Libra

¿Estais seguros de que ese error es producido por este método? Es que no comprendo porqué ha de producirse ese error por la llamada a una página desde el src del tag IMG. Recuerda que al hacerlo asi, se ejecuta la página ASP llamada como si de una imagen se tratara. Comprueba si el content-type que se imprime en la "página-imagen" es el correcto. Y tambien comprueba que no sea debido a otra cosa (eliminando la llamda a dicha página desde la página que llama a la imagen.

De todas formas, no puedes llamar a un contenido OLE desde una página en la cual ya has definido su tipo (html/text) como lo estais haciendo ahora. Es decir, no puedes escribir codigo binario (BynaryWrite) cuando ya hay un response.write que escribe texto plano ni haya algun tag. No debe de haber ningun output que no sea el mismo contenido OLE. Por eso lo hago en otra página.

Un saludo

Shiryu_Libra · #7 (**permalink**) 30/03/2007, 00:56

es que lo mas extraño de todo, es que no se a declarado el Content-Type al principio de la pagina...

esto es lo que el tiene

Código:

 <%@ LANGUAGE="VBSCRIPT" %>
<HTML>
<HEAD>
<title>Lectura de la base de datos</title>
</HEAD>
......

habria que quitar los encabezados o algo similar????

tammander · #8 (**permalink**) 30/03/2007, 01:43

En la página llamada (la que yo llamo paginaaspparaimagenes.asp) no debe haber nada. Es decir, es mejor crearla con el block de notas ya que no te mete ningun texto de forma predeterminada (como el dreamweaver).

Solo esto:

(los tag de apertura y cierre)

<%
' Abrimos el buffer

response.Buffer = True

' Limpiamos cualquier cabaecera que pueda haber

response.Clear

' Hacemos las transacciones que sean necesarias

dim id
id = request("id")
if id <> "" then
Set rs = Server.CreateObject("adodb.recordset")
strSQL = "select FileData,ContentTyped from fotos where id = " & id
rs.Open strSQL, MM_fotos_STRING

' Fijate que todavia no he mandado nada a la pantalla
' Es ahora cuando defino el content-type de la página
' Lo defino desde la BD porque guardo tanto imagenes
' como ejecutables, psds y demas. O sea, archivos binarios
' con sus respectivos content-type. No es necesario
' que sean imagenes. Al navegador le da igual :D
' si solo vas a usar un tipo (jpg) lo puedes poner
' directamente:
' response.ContentType = "image/JPEG"
' (mas info: http://www.topxml.com/asp/response_o...ontenttype.asp)

response.contentType = rs("ContentTyped")

' Ahora envio el output:

response.BinaryWrite(rs("FileData"))

' Ahora solo queda cerrar el recordset y la conexion

rs.close()
end if

' Y descargamos todo lo que haya en el buffer.
' Es aqui donde realmente el ASP "pinta" el contenido

response.End()

%>

Y ya esta. Hemos creado una imagen "en modo texto"

NOTA: No uso el Flush() porque este método sigue dejando abierto el documento. End() descarga el buffer y cierra la página con lo que haya.

Un saludo y Viva San Viernes!!!!!!!!

asarte82 · #9 (**permalink**) 30/03/2007, 01:56

Gracias, voy a probar, la unica duda es si en la base de datos tengo k crear el campo como texto, de ser asi, como inserto la imagen en la base de datos puesto que al ser texto no conozco manera de introducirla. explicame esto y me pongo manos a la obra, muchas gracias.

tammander · #10 (**permalink**) 30/03/2007, 02:13

No, no. El campo debe ser tipo Objeto OLE. Para añadir/modificar dicho campo lo que hago yo es crear un recordset y empleo el metodo AppendChunk del recordset:

rs2.Open "fotos", connStr, 2, 2

rs2.AddNew
rs2("idLocal") = idLocal
rs2("FileName") = load.getFileName(newImage)
rs2("FileSize") = load.getFileSize(newImage)
rs2("ContentTyped") = load.getContentType(newImage)
rs2("FileData").AppendChunk load.getFileData(newImage)
rs2("Descripcion") = load.getFileSizeTranslated(newImage) & " (" & load.getType(newImage) & ")"
if load.IsImage(newImage) then
rs2("width") = load.getWidth(newImage)
rs2("height") = load.getHeight(newImage)
end if
rs2.Update

(load es una clase creada por mi especificamente para leer archivos pero puedes usar cualquier clase / componente existente en el mercado. Necesitas el BinaryData del archivo descargado, es decir, su CONTENIDO, no el nombre del archivo.)

Un saludo

asarte82 · #11 (**permalink**) 30/03/2007, 03:16

Vale lo que pasa es que así, si no estoy equivocado, le permitiria a cualquier usuario que entre en mi web, cambiar la imagen del y no es lo que quiero. Yo simplemete quiero que alque le venda la pagina web no tenga que utilizar el dreamweaver para cambiar la imagen. que desde el programa que he creado con acces, le introduzca una imagen nueva y se modifique el la web.

De momento tengo esto:

En la base de datos tengo una tabla con estos campos:

Un campo que se llama contacto de tipo texto y un campo que se llama foto de tipo objeto ole, esta tabla demoento no la tengo relacionada con nada.

Un formulario de access donde aparece el cuadro para introducir el texto de el campo contacto y un cuadro donde dandole al boton de la derecha del raton me da la opcion de meter una imagen, ya sea jpg painbrus o lo que sea.

Despues en dreamweaver tengo:

Una html donde aparece la imagen de fondo de la web y esta imagen cortada en secciones para poder hacer cambios.
En la parte del texto ya lo tengo solucionado porque creo un asp donce realizo la conexión y desde el htm lo llamo y me lo muestra el texto que tengo en la base de datos y lo tengo asi:

<%@ LANGUAGE="VBSCRIPT" %>
<HTML>
<HEAD>
<title>Lectura de la base de datos</title>
<style type="text/css">

</style>
</HEAD>

<body>
<div class="letra" id="Layer1">
<%

' Creamos la conexión con la base de datos
set cn = Server.CreateObject("ADODB.connection")

' Abrimos la conexión con la base de datos, pasándole el DSN
cn.Open "DSN=BDWeb"

' Creamos un objeto recorset
set rs = Server.CreateObject("ADODB.Recordset")

' Creamos la consulta para seleccionar los registros a recuperar.
sql = "Select contacto FROM contacto"

'Abrimos el objeto recordset pasándole la consulta y la conexión.
rs.Open sql, cn, 1, 1

Response.Write Server.HTMLencode(rs.Fields("contacto") & "")

rs.Close
Set rs = Nothing

'cerramos la conexión y liberamos la memoria del objeto conexión
cn.close
Set cn = Nothing

%>
</div>
</BODY>
</HTML>

Ahora para la imagen creo otro asp y tengo esto:

</HEAD>

<body>

<%

'response.ContentType = "img/image"

sql = "SELECT foto FROM contacto"
' Creamos la conexión con la base de datos
set cn = Server.CreateObject("ADODB.connection")

' Abrimos la conexión con la base de datos, pasándole el DSN
cn.Open "DSN=BDWeb"

' Creamos un objeto recorset
set rs = Server.CreateObject("ADODB.Recordset")
rs.Open "contacto", cn, 1, 1

Response.BinaryWrite(RS("foto"))

rs.Close
Set rs = Nothing

'cerramos la conexión y liberamos la memoria del objeto conexión
cn.close
Set cn = Nothing

%>

</BODY>
</HTML>
lo que no consigo es saber como en este asp que se me muerte la imagen.
Estoy iniciandome en esto y me cuesta entender partes de vuestos codigos, quizas porque la base de datos que me dais de ejemplo es diferente y me hago un lio. Si no es mucha molestia y con fin de tener algo de ejemplo si podrias comletar lo que me falta porque estoy haciendo prubas con tus comandos pero no me aclaro.
Muchas gracias de nuevo por entreteneros. ASIAS¡¡

tammander · #12 (**permalink**) 30/03/2007, 04:27

La página ASP que va a contener la imagen NO PUEDE TENER NADA: Ni <HTML>, ni <HEAD>, ni <BODY> ni siquiera charset: NADA.

Voy a intentar explicarte qué es una imagen para el ordenador: Esto:

Código:

ÿØÿà JFIF   d d  ÿì Ducky     <  ÿî Adobe dÀ   ÿÛ „         





ÿÀ „ ÿÄ Q                                            ¢c%                ÿÚ   ? èð  €

Esto es una imagen JPG visto por el Block de Notas

¿Como el navegador intrerpreta esto? Por el content-type. Cualquier programa de retoque fotográfico lo primero que hace es crear un archivo y asignarle un tipo de contenido (image/JEPG) y luego rellena el resto con esos caracteres extraños solo entendibles por el ordenador y algun friki

Nosotros debemos hacer lo mismo:

- Content-type
- Codigo Binario

NADA MAS.

¿Como hago para ver la imagen en otra página que SI contiene texto (descripciones, precios, etc etc etc)? Haciendo creer al navegador que eso que pongo en el src de IMG es una imagen aunque no tenga la extension de imagen (jpg, gif, etc) es una ASP. ¿Porqué el navegador se lo traga? Porque el navegador es un papel en blanco: Si tu le dices que eso es una imagen, el te cree. Enviale lo que tiene que leer correctamente. Al navegador web le importa poco como lo llames.

Asi:

<img src="foto.asp?id=1" width="150" height="150" />

el navegador leerá foto.asp?id=1 y lo cargará como imagen en un recuadro de 150 x 150. Si la información que tu le envias es, ciertamente una imagen, este la dibujará. Si no es pondrá imagen perdida (el simbolito ese cuando no encuentra la imagen)

y foto.asp solo tiene lo que te he puesto. NADA MAS:

foto.asp

Código:

<%@ LANGUAGE="VBSCRIPT" %>
<!--#include file="../Connections/fotos.asp" -->

<% 
    
    response.Expires = 0
    response.Buffer  = True
    response.Clear

    dim id
    id = request("id")
    
    if id <> "" then
    
        Set rs = Server.CreateObject("adodb.recordset")

        strSQL = "select FileData,ContentTyped from fotos where id = " & id

        rs.Open strSQL, MM_fotos_STRING

        response.contentType = rs("ContentTyped")
        response.BinaryWrite rs("FileData")
        rs.Close
    end if
    response.End
%>

Como ves no tiene ni <html> ni <body> ni nada de eso porque NO ES UNA PAGINA HTML, es una IMAGEN (en modo texto, pero es una imagen)

Siento no poder explicarme mejor

Tienes que comprender que estas usando un papel como si fuera una fotografia.

Espero haberme explicado mejor esta vez.

Un saludo

Shiryu_Libra · #13 (**permalink**) 30/03/2007, 09:41

Cita:

Iniciado por asarte82

Vale lo que pasa es que así, si no estoy equivocado, le permitiria a cualquier usuario que entre en mi web, cambiar la imagen del y no es lo que quiero. Yo simplemete quiero que alque le venda la pagina web no tenga que utilizar el dreamweaver para cambiar la imagen. que desde el programa que he creado con acces, le introduzca una imagen nueva y se modifique el la web.

.....

no necesariamente, por que la pagina que tu crearas para insertar imagenes no la pondras al publico....

tu sitio es asi....

www.misitio.com/web/index.asp
donde te manda a tu pagina de muestra

puedes crear una pagina completamente diferente... donde solo los de tu empresa o a las personas que les hayas vendido el sistema, sepan que existe y puedan anexar datos(imagenes en este caso), y ponerle contraseña....

www.tusitio.com/sistema/private.asp
el nombre tu lo puedes poner como quieras... esto es un simulacro

si te fijas, en la direccion, se escribio que privado.asp, esta dentro de una carpeta SISTEMA, donde accederias a anexar datos. asi de facil puede ser evitar que alguien entre y te mueva las imagenes, ya solo seria cuestion de que hicieras tu procedimiento de logeo, y dentro del mismo, pues permitirias al usuario cambiar lo que le permitas... ya sea que nada mas pueda entrar a cambiar noticias, a otro imagenes o en su caso al administrador, cambiar todos los datos.

respecto a la imagen.. pues que otra cosa podemos agregar que no te haya dicho tammander(), realmente lo ha puesto en claro

suerte.

GriLiz · #14 (**permalink**) 04/06/2008, 15:19

Cita:

Iniciado por tammander

Necesitas tres cosas:

1 - Una tabla con un campo tipo OLE donde esten guardas las imagenes.

2 - Una página ASP que actue de IMAGEN. Este sería su contenido (mas o menos)

Código:

<%@ LANGUAGE="VBSCRIPT" %>
<!--#include file="../Connections/fotos.asp" -->

<% 
    
    response.Expires = 0
    response.Buffer  = True
    response.Clear

    dim id
    id = request("id")
    
    if id <> "" then
    
        Set rs = Server.CreateObject("adodb.recordset")

        strSQL = "select FileData,ContentTyped from fotos where id = " & id

        rs.Open strSQL, MM_fotos_STRING

        response.contentType = rs("ContentTyped")
        response.BinaryWrite rs("FileData")
        rs.Close
    end if
    response.End
%

3 - La página ASP desde la que es llamada la anterior:

Código:

<%@LANGUAGE="VBSCRIPT" CODEPAGE="1252"%>
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Transitional//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-transitional.dtd">
<html xmlns="http://www.w3.org/1999/xhtml">
<head>
<meta http-equiv="Content-Type" content="text/html; charset=iso-8859-1" />
<title>Imagenes</title>
</head>

<body>
....

 <img src="paginaaspparaimagenes.asp?id=<%=rs("fotoid")%>" width="150" height="150" border="0" />
.....
</body>
</html>

Un saludo

hola!! tammander, tengo un problemita lo que pasa es que yo uso sql server, necesito jalar una foto de un alumno, esta tabla me la proporcionaron diractamnete asi que no puedo modificarla... los campos de la tabla de alumno entre muchos mas datos tiene el campo alu_Foto que es de tipo image... puedo lajar los datos del alumno pero la foto aun no puedo hee estado leyendo lo que has expuesto en lo de las fotos e imagenes pero la verdad es que soy nueva en esto de las fotos y hay varias cosas que no entiendo

Set rs = Server.CreateObject("adodb.recordset")
' en mi caso yo tengo el recorset con otra variable que hace que recora la tabla set tabla=server.CreateObject("ADODB.RECORDSET")

strSQL = "select FileData,ContentTyped from fotos where id = " & id
'en esta parte si se lo que hace pero no entiendo filedata, y contenttyped no, son campos de la tabla me supongo
rs.Open strSQL, MM_fotos_STRING
response.contentType = rs("ContentTyped")
response.BinaryWrite rs("FileData")
rs.Close
end if
response.End

si me pudieras exoplicar por favor!!! este es el codigo que tengo

alu_NumControl = Request.Form("control")
alu_Password= Request.Form("contraseña")

set conexion=server.CreateObject("ADODB.CONNECTION")
set tabla=server.CreateObject("ADODB.RECORDSET")
Conexion.Open "driver={SQL Server};server=GRINCHLIZ; database=SIS_JIMCEL; uid=sa;pwd=sa"
encontro=0
set tabla=conexion.Execute("SELECT * FROM ceAlumnos WHERE alu_NumControl = '" & alu_NumControl & "'")
if tabla.eof then
Response.Write"No se encontro"
else
encontro=1
nombre=tabla.Fields("alu_Nombre")
ape_paterno=tabla.Fields("alu_ApePaterno")
ape_materno=tabla.Fields("alu_ApeMaterno")
id_carrera=tabla.Fields("esp_Id")
semestre=tabla.Fields("alu_SemestreAct")
foto= tabla.Fields("alu_Foto")
end if
set tabla=conexion.Execute("SELECT TBL_PROGRAMA.NOMBRE, SUM(TBL_ALUACTIVIDAD.HORAS) AS Expr1, TBL_PROGRAMA.TH_PROGRAMA FROM TBL_PROGRAMA INNER JOIN TBL_ALUACTIVIDAD ON TBL_PROGRAMA.IDE_PROGRAMA = TBL_ALUACTIVIDAD.CLAVE_PROGRAMA GROUP BY TBL_PROGRAMA.NOMBRE, TBL_ALUACTIVIDAD.NUMCONTROL, TBL_PROGRAMA.TH_PROGRAMA HAVING (TBL_ALUACTIVIDAD.NUMCONTROL = '" & alu_NumControl & "')")
%><div align = center><h5>Lista de Horas</h5></div><HR>
<br><br>
<b>NOMBRE </b><% Response.Write(nombre)
Response.Write(ape_paterno)
Response.Write(ape_materno)%>
<br><b>CARRERA </b><%Response.Write(id_carrera)%>
<br><b>SEMESTRE </b>
<%Response.Write(semestre)%>
<br>
<% 'Response.ContentType = tabla("foto")
'Response.BinaryWrite tabla("foto")%>

<br><br><br><br>
<table border=1>
<TR>
<TD><b>PROGRAMA</b>
<TD><b>HORAS ACOMULADAS</b>
<TD><b>DE UN TOTAL DE</b>
</TR>
<%
dim col
dim x
x = tabla.fields.count
do while not tabla.eof
response.write "<tr>"
for col=0 to (x-1)
response.write "<td>" & tabla.fields(col).value
next
tabla.MoveNext
response.write "</tr>"
loop
conexion.close
%>
</table>