swf de contacto externo

[tacopay10]

Tengo un problema si alguien me puede ayudar se lo agradeceria de por vida.
Tengo una plantilla en flash que compre por internet no puedo hacer que el formulario de contactos se conecte a mi base de datos hace poco consegui un codigo en php que lo hace pero el formulario es externo como hago para conectarlo a mi swf principal en la seccion de contactos.
Una forma que encontre es hacer que el formulario externo se muestre independiente del principal (en otro flash player aparte) pero no he encontrado el codigo al boton para que esto pase.

[mariox55]

Hola tocopay10, lo que debes hacer es enviar las variables desde flash hacia php para que php se encargue de enviar la query a la base de datos y luego retornar un resultado, esto no implica que se valla a dejar de ver el flash (el envío es asíncrono). Esto es posible mediante el uso de objetos LoadVars.

Te muestro un ejemplo para que te guies:
1_ Creas un archivo formulario.fla y un archivo procesa.php
2_ En formulario.fla agregas 2 textos de introducción de datos (nombre_txt, edad_txt)
3_ Ademas agregas un texto dinámico (mostrar_txt) en donde mostraras el resultado de procesa.php
4_ Agregas un boton (enviar_btn) para enviar los datos del formulario.
5_ coloca el siguiente codigo

Código de formulario.fla :

Código ACTIONSCRIPT:

_root.enviar_btn.onRelease = function()
{
    var enviar_lv:LoadVars = new LoadVars();
    var resultado_lv:LoadVars = new LoadVars();
    
    resultado_lv.onLoad = function(success:Boolean)
    {
        if(success)
        {
            mostrar_txt.text = resultado_lv.mensaje;
        }
        else
        {
            mostrar_txt.text = "Error al conectar al servidor";
        }
    };
    enviar_lv.nombre = nombre_txt.text;
    enviar_lv.edad = edad_txt.text;
    enviar_lv.sendAndLoad("procesa.php", resultado_lv, "POST");
};
 

Código de procesa.php :

Código PHP:

<?php
//obtienes las variables desde fash
$nombre = $_POST["nombre"];
$edad = $_POST["edad"];
 
//aqui deberias ocupar las variables $nombre y $edad para
//armar tu cadena sql pero eso ya lo sabes hacer
// ...
 
//ahora imagina que $msj tiene el resultado de tu consulta sql
$msj = "guardado exitosamente";
 
// 'mensaje' será recibida desde flash 
echo "mensaje=".$msj;
 
//de hecho podrias enviar mas variables concatenadolas con &
//ej: echo "mensaje=".$msj."&id=0&etc=valor";
 
?>
 

A probar el ejemplo.

ahhh... y aquí hay otro buen tutorial en donde ademas sale la consulta a la base de datos:
http://www.forosdelweb.com/f62/tutor...-mysql-157514/
Mis saludos.