cargar campo de acces en listbox en visual basic 6

[MINTZ]

Hola, estoy aprendiendo visual basic 6 y tengo una duda que no consigo solucionar mirando en mil webs y foros, a ver si me podeis ayudar.

Tengo una base de datos llamada "animales" (en Acces) y dentro de ella una tabla llamada "Especies" y dentro de esa tabla un campo o columna llamado "nombre".
lo que quiero es que en un listbox se carguen los casi doscientos nombres de animales que tengo en ese campo de esa base de datos.

lo ideal seria conectarme a la base de datos mediante ADO (pero no se hacerlo tampoco)
por favor enviadme el codigo si no es molestia...

muchas gracias.

[ReViJa]

Puedes echar un vistazo AQUÍ


Saludos.

[MINTZ]

Ok, Clara La Conexión, Mirando Por Ahí Ya Hyabia Encontrado Opciones Similares
Pero Me Falta Lo Imprescindible Que Es Lo Que Os Comentaba, Una Vez Hecha La Conexion Como Cargo En El Listbox Los Valores Del Campo "nombre"

Gracias

[Avellaneda]

Mira, no es tan complicado.
En el menú Proyecto -> Referencias... selecciona "Microsoft ActiveX Data Objects 2.x Library"

.x es la mayor versión que tengas en tu pc.

y colocas este código, p.e. en un CommandButton:

Código:

Private Sub Command1_Click()
    Dim rs As ADODB.Recordset
    Set rs = New ADODB.Recordset
    With rs
        .ActiveConnection = "Provider=Microsoft.jet.OLEDB.4.0;Data Source=" & _
            "C:\animales.mdb"
        .CursorType = adOpenStatic
        .CursorLocation = adUseClient
        .Open "Select * from Especies"
    End With
Do Until rs.EOF
    List1.AddItem rs!nombre
    rs.MoveNext
Loop
End Sub

Nota: En la propiedad ActiveConnection le tienes que poner la ruta completa donde se encuentra la base de datos. Si la BD está en el mismo directorio donde tienes la aplicación puedes ponerlo así:

.ActiveConnection = "Provider=Microsoft.jet.OLEDB.4.0;Data Source=" & _
App.Path & "\animales.mdb"

... y eso es todo!

[MINTZ]

te amo!!!!!! muchisimas gracias!!!!!!!!!!

espero algun dia tener los conocimientos suficientes para poder devolveros el favor ayudando a otros compañeros!

[MINTZ]

UNA PREGUNTILLA MAS.
ya tengo cargado el listbox, ahora tengo otro problema...
en la propiedad caption de la label1 quiero que me aparezca lo que llamo "grupo". "grupo" es otro campo de la base de datos (misma tabla).
lo que quiero es que si en el listbox pulso sobre un dato, en el caption de la label me ponga el valor de "grupo" (alfanumerico y menor de 256) correspondiente a ese registro.
Ejemplo:
En nla base de datos tenemos:

NOMBRE GRUPO
Gorrion Aves
Perro Mamiferos
Gato Mamiferos
Boa Reptiles

Si yo pulso sobre Perro en el listbox, en el label1.caption vere "mamifero", si luego pulso sobre Boa en el listbox, en el label1.caption vere "reptil".

Gracias por adelantado

[Avellaneda]

Sigue siendo igual de sencillo, sólo que ahora tienes que declarar el recordset a nivel de módulo para que esté presente en todas las rutinas del mismo, te pongo el ejemplo:

Código:

Dim rs As ADODB.Recordset   ' rs está declarado a nivel de módulo

Private Sub Command1_Click()
Set rs = New ADODB.Recordset
With rs
    .ActiveConnection = "Provider=Microsoft.jet.OLEDB.4.0;Data Source=" & _
        "C:\animales.mdb"
    .CursorType = adOpenStatic
    .CursorLocation = adUseClient
    .Open "Select * from Especies"
End With
Do Until rs.EOF
    List1.AddItem rs!nombre
    rs.MoveNext
Loop
End Sub

Private Sub List1_Click()
rs.MoveFirst
rs.Find "nombre = '" & List1.Text & "'"
Label1.Caption = rs!Grupo
End Sub