como Diferenciar unidades

[Angel_Snaker]

Estoy en un nuevo proyecto en el cual muestra en una lista las unidades que hay en el equipo. el asunto que me las diferencia entre "Disco Local" y "Extraible".

Pero entre las extraibles están las compacteras, las disqueteras y los pendrives.

Quisiera saber si hay una forma de diferenciar si una unidad extraible es un pendrive o una compactera, ya que las disqueteras siempre son A: o B:

[erbuson]

Mira en Recursos VB, en este enlace Tipos de Unidades, ...

Saludos

[Angel_Snaker]

Iniciado por erbuson

Mira en Recursos VB, en este enlace [URL="http://www.recursosvisualbasic.com.ar/htm/listado-api/api-29.htm"]Tipos de Unidades, ...[/URL]

Saludos

Como dije anteriormente me dice Unidad removible (o extraible) tanto a los CD como a los pen

yo necesito mostrar cuando una unidad es CD y Cuando es Pendrive

Código:

' Función Api GetDriveType para obtener el tipo y clase de unidad
Private Declare Function GetDriveType _
    Lib "kernel32" _
    Alias "GetDriveTypeA" ( _
    ByVal nDrive As String) As Long

Private Sub Command1_Click()
' Llamamos a la función pasandole la unidad que queremos obtener la información
Select Case GetDriveType(Trim(Text1))
        Case 2
            ' Unidad de tipo removible, por ejemplo la unidad A:
            MsgBox "Unidad removible"
        Case 3
            ' Por ejemplo un disco duro
            MsgBox "Unidad Fija"
        Case Is = 4
            ' Una unidad de red
            MsgBox "Unidad remota"
        Case Is = 5
            'Unidad de Cd - Dvd
            MsgBox "Unidad de Cd-Rom"
        Case Is = 6
            ' Para una unidad de dsico Virtual
            MsgBox "Unidad virtual"
        Case Else
            'Cuando es desconocida
            MsgBox "Unidad no reconocida"
    End Select
End Sub

Gracias por la respuesta

[Angel_Snaker]

Te doy un ejemplo de lo que quiero hacer

En una lista poner:

Disco Local C:

Pen Drive D:

Compactera E:

[erbuson]

Hola:
Con este código modificado para evitar multiples llamadas en mi equipo con Windows XP me los detecta igual que el sistema.

Código vb:

Option Explicit
 
'Función Api getLogicalDrives para recuperar las unidades
Private Declare Function GetLogicalDrives Lib "kernel32" () As Long
 
' Función Api GetDriveType para obtener el tipo y clase de unidad
Private Declare Function GetDriveType _
    Lib "kernel32" _
    Alias "GetDriveTypeA" ( _
    ByVal nDrive As String) As Long
 
Private Function TipoUnidad(Unidad As String) As String
' Llamamos a la función pasandole la unidad que queremos obtener la información
Select Case GetDriveType(Trim(Unidad & ":\"))
        Case 2
            ' Unidad de tipo removible, por ejemplo la unidad A:
            TipoUnidad = Unidad & ":\ Unidad removible"
        Case 3
            ' Por ejemplo un disco duro
            TipoUnidad = Unidad & ":\ Unidad Fija"
        Case Is = 4
            ' Una unidad de red
            TipoUnidad = Unidad & ":\ Unidad remota"
        Case Is = 5
            'Unidad de Cd - Dvd
            TipoUnidad = Unidad & ":\ Unidad de Cd-Rom"
        Case Is = 6
            ' Para una unidad de dsico Virtual
            TipoUnidad = Unidad & ":\ Unidad virtual"
        Case Else
            'Cuando es desconocida
            TipoUnidad = Unidad & ":\ Unidad no reconocida"
    End Select
End Function
 
 
Private Sub Command1_Click()
Dim LDs As Long, Cnt As Long, sDrives As String
    
    LDs = GetLogicalDrives
    sDrives = "Drives disponibles: "
    For Cnt = 0 To 25
        If (LDs And 2 ^ Cnt) <> 0 Then
            'sDrives = sDrives + " " + Chr$(65 + Cnt)
            MsgBox TipoUnidad(Chr$(65 + Cnt))
        End If
    
    Next Cnt
'Mostramos las unidades
'MsgBox sDrives, vbInformation, "Drives del sistema"
 
End Sub