desactivar menu de flash

[danistrein]

hola amigos estoy aprendiendo flash y intento desactivar el menu cuando haces click derecho, me funciona con as2, pero no me funciona con as3.

alguien sabe como desactivar el menu en as3?
y de paso aprovecho para preguntar:
alguien sabe como agregarle otras opciones al menu? es decir crear un menu con as3 al hacer click derecho que salga junto con "Acerca de Adobe Flash....".

[sixela80]

revisa esto http://livedocs.adobe.com/flash/9.0_...ntextMenu.html ahi explican de lo que buscas, espero te sirva.

[polo_W12]

Iniciado por danistrein

hola amigos estoy aprendiendo flash y intento desactivar el menu cuando haces click derecho, me funciona con as2, pero no me funciona con as3.

alguien sabe como desactivar el menu en as3?
y de paso aprovecho para preguntar:
alguien sabe como agregarle otras opciones al menu? es decir crear un menu con as3 al hacer click derecho que salga junto con "Acerca de Adobe Flash....".

Amigo esto te debiera simplificar las cosas bastante.

Código actionscript:

import flash.net.URLRequest;
import flash.net.URLLoader;
import flash.net.*
 
 
var menu:ContextMenu = new ContextMenu  ;
menu.hideBuiltInItems();
 
var arreglolinks:Array      = new Array("http://www.google.cl/::GOOGLE", "http://www.lun.cl/::LUN");
var totallinks:Number       = arreglolinks.length;
var vinculo:Array           = new Array();
 
init();
 
function init():void{
    var i:Number = 0;
    for(i=0;i<totallinks;i++){
        var tmp:Array   = arreglolinks[i].split("::");
        var elemento:ContextMenuItem = new ContextMenuItem(tmp[1]);
        elemento.addEventListener(ContextMenuEvent.MENU_ITEM_SELECT,linkear);
        menu.customItems.push(elemento);
    }
    this.contextMenu=menu;
}
 
function linkear(e:ContextMenuEvent):void{
    var a:String=e.currentTarget.caption;
    var i:Number = 0;
    for(i=0;i<totallinks;i++){
        var tmp:Array   = arreglolinks[i].split("::");
        if(a==tmp[1]){
            trace(tmp[0]);
            if(tmp[0]){
                var targetURL:URLRequest=new URLRequest(tmp[0]);
                navigateToURL(targetURL, "_blank");
            }
        }
    }
}
 

Espero haberte sido de ayuda.
Saluda Atte.
Claudio Barrera Asencio.

[santirekapo90]

yo estoy interesado en hacer esto, pero as 2.0 ¿alguein sbe como hacer para sacar el menu para cuando haces clic derecho y poner otras cosas?

[polo_W12]

Iniciado por santirekapo90

yo estoy interesado en hacer esto, pero as 2.0 ¿alguein sbe como hacer para sacar el menu para cuando haces clic derecho y poner otras cosas?

Amigo aqui va lo mismo de arriba pero con actionscript2 el anterior era con actionscript3

Código ACTIONSCRIPT:

var menu:ContextMenu = new ContextMenu();
menu.hideBuiltInItems();
 
var arreglolinks:Array      = new Array("http://www.google.cl/::GOOGLE","http://www.lun.cl/::LUN");
var totallinks:Number       = arreglolinks.length;
var vinculo:Array           = new Array();
 
init();
 
function init():Void{
    var i:Number = 0;
    for(i=0;i<totallinks;i++){
        var tmp:Array   = arreglolinks[i].split("::");
        var elemento:ContextMenuItem = new ContextMenuItem(tmp[1],linkear,true,true)
        elemento.onSelect = function(obj:Object,item:ContextMenuItem):Void{
            var caption:String=item.caption;
            linkear(caption);
        }
        menu.customItems.push(elemento);
    }
    this.menu = menu;
}
 
function linkear(a:String):Void{
    var i:Number = 0;
    for(i=0;i<totallinks;i++){
        var tmp:Array   = arreglolinks[i].split("::");
        if(a==tmp[1]){
            if(tmp[0]){
                trace(tmp[0]);
                getURL(tmp[0],"_blank");
            }
        }
    }
}
 

Espero te sea de ayuda.
Saluda Atte.
Claudio Barrera Asencio.

[Bandit]

Hola santirekapo90_
Aquí un ejemplo:
En el primer frame de tu película coloca éste código:

Código:

my_cm = new ContextMenu();
open_cmi = new ContextMenuItem("Bandit", itemHandler);
my_cm.hideBuiltInItems();
my_cm.customItems.push(open_cmi);
function itemHandler(obj, menuItem) {
	trace("Ha seleccionado: "+menuItem.caption);
}
_root.menu = my_cm;

Espero haberte sido de ayuda.

[santirekapo90]

gracias chicos!!!! reparto karma jaja muchas gracias

[danistrein]

muchas gracias por el codigo polo_W12, me funciono bien.