Boton para parar un carrusel de imágenes

[javihb]

Hola amigos, tengo un carrusel de imagenes que van girando nada más entrar a la página y necesito ponerle unos botones de play y de stop para poder parar y arrancar el flash desde esos botones....y no se como hacerlo....os pongo el codigo que lleva el flash el cual hace todo lo que es el movimiento del flash

Código:

var folder:String = "/imgfiles/imagenes/thumbnails/";	// a folder for thumbnail files + an XML file
var total:Number;
var radiusX:Number = 360;
var radiusY:Number = 30;
var centerX:Number = 450;
var centerY:Number = 110;
var speed:Number = 0.002;
tn_group_mc._visible = false;
fm_label.text = ""; fm_url.text = "";

var xml:XML = new XML();
xml.ignoreWhite = true;

xml.onLoad = function()
{
	var nodes = this.firstChild.childNodes;
	total = nodes.length;
	
	for( var i=0; i < total; i++)
	{
		var t = tn_group_mc.duplicateMovieClip("tn"+i, i);
		t.angle = i * ((Math.PI*2)/total);
		t.onEnterFrame = mover;
		t.tn_mc.inner.loadMovie( folder + nodes[i].attributes.filename );
		t.tn_reflection_mc.inner.loadMovie( folder + nodes[i].attributes.filename );
		t.fm_label = nodes[i].attributes.label;
		t.fm_url = nodes[i].attributes.url;
	
		t.fm_button.onRollOver = function()
		{
			fm_label.text =   this._parent.fm_label;
			fm_url.text = "URL: " + this._parent.fm_url;
		}
		t.fm_button.onRollOut = function()
		{
			fm_label.text = "";
			fm_url.text = "";
		}
		t.fm_button.onRelease = function()
		{
			getURL(this._parent.fm_url);
		}
	}
}
xml.load( folder + "flashmo_thumbnails.xml");

function mover()
{
	this._x = Math.cos(this.angle) * radiusX + centerX;
	this._y = Math.sin(this.angle) * radiusY + centerY;
	var s = this._y /(centerY+radiusY);
	this._xscale = this._yscale = s*95;
	this.angle += this._parent.speed;
	this.swapDepths(Math.round(this._xscale) + 100);
}
this.onMouseMove = function()
{
	speed = (this._xmouse-centerX) * 0.00002;
}

en el flash le he puesto ya los dos botones.....que codigo tendrian que llevar esos botones (play y stop) para que funcione?
Un saludo

[stramin]

ve si alguno de estos 2 botones de stop te funciona, para hacer los demás:

Código actionscript:

on(release){
speed=0;
}
 

Código actionscript:

on(release){
_parent.speed=0;
}
 

[javihb]

gracias por contestar stramin....en principio si que me para el movimiento del carrusel con speed=0;....pero...en cuanto quito el puntero del raton el carrusel vuelve a ponerse en marcha.....alguna otra idea...?

[stramin]

perfect, eso quería saber, entonces ahora haz el botón stop así:

Código Actionscript:

on(release){
paused=1;
}
 

y el play asi:

Código Actionscript:

on(release){
paused=0;
}
 

y ademas debes cambiar la función "this.onMouseMove" para que quede así:

Código Actionscript:

this.onMouseMove = function(){
 if(paused==1){
    speed=0;
 }else{
    speed = (this._xmouse-centerX) * 0.00002;
 }
}
 

[javihb]

Vaya....muchisimas gracias esto funciona ahora perfecto.....gracias y que pases buenas navidades