comprobar existencia de directorio en vb6

[matu2982]

Hola estoy desarrollando un programa que aparte de otras cosas abre una ficha que muestra datos de base dde datos de sql server y ademas lee la ruta completa y archivo de una columna de datos con el siguente formato:

\\Matias\Directorio\fichero.jpg o C:\Directorio\fichero.jpg

necesitaria saber si hay alguna funcion o procediemiento para comprobar la existencia de un directorio, no un fichero en si, que eso lo se hacer, pero un directorio, porque al poner una ruta que no existe el compilador me reporta un error, si pongo la ruta correcta y un fichero que no existe funciona bien y puedo poner mi cartel personalisado como "el fichero no existe".

No se si me explico bien. En sintesis si hay un error al leer la ruta entera que me muestre un cartel hecho por mi, pero no el tipico cartel de depurar del comilador.

Desde ya Gracias

[emilio21]

Hola!

coloca esto en un modulo:

Código:

Option Explicit

Public Const INVALID_HANDLE_VALUE = -1
Public Const MAX_PATH = 260

Public Type FILETIME
   dwLowDateTime As Long
   dwHighDateTime As Long
End Type

Public Type WIN32_FIND_DATA
   dwFileAttributes As Long
   ftCreationTime As FILETIME
   ftLastAccessTime As FILETIME
   ftLastWriteTime As FILETIME
   nFileSizeHigh As Long
   nFileSizeLow As Long
   dwReserved0 As Long
   dwReserved1 As Long
   cFileName As String * MAX_PATH
   cAlternate As String * 14
End Type

Public Declare Function FindFirstFile Lib "kernel32" _
   Alias "FindFirstFileA" _
  (ByVal lpFileName As String, _
   lpFindFileData As WIN32_FIND_DATA) As Long

Public Declare Function FindClose Lib "kernel32" _
  (ByVal hFindFile As Long) As Long

Public Function FileExists(sSource As String) As Boolean

   Dim WFD As WIN32_FIND_DATA
   Dim hFile As Long
   
   hFile = FindFirstFile(sSource, WFD)
   FileExists = hFile <> INVALID_HANDLE_VALUE
   
   Call FindClose(hFile)

End Function

al momento de verificar el directorio pones

Código:

if FileExists("Mi_directorio") = True then
    msgbox "Existe"
else
    msgbox "No Existe"
end if

ESTO FUNCIONA PARA ARCHIVOS Y DIRECTORIOS

espero te sirva!