Restar indice a un array

[RM13]

Buenas, sigo con la galería de imágenes, esta vez me interesa guardar en una array la anchura de cada imagen para después poder posicionar cada imagen dependiendo del ancho de la anterior, sería así:

Código PHP:

  var anchos:Array = new Array(); 
.... 
 
//Creo las imagenes: 
 
for (i = 0; i < 4; i++){ 
   crearImagenes(i); 
} 
 
function crearImagenes(num:Number){ 
    ... 
    listener.onLoadInit = function(target_mc){ 
        anchos[num] = target_mc._width; 
        //Y AHORA PARA SABER EL ANCHO DEL ANTERIOR 
        trace(anchos[num - 1]); 
        //ME DICE UNDEFINED DE CADA ELEMENTO DEL ARRAY 
   }; 
}  
   

No lo entiendo me debería decir "undefined" cuando sea anchos[-1], para el resto debería de mostrarmelo.

Sin embargo:

Código PHP:

  var i:Number; 
var mi_array:Array = new Array(); 
 
mi_array[0] = "Cero"; 
mi_array[1] = "Uno"; 
mi_array[2] = "Dos"; 
mi_array[3] = "Tres"; 
 
for (i = 0; i < 4; i++){ 
   trace(mi_array[i-1]); 
}  
   

Imprime:

undefined
Cero
Uno
Dos

He intentado buscarle la lógica pero no lo entiendo, espero que puedan ayudarme.

[Ludwingg]

Creo que el problema es que la variable i en un inicio equivale a cero, entonces cuando hace el trace de i-1, o sea 0-1 (cero menos uno), este equivale a -1, por eso te lanza undefined...

En este momento no tengo el flash, por lo tanto no puedo probar, pero te sugiero que agregues un if para verificar cuando i equivale a cero, ya que antes de el no hay ningun valor, asi que no debería tomarlo en cuenta:

Código:

for (i=0; i<mi_array.length; i++) {
   if (i != 0) {
      trace(mi_array[i-1]);
   }
}

[jahepi]

Hola RM13 !

Por lo que veo, hay alguna variable que no puede ser leída en el ámbito de onLoadInit, puede ser anchos o target_mc._width, prueba con el depurador para ver si esas variables están definidas ahí.

Un saludote !

[RM13]

Ludwingg gracias por tu ayuda, sé que porque me lanza el primer undefined lo que no entiendo es por que si guardo la anchura de cada imagen en el array, al hacer el trace, me las imprime perfectamente, pero cuando hago un trace del array, restandole uno a cada indice, no logra reconocerlo.

jahepi, la verdad es que lee las dos porque por ejemplo:

function crearImagenes(num:Number){
...
listener.onLoadInit = function(target_mc){
anchos[num] = target_mc._width;
trace(anchos[num]);
};
}

Imprime correctamente el ancho de cada imagen, en cambio si intentas restarle un indice al array ya no reconoce, y como he realizado en el segundo ejemplo de manera mas sencilla reconoce perfectamente al restarle el indice, esto se escapa a mi comprensión jeje, un saludo y gracias por vuestra ayuda.

[Lynxcraft]

Código PHP:

  var anchos:Array = new Array(); 
//.... 
 
//Creo las imagenes: 
 
for (var i:Number = 0; i < 4; i++){ 
   crearImagenes(i); 
} 
 
function crearImagenes(num:Number){ 
   // ... 
    listener.onLoadInit = function(target_mc){ 
        anchos.push(target_mc._width); 
        //Y AHORA PARA SABER EL ANCHO DEL ANTERIOR 
        if(anchos[num - 1]==undefined){ 
        trace('Espera que cargue el otro dato '); 
        }else{ 
            trace(anchos[num - 1]); 
        }  
        //ME DICE UNDEFINED DE CADA ELEMENTO DEL ARRAY 
   }; 
}  
   

te explico como va el asunto el hecho que un array almacena sus valores con un indice en pesado por cero, como es logico si restas su indice y el resultado de este es menor a 0 o de por si el array no contiene nada te devuelve undefined

[RM13]

Utilizando:

Código PHP:

  anchos.push(target_mc._width);
        if(anchos[num - 1]==undefined){
               trace('Espera que cargue el otro dato ');
        }else{
               trace(anchos[num - 1]);
        }  
   

Espera que cargue el otro dato
anchos[1]: undefined
anchos[0]: 270
Espera que cargue el otro dato.

No logro entender muy bien lo que sucede y todavia no me ha quedado muy claro lo siguiente, no sé si es lo que me habéis explicado:

Vamos a ver tengo 4 imágenes (probando con 4, después van a ser muchas más):

Nombre Dimensiones
---------- --------------------
0.jpg 480 x 360
1.jpg 270 x 360
2.jpg 270 x 360
3.jpg 270 x 360

//Tengo el bucle

Código PHP:

  for(i = 0; i < 4; i++){
    crearGrandes(i);
}  
   

La función es la siguiente:

Código PHP:

  function crearGrandes(num:Number){
     var fotoP:MovieClip = lienzo_grandes.createEmptyMovieClip("fotoP_" + num, lienzo_grandes.getNextHighestDepth());
     var contenedorP:MovieClip = fotoP.createEmptyMovieClip("contenedorP", 1);
     var mclP:MovieClipLoader = new MovieClipLoader();
     var listenerP:Object = new Object();

     mclP.addListener(listenerP);
     mclP.loadClip("imagenes/galeria/grandes/" + i + ".jpg", contenedorP);

      listenerP.onLoadInit = function(target_mc:MovieClip) {
      //No entiendo lo siguiente, si yo hago:
          //Primera iteración, num = 0;
          anchos[num] = target_mc._width  // anchos[0] = 480
          trace(anchos[num - 1]); // anchos[-1] = undefined, bien.
           ...
           //Posiciono cada imagen con _x e _y;
           ...
           //Segunda iteración, num  = 1;
           anchos[num] = target_mc._width // anchos[1] = 270;
          trace(anchos[num - 1]); // anchos [0] = 480;
          //cuando devuelve: anchos[0] = undefined;  
       };
}  
   

Si no encuentran solución, ¿se les ocurriría una forma más sencilla de poder conseguir el ancho de la imagen anterior?, gracias por vuestra ayuda de verdad y perdonen mi ignorancia llevo 1 mes y poco con esto todavía tengo mucho que aprender :).

[jahepi]

Hola RM13 !

El problema se encuentra en la parte donde añades el listener.

Los eventos se ejecutan de manera asincrónica, esto quiere decir, cuando se llame a la función crearGrandes, el método onLoadInit no se llamará inmediatamente, se ejecutará hasta que la imagen sea cargada completamente, entonces no tienes un control total en el orden de ejecución, puede ser que primero sea completada la imagen 2 y luego la imagen 3 y por último la imagen 0, así que el vector no te será de utilidad para saber el ancho anterior.

Lo que te recomiendo es que vayas cargando imagen por imagen, primero cargas la imagen 0, cuando esta sea completada, pasas a la siguiente imagen y así sucesívamente, en esta situación si que podrías utilizar el vector para ir almacenando los anchos de cada una de las imágenes para saber el ancho anterior porque tendrías un control total en el orden de carga.

Un saludote !

[RM13]

Buenas de nuevo, siento deciros que sigue sin funcionar y empiezo a pensar en tirar la toalla e intentar otra cosa, jeje ya llevo un par de días con esto y no le veo solución .
Al fin he comprendido lo que me has explicado, de hecho yo posicionaba las imagenes en el onLoadInit, y comenzaba posicionando la ultima y terminaba en la primera no entendía porqué ahora ya lo entiendo, de hecho las he posicionado en el onLoadComplete y comienzo por la primera y termina por la última .

Bien sobre lo que me recomendabas de hacer, he intentado lo siguiente, con igual resultado:

var cargados:Number;
var total:Number;

listenerP.onLoadProgress = function(bytesLoaded:Number, bytesTotal:Number){
cargados = bytesLoaded;
total = bytesTotal;
};

listenerP.onLoadInit = function(target_mc:MovieClip) {
if (cargados == total){
anchos[num] = target_mc._width;
}

};

listenerP.onLoadComplete = function(target_mc:MovieClip){
trace("anchos[" + num + "] = " + anchos[num - 1]); // Devuelve los undefined
// Y aqui posiciono de acuerdo con anchos[num - 1])
};

Parece un rompecabezas, me quieren hacer la puñeta jeje, solo reconoce los anchos en el onLoadInit.
En onLoadProgress y onLoadComplete valen 0.

No sé si es exactamente a lo que te referías que hiciera, ¿sabrias ponerme un ejemplo?, la verdad me interesa que sea así porque también tengo pensado meter unos preloaders en el onLoadProgress.

Gracias de nuevo y repito perdonen mi ignorancia llevo muy poquito con esto jeje, un saludo.

[jahepi]

Iniciado por RM13

Buenas de nuevo, siento deciros que sigue sin funcionar y empiezo a pensar en tirar la toalla e intentar otra cosa, jeje ya llevo un par de días con esto y no le veo solución .
Al fin he comprendido lo que me has explicado, de hecho yo posicionaba las imagenes en el onLoadInit, y comenzaba posicionando la ultima y terminaba en la primera no entendía porqué ahora ya lo entiendo, de hecho las he posicionado en el onLoadComplete y comienzo por la primera y termina por la última .

Bien sobre lo que me recomendabas de hacer, he intentado lo siguiente, con igual resultado:


Parece un rompecabezas, me quieren hacer la puñeta jeje, solo reconoce los anchos en el onLoadInit.
En onLoadProgress y onLoadComplete valen 0.

No sé si es exactamente a lo que te referías que hiciera, ¿sabrias ponerme un ejemplo?, la verdad me interesa que sea así porque también tengo pensado meter unos preloaders en el onLoadProgress.

Gracias de nuevo y repito perdonen mi ignorancia llevo muy poquito con esto jeje, un saludo.

Te hago una pequeña modificación al código para que se haga una por una:

Código actionscript:

var anchos:Array = new Array();
var counter:Number = 0;
var MAX_LIMIT:Number = 3;
crearGrandes(counter);
 
function crearGrandes(num:Number) {
    var fotoP:MovieClip = lienzo_grandes.createEmptyMovieClip("fotoP_"+counter, lienzo_grandes.getNextHighestDepth());
    var contenedorP:MovieClip = fotoP.createEmptyMovieClip("contenedorP", 1);
    var mclP:MovieClipLoader = new MovieClipLoader();
    var listenerP:Object = new Object();
 
    mclP.addListener(listenerP);
    mclP.loadClip("grandes/"+counter+".jpg",contenedorP);
 
    listenerP.onLoadInit = function(target_mc:MovieClip) {
        anchos[counter] = target_mc._width;
        trace(anchos[counter - 1]);
        counter++;
        if(counter <= MAX_LIMIT) {
            crearGrandes(counter);
        }
    };
}
 

La variable counter es solamente un contador para ir incrementándola hasta llegar al límite que es almacenado en la constante MAX_LIMIT, cada vez que entra al método onLoadInit incrementa el contador y ve si no ha llegado al limite para no seguir llamando a la función cargarGrandes.

Un saludote !

[RM13]

Rebuenas!, siento no haber podido contestar antes, no he tocado el ordenador en todo el fin de semana, funciona 100% y sin modificar mi código apenas !, eres un fenómeno, 16 millones de gracias, un saludo