Boton creador de codigo vb

[Victorchef]

Hola, estoy haciendo un programa de ferreteria, en el formulario de articulos he creado varios botones de navegación, nuevo, guardar, eliminar, tambien e puesto imagenes de los articulos. Ahora tengo que crear un boton, que cuando añada un nuevo articulo, me cree automaticamente el codigo del articulo a partir de de la primera letra del codigo de la familia y el ultimo numero que hay en la tabla articulos de esa familia. (Los articulos tambien estan clasificados por familias), no se como hacerlo.
Gracias
Programa en vb6.0

[lokoman]

Hola!
Si pudieras ser un poquito mas explicito (por el asunto de las familias, como cargas o presentas los datos, que controles usas, etc.) para poder darte algo mas concreto, de todas formas te muestro algo:

Primero: obtienes debes obtener el nombre de la 'familia' (varFAMIL)
Segundo: guardas en una variable los 3 primeros caracteres de esa 'familia' con este codigo:

Código vb:

varCOD_PROD=MID(varFAMIL,3)
 

Tercero: haces una consulta en la tabla de articulos basandote en esa 'familia', asi:

Código vb:

DIM strSELECT AS STRING
DIM rstTOTAL AS ADODB.RECORSET
 
SET rstTOTAL = NEW ADODB.RECORDSET
 
strSELECT="SELECT COUNT(*) AS TOTAL_FAMIL FROM ARTICULOS WHERE FAMILIA='" & varFAMIL & "'"
rstTOTAL.OPEN strSELECT, conCONEXION
 
'ASIGNAS EL CODIGO CON LAS 3 LETRAS + LA SECUENCIA DE LA 'FAMILIA'
IF rstTOTAL.EOF=FALSE THEN
varCOD_PROD=varCOD_PROD & "-" & (rstTOTAL!TOTAL_FAMIL + 1)
END IF
 

Postea tu codigo o agarra la idea y nos cuentas!

[Victorchef]

La tabla articulos se presenta asi, te pongo el nombre de la fila y entre() el articulo.
ccodigo(E001), cfamilia(ELEC), carticulo(soldador jbc 100w).... formato de texto
si ahgora le añado un nuevo articulo, por ejemplo un soldaor jbc 50w de la misma familia, el boton me debe generar el codigo E002
Gracias

[lokoman]

Pues bajate el proyect, ajustalo y nos cuentas!!

http://dl.dropbox.com/u/23151936/Foro/Ferret.rar

Codigo:

Código vb:

Public Conexion As ADODB.Connection
 
Private Sub cboFAMILIA_Click()
    Dim rstData As ADODB.Recordset
    Dim Secuencia As Integer
    
    Set rstData = New ADODB.Recordset
    Secuencia = 0
    txtARTICULO.Text = Empty
    
'OBTENER EL CODIGO
    rstData.Open "SELECT * FROM ARTICULOS WHERE CFAMILIA='" & cboFAMILIA.Text & "'", Conexion, adOpenDynamic, adLockBatchOptimistic
    
    If rstData.EOF = False Then
        Secuencia = Val(Mid(rstData!CCODIGO, 2))
        
        Do While rstData.EOF = False
            If Secuencia < Val(Mid(rstData!CCODIGO, 2)) Then Secuencia = Val(Mid(rstData!CCODIGO, 2))
            rstData.MoveNext
        Loop
        
        txtCODIGO.Text = Mid(cboFAMILIA.Text, 1, 1) & Format(Secuencia + 1, "000")
    End If
    
    If rstData.State = 1 Then
        rstData.Close
        Set rstData = Nothing
    End If
End Sub
 
Private Sub cmdGUARDAR_Click()
    Dim strINSERT As String
    Dim Guardado As Integer
    
    Guardado = 0
    
    If Trim(txtARTICULO.Text) <> Empty Then
        strINSERT = "INSERT INTO ARTICULOS (CCODIGO, CFAMILIA, CARTICULO) VALUES ('" _
                & txtCODIGO.Text & "','" & _
                cboFAMILIA.Text & "','" & _
                Trim(txtARTICULO.Text) & "')"
        Conexion.Execute strINSERT, Guardado
        
        If Guardado = 1 Then
            MsgBox "ARTICULO GUARDADO!!", vbInformation
            cboFAMILIA_Click
            txtARTICULO.SetFocus
        Else
            MsgBox "NO SE PUDO GUARDAR EL ARTICULO!!", vbInformation
        End If
    End If
End Sub
 
Private Sub Form_Load()
    Dim rstData As ADODB.Recordset
    
    Set Conexion = New ADODB.Connection
    Set rstData = New ADODB.Recordset
    
'CONEXION A LA BD
    Conexion.ConnectionString = "Provider=Microsoft.Jet.OLEDB.4.0;" _
            & "Data Source=" & App.Path & "\FERRET.mdb;Persist Security Info=False"
    Conexion.Open
    
'CARGAR EL COMBO
    rstData.Open "SELECT DISTINCT CFAMILIA FROM ARTICULOS", Conexion, adOpenDynamic, adLockBatchOptimistic
    
    If rstData.EOF = False Then
        cboFAMILIA.Clear
        
        Do While rstData.EOF = False
            cboFAMILIA.AddItem rstData!CFAMILIA
            rstData.MoveNext
        Loop
        
        If cboFAMILIA.ListCount > 0 Then cboFAMILIA.Text = cboFAMILIA.List(0)
    End If
    
    If rstData.State = 1 Then
        rstData.Close
        Set rstData = Nothing
    End If
End Sub
 
Private Sub Form_Unload(Cancel As Integer)
'CERRAR LA CONEXION
    If Conexion.State = 1 Then
        Conexion.Close
        Set Conexion = Nothing
    End If
End Sub