Como hacer un backup en vb 6.0

[mosquitoislero]

Hola, alguien podria explicarme como hacer backup de la base de datos... Trabajo con visual basic 6.0 en una base de access.
Muchas gracias.

[Avellaneda]

Iniciado por mosquitoislero

Hola, alguien podria explicarme como hacer backup de la base de datos... Trabajo con visual basic 6.0 en una base de access.
Muchas gracias.

Hola, mejor que explicarlo, te pongo un ejemplo comentado:

Código:

Public Function CopiaBD(sOrigen As String, sDestino As String) As String
    ' nota: tiene que estar marcada la referencia "Microsoft Access xx.x Object Library"
    Dim oAccess As New Access.Application
    ' comprobar que la BD origen existe
    If Len(Dir$(sOrigen)) = 0 Then
        CopiaBD = "La base de datos '" & sOrigen & "' no existe"
        Exit Function
    End If
    Screen.MousePointer = vbHourglass
    ' si ya existe el archivo de copia, lo eliminamos
    If Len(Dir$(sDestino)) Then Kill sDestino
    oAccess.CompactRepair sOrigen, sDestino
    Screen.MousePointer = vbDefault
    CopiaBD = "Realizada copia con éxito en '" & sDestino & "'."
End Function

Para llamar a esta función, prodrías poner el siguiente código p.e. en un Botón:

Código:

Private Sub cmdBacKUp_Click()
' Notas: Si existe alguna conexión abierta a la BD, cerrar primero
' If conexion.State = 1 Then conexion.Close
' La carpeta BackUp tiene que existir en el directorio de la aplicación
MsgBox CopiaBD(App.Path & "\MiDb.mdb", App.Path & "\BackUp\Copia de MiDb.mdb")
End Sub

[SalomonSab]

Disculpa Avellaneda pero si la base de datos tiene contraseña, como funcionaria

[mosquitoislero]

Gracias avellaneda, una pregunta mas antes de probar con lo que me dijiste...

' comprobar que la BD origen existe
If Len(Dir$(sOrigen)) = 0 Then

donde dice: (Dir$(sOrigen)) debo colocar la ruta de origen, p.e. ("C:\Documents and Settings\Ema\My Documents\Seminario\origen.mdb")

Gracias de nuevo...

Saludos.

[Avellaneda]

Iniciado por mosquitoislero

Gracias avellaneda, una pregunta mas antes de probar con lo que me dijiste...

' comprobar que la BD origen existe
If Len(Dir$(sOrigen)) = 0 Then

donde dice: (Dir$(sOrigen)) debo colocar la ruta de origen, p.e. ("C:\Documents and Settings\Ema\My Documents\Seminario\origen.mdb")

Gracias de nuevo...

Saludos.

Así es, pero si estás utilizando la función se lo pasas como primer parámetro.

Para SalomonSab

En ése caso utilizamos la referencia a JRO

Código:

Public Function CopiaBDPwd(sOrigen As String, sDestino As String, sPwd As String) As String
    ' marcar referencia: Microsof Jet and Replication objects 2.6 Library
    Dim je As JRO.JetEngine
    Set je = New JRO.JetEngine

    If Len(Dir$(sDestino)) Then Kill sDestino
    je.CompactDatabase "Data Source=" & sOrigen & ";" & _
        "Jet OLEDB:Database Password=" & sPwd, _
        "Data Source=" & sDestino & ";" & _
        "Jet OLEDB:Database Password=" & sPwd
    
    CopiaBDPwd = "Realizada copia con éxito en '" & sDestino & "'."
End Function

La llamada a la función es igual a la anterior, pero pasándole un tercer parámetro con la password.

[SalomonSab]

Excelente Gracias Avellaneda

[danielkrrik]

Hola. Estoy haciendo una aplicación vb 6.0 y he aplicado este código para hacer un backup. En el proyecto funciona perfecto, pero cuando empaqueto, si bien sDestino funciona perfecto, el error que me da es el 3051. La ruta está bien, pero creo que la base access es de solo lectura, incluso cuando trato de arreglarlo desde el mismo access me dice que no puede abrir el archivo.
¿Podrían ayudarme, por favor?
Desde ya muchas gracias.