Problema con listas al recuperar de la base de datos

[ALUCARD81]

.... Recorset y otras cosas para recuperar datos de la BD ..

.... Más código

Código:

<SELECT name="dia" size="1">
                <OPTION value="1">Lunes</OPTION>
                <OPTION value="2">Martes</OPTION>
                <OPTION value="3">Mi&eacute;rcoles</OPTION>
                <OPTION value="4">Jueves</OPTION>
                <OPTION value="5">Viernes</OPTION>
                <OPTION value="6">S&aacute;bado</OPTION>
                <OPTION value="7">Domingo</OPTION>
</SELECT>

..... boton para enviar(hacer la modificación) ...

como ven necesito hacer una lista por si quieren cambiar el dia de la orden, que tiene un código asignado, según el detalle del SELECT, ahora lo que quiero saber es como puedo hacer para que asi como se llenan los text con los datos que recupero, se seleccione automáticamente la opción que corresponda en el SELECT.

Ej en la base de datos tengo

Hora Inicio Hora Fin Pelicula Dia
06:00 08:00 Hombres de Negro 1 (Dia Lunes)
08:00 10:00 Hombres de Negro 2 1 (Dia Lunes)
....
06:00 08:30 Final Fantasy: The Movie 2 (Dia Martes)
08:30 10:30 Inframundo 2 (Dia Martes)
..
06:00 09:00 El Señor de los Anillos 1 3 (Dia Miercoles)
09:30 12:00 El Señor de los Anillos 2 3 (Dia Miercoles)


Puedo recuperar todos los campos, pero como hago para que el SELECT aparezca seleccionado el dia que corresponda, porque luego toma los datos del SELECT, para hacer la modificación correspondiente, si necesitan alguna aclaración no duden en pedirla.

Gracias por cualquier sugerencia o solución que me puedan brindar

[AlZuwaga]

En un trabajo que me pidieron me tocó hacer varios "calendarios semanales" de éste estilo, así que lo metí en una función:

Código:

<%
Function selCreaSemana(nombre, tamanio, DiaActual, multiple)
If DiaActual > 0 AND DiaActual < 8 Then varSel = " SELECTED"
If multiple = 1 Then varMul = " multiple"

varTmp = "<SELECT name=""" & nombre & """ size=""" & tamanio & """" & varMul & ">" & VBCrLf
For i = 1 to 7
varTmp = varTmp & "<OPTION value=""" & i & """"
If i = CInt(DiaActual) Then varTmp = varTmp & varSel
varTmp = varTmp & ">" & WeekDayName(i, false, 2) & "</OPTION>" & VBCrLf
Next
varTmp = varTmp & "</SELECT>" & VBCrLf
selCreaSemana = varTmp
End Function
%>

Luego, donde lo tenía que usar, sólo lo llamaba:

Código:

<FORM...>
...
<% = selCreaSemana("dia", 1, 5, 0) %>
...
</FORM>

eso te crea un desplegable llamado "dia", con los días del lunes a domingo, con el día número 5 seleccionado y que no permite selecciones múltiples.

Para tu caso, lo llamarías así:

Código:

<% = selCreaSemana("dia", 1, Rs("dia"), 0) %>

Si no te interesa esta propuesta, podés hacer símplemente esto:

Código:

<%
varDia = Rs("dia")

Sub Selecciona(DiaBD, nroDia)
If CInt(DiaBD) = CInt(nroDia) Then Response.Write " selected"
End Sub
%>

<SELECT name="dia" size="1">
                <OPTION value="1"<% Selecciona varDia,1 %>>Lunes</OPTION>
                <OPTION value="2"<% Selecciona varDia,2 %>>Martes</OPTION>
                <OPTION value="3"<% Selecciona varDia,3 %>>Mi&eacute;rcoles</OPTION>
                <OPTION value="4"<% Selecciona varDia,4 %>>Jueves</OPTION>
                <OPTION value="5"<% Selecciona varDia,5 %>>Viernes</OPTION>
                <OPTION value="6"<% Selecciona varDia,6 %>>S&aacute;bado</OPTION>
                <OPTION value="7"<% Selecciona varDia,7 %>>Domingo</OPTION>
</SELECT>

Lo bueno de la primera opción es que si tenés muuuchos, se te simplifica el trabajo
Saludos

[ALUCARD81]

Gracias Al Zuwaga

Voy a probar con ambas, aunque me inclino por la segunda porque solo la necesito para el formulario de modificación de la programación, donde solo se utiliza una vez, gracias por la ayuda.

Un saludo