Base de Datos en Access 2003

[dennug24]

Hola! Llevo poco tiempo trabajando con la Base de Datos de Access por lo que aun estoi un poco verde...

Este es el tema:

Tengo una tabla con campos como Id, nombre, apellidos, edad, foto, localidad, etc...

Y luego para visualizar esa tabla e creado un formulario.

Pues bien, lo que yo queria hacer es, cada vez que veo a una persona en el formulario, queria que hubiera un contador que me dijera, cuantas veces e visto el registro de esa persona... es decir, yo abro el formulario, y obviamente me sale el primer registro, pues ese registro deberia sumar una visita, y si yo visito otro registro de otra persona, que esa persona se le sume una visita mas...

No se si me e explicado bien... eso es todo, no se si sera posible poder hacerlo.



Gracias.

[Taribo007]

Si quieres hacerlo en cada sesion, es decir, que cada vez que se abra la BD empiece a contar desde 0, bastaria con unas variables globales a nivel de modulo, para ir contando, pero en funcion del nuemro de regitros igual serian demasiadas, por loq ue podrias usar un array.

Si quieres que el "contador" no se inicialice cada vez que se abre la BD, puedes crear una tabla donde guardes ese contador, y actualizarlo en el evnto current (al activar registri) del formulario.

En funcion de tu respuesta, continuamos.

un saludo

[dennug24]

Yo tenia pensado crear un campo llamado Número de Visitas y que cada "persona" en el formulario le saliera el campo Número de Visitas, con el numero de visitas que obviamente tiene cada uno, nose cual es la opcion mas eficaz de las que as mencionado, asique como tu quieras...



Un saludo y gracias por contextar.

[Taribo007]

Eficaces son las dos, la diferencia es si quieres tener un historico o quieres que se inicie cada vez que abres la bd.

Optemos por la segunda opcion.
Supongo que cada registro de persona, tendra un identificador. Llamemosle Idpersona.

Crea una tabla nueva con dos campos: IdPersona, NumVisitas. Llamemos a la tabla TblContadorVisitas.

El fomrulario, tiene un evento llamado al activar registro (current), pues en ese evento, has de poner algo asi, para que se incremente en 1 cada vez que se active (se visite) ese registro.

Private Sub Form_Current()
Dim rstContador As DAO.Recordset

If Not Me.NewRecord Then 'no se trata d eun nuevo regitro
Set rstContador = CurrentDb.OpenRecordset("SELECT IdPersona,NumVisitas from TblContadorVisitas WHERE IdPersona=" & Me.Id_empleado)

If rstContador.RecordCount = 0 Then 'No esta introducido el regitro: Añadimos
rstContador.AddNew
rstContador("IdPersona") = Me.Id_empleado
rstContador("NumVisitas") = 1
rstContador.Update
Me.NumVisitas = 1
Else ''YA esta introducido el regitro: editamos
rstContador.Edit
rstContador("NumVisitas") = Nz(rstContador("NumVisitas"), 0) + 1
rstContador.Update
Me.NumVisitas = rstContador("NumVisitas")
End If

rstContador.Close
Set rstContador = Nothing
Else
Me.NumVisitas = 0
End If

End Sub

NumVisitas es un cuadro de texto, independiente, para mostrar el nuemro de visitas.
Tienes que activar la referencia Microsoft Dao x.xx object library

Vete probando, tendras errores, adaptalo a los nombres de tus campos y tablas.

Un saludo

[Taribo007]

Igual me he liado demasiado, tambien puedes incluir en en el origen de registro del formualrio la nueva tabla, uniendola con un inner join (o con el asitente de access, uniendo los dos ampos claves), e incrementar directamente en el evento current el campo:

If Not Me.NewRecord Then
Me.NumVisitas = Nz(Me.NumVisitas, 0) + 1
End If

En este caso, el cuadro de texto NumVisitas tendra que tener como origen de control el campo NumVisitas de la tabla TblContadorVisitas

un saludo

[dennug24]

Muchas gracias, despues de un rato depurando el codigo ya me funciona justo como queria.

Asique muchas gracias de nuevo!!

Un saludo!