Arrastrar ficheros sobre un control MediaPlayer (VB6)

[pkj]

Como me aburro, vuelvo a preguntar algo que me gustaría solucionar y que, aunque lo comenté en otro post, después le cambié el título al post (¿estará bien dicho 'post'?, yo es que soy de números ), y centré el tema en imágenes transparentes.

Hoy quiero abrir de nuevo este tema por si alguien conoce una solución (aunque sea un poco chapuza) para conseguir que un control MediaPlayer permita y comunique el arrastrado de ficheros sobre él, o técnicamente creo que sería ¿como conseguir generar un evento OLEDragDrop en un control MediaPlayer (al arrastrar un fichero sobre él)?

En fín, se agradecerá cualquier idea.

Saludos.

[seba123neo]

Hola, lo que podes hacer es como una playlist con un listbox y asi usas los eventos de Drag de ese control, y ahi sacas facil en pocas lineas de codigo el archivo que estas queriendo reproducir, la otra es hacerlo directamente en el windows media player, la verdad no he visto codigo para hacerlo directo con algun evento o algo, lo he solucionado usando esto, puede ser largo el codigo usando algunas api's de windows, pero otra no vi, y anda bien, si alguno sabe otra bienvenido.

En un Modulo:

Código vb:

Option Explicit
 
Public Declare Function SetWindowLong Lib "user32" Alias "SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, ByVal dwNewLong As Long) As Long
Public Declare Sub DragAcceptFiles Lib "shell32.dll" (ByVal hWnd As Long, ByVal fAccept As Long)
Private Declare Function DragQueryFile Lib "shell32.dll" Alias "DragQueryFileA" (ByVal hDrop As Long, ByVal UINT As Long, ByVal lpStr As String, ByVal ch As Long) As Long
Private Declare Function CallWindowProc Lib "user32" Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
 
Public Const WM_DROPFILES = &H233
Public Const GWL_WNDPROC = -4
Public lProcOld As Long
 
Public Function Drag_Drop_WindowsMediaPlayer(ByVal hWnd As Long, ByVal Mensaje_Windows As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
   Dim n_Archivos As Long
   Dim x As Long
   Dim Archivo As String * 128
   
   If Mensaje_Windows = WM_DROPFILES Then
      n_Archivos = DragQueryFile(wParam, -1, Archivo, 127)
      For x = 1 To n_Archivos
         Call DragQueryFile(wParam, x - 1, Archivo, 127)
         Form1.WindowsMediaPlayer1.URL = Archivo
         Debug.Print Archivo
      Next x
      Exit Function
   End If
   Drag_Drop_WindowsMediaPlayer = CallWindowProc(lProcOld, hWnd, Mensaje_Windows, wParam, lParam)
End Function
 

en el Form:

Código vb:

Option Explicit
 
Private Sub Form_Load()
    Call DragAcceptFiles(hWnd, True)
    lProcOld = SetWindowLong(hWnd, GWL_WNDPROC, AddressOf Drag_Drop_WindowsMediaPlayer)
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
    Call DragAcceptFiles(hWnd, False)
    Call SetWindowLong(hWnd, GWL_WNDPROC, lProcOld)
End Sub
 

saludos.

[pkj]

Muchas gracias por tu ayuda, Seba.

Me ha costado horas por mi mala cabeza pero he conseguido que funcione.

El programa se vuelve un poco inestable, pero parece ser solo durante la depuración cuando más problemas dá, ya que cuando activo el evento, al salir del programa se cierra incluso el VB6, chafandote los cambios.
Lo he solucionado con algo que ya usaba y que evita que se active cuando lo estoy depurando, sin tener que andar luego acordándome de permitir la activación cada vez que tengo que compilar. El caso es que el .exe no empiece a hacer cosas raras. Lo observaré un tiempo.

De todas formas, muchas gracias por la solución. Había perdido la esperanza de encontrar una.

Saludos.

[seba123neo]

fijate que en el modulo dice:

Código vb:

Form1.WindowsMediaPlayer1.URL = Archivo
 

ahi tenes que poner el nombre dle form tuyo y el nombre del control tuyo, porque si lo pegas y lo probas asi, y el control no existe te va a tirar un error que te saca del visual basic ya que estas haciendo un Hook al mensaje WM_DROPFILES, tampoco lo pares del boton de stop del visual basic no se debe hacer eso.

saludos.

[pkj]

Sí, por alucinante que me pareciese incluso a mí, de primeras entedí exactamente lo que hacía la función, ya que he usado cosas parecidas.
El problema fué que, primero al copiar y pegar metí la pata y se me quedó una copia de las lineas de desactivación en el form_Load, con lo que nada más cargarse se descargaba y me volví loco buscando el fallo.
Luego resulta que cambié el exit function por un goto finfuncion, pero "por H o por B", lo escribí donde no era y nunca pasaba por la última línea, (cuando debía hacerlo todo el tiempo mientras no arrastrases nada), con lo que algo se saturaba y bloqueaba el programa y todo el VB6.
Cuando conseguí que por fín funcionase, resulta que mi mejor opción de adaptación era cargar los ficheros en un DataObject como los que generan los controles que permiten arrastrar, pero soy tan burro que una vez cargado, al lanzarlo a la sub a la que todos los controles lanzan sus DataObject's, el caso es que llegaba vacío y no supe adivinar por qué, ya que cargarse se cargaba por que el fichero llegaba y el Data.Files.Count tenía un valor > 0.
En fín, al final tuve que pasarlos a un ListBox y procesarlos aparte.

El caso es que la inestabilidad continúa en el editor de VB, y no he podido evitarlo cambiando las activaciones y desactivaciones de sitio y tal. Pero como fácilmente he conseguido que no se cargue con el editor, "no poblemo".

Muchas gracias por el interés. Y no le dés muchas vueltas, será algo de mi XP o cualquier incompatibilidad, o, (creo que esta vez no he hecho nada mal, pero nunca se sabe,) igual es mi culpa.

PD: Por cierto, no he comentado nada en esta sección, pero es para un programa que he subido en la sección de Audio/Video y Multimedia.
Si quieres ver el resultado, date una vuelta por:
http://www.forosdelweb.com/f3/quiero...0/#post3073653
(creo que el título fue un error, pero ya no lo voy a cambiar)
Seguramente lo actualice en breve con la nueva función.

Saludos.

[pkj]

Después de un tiempo, usando un control MediaPlayer en otro sitio, descubrí que se puede hacer que el Form que contiene el control reciba los ficheros arrastrados sobre el control siempre que el control tenga el valor .Visible = False.

Al cargar un video este se ve, aunque la barra de posicion no consigo que se vea en modo ventana. En pantalla completa sin embargo la barra si se deja activar.
El caso es que al arrastrar ficheros sobre el video que estás viendo, como está en modo Visible = False, no recibe los ficheros, sino que pasan a través del video y llegan al Form, siendo este el que los captura.

Si alguien sabe como activar la barra de posición en modo ventana sin poner el modo .Visible = True, por favor que me lo explique y creo que se solucionarán mis problemas. El caso es que me vuelvo loco para mostrar/ocultar los controles que quiero.

Saludos