Abrir winforms desde otro winform

[klaudio83]

Holas estoy trabajando en Visual Studio 2008 utilizando vb.net.

Tengo un winform(inicio.vb) que tiene la opcion isMdi container habilitada,

esta tiene un menu con un boton con la opcion "Clientes",

al apretar este boton se abre otro Winform(menu_clientes.vb),

menu_clientes.vb tiene un DataGridView, me muestra todos los clientes que ya se encuentran registrados, esto lo hace al abrir menu_clientes.vb

menu_clientes.vb tiene un ToolStrip,

en este ToolStrip tengo un boton(nuevo Cliente) que abre otro

winform(nuevo_cliente.vb), en nuevo_cliente.vb tengo un formulario donde ingreso los datos del nuevo cliente,

apreto el boton guardar de nuevo_cliente.vb, y registra el cliente

Lo que deberia ocurrir, es que al apretar el boton guardar de nuevo_cliente.vb, deberia hacer el registro en la BD(que si lo hace perfectamente) y visualizar (o que se actualice el datagridview con los mismos datos mas los datos nuevos) automaticamente el cliente recien ingresado dentro del datagridview de menu_clientes.vb


El Problema es que esto no pasa, si alguien sabe como hacer esto que me ayude porfavor, de ante mano muchas gracias.

El codigo que utilizo lo pongo en el siguiente mensaje

[klaudio83]

Codigo: inicio.vb

Código vb.net:

Private Sub NavBarItem1_LinkClicked(ByVal sender As Object, ByVal e As DevExpress.XtraNavBar.NavBarLinkEventArgs) Handles NavBarItem1.LinkClicked
        Dim menu_cli As New menu_clientes
        menu_cli.MdiParent = Me
        menu_cli.Show()
End Sub
 

Codigo: menu_clientes.vb

Código vb.net:

Public Sub menu_clientes_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        Dim conexion As New SqlConnection(cadena)
        Dim sql As String
        Dim MiAdapter As SqlDataAdapter = New SqlDataAdapter("SELECT cod_cli AS Codigo, rut_cli AS Rut, nombre_cli AS Nombre, fijo_cli AS Telefono, movil_cli As Celular, email_cli AS Mail FROM cliente", conexion)
 
         Dim MiDataSet As New DataSet
         MiAdapter.Fill(MiDataSet)
         DataGridView1.DataSource = MiDataSet.Tables(0)
End Sub
 
Private Sub nuevo_cliente_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles nuevo_cliente.Click
        Dim NuevoCliente As New nuevo_cliente
        NuevoCliente.ShowDialog()
End Sub
 

Codigo: nuevo_cliente.vb

Código vb.net:

Private Sub guardar_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles guardar.Click
       
            ingresar_cliente(txRut.Text, txNombre.Text, txTelFijo.Text, txTelMovil.Text, txDomicilio.Text, txPerContacto.Text, txGiro.Text, txMail.Text, txFecha.Text, txEstado.Text, txCiudad.SelectedValue)
 
           'AQUI ESTO ES LO QUE HAGO PARA QUE SE VUELVA A CARGAR EL 'DATAGRIDVIEW DE menu_clientes.vb
           menu_clientes.menu_clientes_Load(sender, e)
            
End Sub
 
Private Sub ingresar_cliente(ByVal rut As String, ByVal nombre As String, ByVal fijo As String, ByVal movil As String, ByVal domicilio As String, ByVal contacto As String, ByVal giro As String, ByVal email As String, ByVal fecha As String, ByVal estado As String, ByVal idCiudad As String)
        Dim conexion As New SqlConnection(cadena)
        Dim comando As New SqlCommand("INSERT INTO cliente(rut_cli, nombre_cli, fijo_cli, movil_cli, domicilio_cli, contacto_cli, giro_cli, email_cli, fecha, estado_cli, id_ciudad) values(@rut, @nombre, @fijo, @movil, @domicilio, @contacto, @giro, @email, @fecha, @estado, @idCiudad)", conexion)
 
        comando.Parameters.AddWithValue("@rut", rut)
        comando.Parameters.AddWithValue("@nombre", nombre)
        comando.Parameters.AddWithValue("@fijo", fijo)
        comando.Parameters.AddWithValue("@movil", movil)
        comando.Parameters.AddWithValue("@domicilio", domicilio)
        comando.Parameters.AddWithValue("@contacto", contacto)
        comando.Parameters.AddWithValue("@giro", giro)
        comando.Parameters.AddWithValue("@email", email)
        comando.Parameters.AddWithValue("@fecha", fecha)
        comando.Parameters.AddWithValue("@estado", estado)
        comando.Parameters.AddWithValue("@idCiudad", idCiudad)
 
        conexion.Open()
        comando.ExecuteNonQuery()
        conexion.Close()
    End Sub
 

[eperedo]

Prueba creando un método que contendrá el código para cargar la grilla.

Código vb.net:

Public Function ListarDatos() As DataTable
        Dim conexion As New SqlConnection(cadena)
        Dim sql As String
        Dim MiAdapter As SqlDataAdapter = New SqlDataAdapter("SELECT cod_cli AS Codigo, rut_cli AS Rut, nombre_cli AS Nombre, fijo_cli AS Telefono, movil_cli As Celular, email_cli AS Mail FROM cliente", conexion)
 
         Dim MiDataSet As New DataSet
         MiAdapter.Fill(MiDataSet)
         return MiDataSet.Tables(0)
End Function
 

En el load de menu_clientes:

Código vb.net:

DataGridView1.DataSource = ListarDatos()
 

Al mostrar el formulario nuevo_cliente

Código vb.net:

Private Sub nuevo_cliente_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles nuevo_cliente.Click
        Dim NuevoCliente As New nuevo_cliente
        NuevoCliente.ShowDialog()
        DataGridView1.DataSource = ListarDatos()
End Sub
 

Luego de que se guarde el formulario se refrescará la grilla.
Cualquier duda me avisas

[klaudio83]

Muchas gracias eperedo. Me funciono de las mil maravillas
Tu siempre das la respuesta precisa, concreta y correcta
Muchas gracias