Formato en columnas de Listview

[franko1809]

Necesito ponerle formato a los campos numericos de un listview, utilizo una funcion que encontre para cargar un recordset, los campos numericos son precio y precio2 dejo el codigo que tengo y si tienen otro que funciona mejor estaria bien.

Código:

Sub Cargar_ListView(ListView As ListView, sql As String, PathBd As String)

    Dim Campo As Integer

    On Error GoTo ErrSub

    'Variable para los SubItem del LV
    Dim Item As ListItem
    Dim i As Long

    'Nuevo objeto Connection y objeto Recordset
    Set cnn = New Connection
    Set Rst = New Recordset

    'Abre la base de datos
    cnn.Open ("Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & PathBd)

    'Llena el Recordset
    Rst.Open sql, cnn, adOpenDynamic, adLockOptimistic
    
    With ListView
        'Vista de reporte
        .View = lvwReport
        ' Elimina los item y los encabezado de columna
        .ListItems.Clear
        .ColumnHeaders.Clear
    End With

    Me.MousePointer = vbHourglass

    'Agrega los nombres campo junto con los encabezados de columna para el ListView
    'For Campo = 0 To Rst.Fields.Count - 1
        'ListView.ColumnHeaders.Add , , Rst.Fields(Campo).Name
    'Next
ListView.ColumnHeaders.Add , , "codigo", 1000
ListView.ColumnHeaders.Add , , "nombre", 4000
ListView.ColumnHeaders.Add , , "precio", 1000, lvwColumnRight
ListView.ColumnHeaders.Add , , "precio2", 1000, lvwColumnRight

    ' Recorre todos los registros del Recordset
    While Not Rst.EOF
        'Agrega el Item
        Set Item = ListView.ListItems.Add(, , Rst.Fields(0), , 1)
        i = 1

        'Agrega los SubItem al ListView mediante la variable ITEM
        For Campo = 1 To Rst.Fields.Count - 1
    
            'si el dato no es de tipo Null lo agrega
            If Not IsNull(Rst.Fields(Campo)) Then
                Item.SubItems(i) = Rst.Fields(Campo)
            End If
            i = i + 1
        Next
    
    'Siguiente registro
    Rst.MoveNext
    Wend
    Me.MousePointer = vbDefault

Exit Sub
'Error
ErrSub:

    MsgBox Err.Description, vbCritical, "Error"
    Me.MousePointer = vbDefault
End Sub

[pkj]

Para resumir te hago una sub

Código :

Sub CambiaFormatoColumna(ByRef ControlListView As ListView, ByVal NumColumna As Integer, ByVal NuevoFormato As Variant)
  Dim F As Long
  For F = 1 To ControlListView.ListItems.Count   ' - 1  'Parece ser que si pongo -1 se queda el ultimo sin cambiar
    ControlListView.ListItems(F).ListSubItems(NumColumna).Text = Format(ControlListView.ListItems(F).ListSubItems(NumColumna).Text, NuevoFormato)
  Next F
End Sub
 

Para usarla añade en tu código detrás del Wend:

CambiaFormatoColumna ListView, 2, "00,000"
CambiaFormatoColumna ListView, 3, "00,000"

cambiando el "00,000" por tu formato

Espero que te sirva.

[lokoman]

Hola!!
Un poco mas corto:
En la linea donde cargas los datos:

'si el dato no es de tipo Null lo agrega
If Not IsNull(Rst.Fields(Campo)) Then
if Rst.Fields(Campo).name="precio" or Rst.Fields(Campo).name="precio2" then
Item.SubItems(i) = FormatNumber(Rst.Fields(Campo).Value, 2)
else
Item.SubItems(i) = Rst.Fields(Campo)
endif
End If

[franko1809]

Muy bueno ambas corren perfectamente.
Tengo otra consulta si quiero cargar las cabeceras automaticamente, como hago para colocarle el ancho y alineacion a cada una de ellas.
Manualmente esta asi:

Código:

ListView.ColumnHeaders.Add , , "precio", 1000, lvwColumnRight

Y de esta forma no tengo esa posibilidad, que recomiendan?

Código:

For Campo = 0 To Rst.Fields.Count - 1
     ListView.ColumnHeaders.Add , , Rst.Fields(Campo).Name
Next

[lokoman]

Es igual, solo pon los parametros que faltan:

For Campo = 0 To Rst.Fields.Count - 1
if Campo=0 then
ListView.ColumnHeaders.Add , , Rst.Fields(Campo).Name, 1000, lvwColumnLeft ' La primera siempre es a la izquierda
Else
ListView.ColumnHeaders.Add , , Rst.Fields(Campo).Name, 1000, lvwColumnRight ' La segunda lo que quieras
end if
Next

[pkj]

Para cambiar el ancho de la columna 1:

ListView.ColumnHeaders(1).Width = 3000