Linea de comandos (procesos)

[vvictoristudio]

Saludos...

Necesito saber la linea de comando con la que se ha iniciado un determinado proceso. Si alguien sabe como hacerlo por favor hagamelo saber.

Gracias de antemano

[pkj]

¿a que te refieres con un proceso?

Si lo que quieres es ver los parámetros incluidos en una llamada a un ejecutable de vb los consigues de Command$.

Dim LineaDeParametros As String
LineaDeParametros = Command$

Saludos

[vvictoristudio]

Iniciado por pkj

¿a que te refieres con un proceso?

Si lo que quieres es ver los parámetros incluidos en una llamada a un ejecutable de vb los consigues de Command$.

Dim LineaDeParametros As String
LineaDeParametros = Command$

Saludos

me explico...
estoy haciendo un visor de procesos activos (como un administrador de tareas de windows) y necesito determinar la linea de comandos con que se inicio un determinado proceso. Yo encontre un metodo pero no es muy efectivo ya que demora un poco, para esto use (WMI) y lo que necesito es alguna API u otro metodo

[seba123neo]

Hola, proba esto:

Código vb:

Option Explicit
 
Private Type OBJECT_ATTRIBUTES
    Length As Long
    RootDirectory As Long
    ObjectName As Long
    Attributes As Long
    SecurityDescriptor As Long
    SecurityQualityOfService As Long
End Type
 
Private Type CLIENT_ID
    UniqueProcess As Long
    UniqueThread  As Long
End Type
 
Private Declare Function NtOpenProcess Lib "NTDLL.DLL" (ByRef ProcessHandle As Long, ByVal AccessMask As Long, ByRef ObjectAttributes As OBJECT_ATTRIBUTES, ByRef ClientID As CLIENT_ID) As Long
Private Declare Function NtClose Lib "NTDLL.DLL" (ByVal ObjectHandle As Long) As Long
Private Declare Function ReadProcessMemory Lib "kernel32" (ByVal hProcess As Long, lpBaseAddress As Any, lpBuffer As Any, ByVal nSize As Long, lpNumberOfBytesWritten As Long) As Long
Private Declare Function GetModuleHandle Lib "kernel32" Alias "GetModuleHandleA" (ByVal lpModuleName As String) As Long
Private Declare Function GetProcAddress Lib "kernel32" (ByVal hModule As Long, ByVal lpProcName As String) As Long
Private Declare Sub CopyMemory Lib "kernel32.dll" Alias "RtlMoveMemory" (ByRef Destination As Any, ByRef Source As Any, ByVal Length As Long)
Private Declare Function GetCurrentProcessId Lib "kernel32" () As Long
 
Private Function GetProcessCommandLine(ByVal dwProcessId As Long) As String
    Dim objCid As CLIENT_ID
    Dim objOa As OBJECT_ATTRIBUTES
    Dim ntStatus As Long, hKernel As Long, strName As String
    Dim hProcess As Long, dwAddr As Long, dwRead As Long
    objOa.Length = Len(objOa)
    objCid.UniqueProcess = dwProcessId
    ntStatus = NtOpenProcess(hProcess, &H10, objOa, objCid)
    If hProcess = 0 Then
        GetProcessCommandLine = "[Not Available]"
        Exit Function
    End If
    hKernel = GetModuleHandle("kernel32")
    dwAddr = GetProcAddress(hKernel, "GetCommandLineA")
    CopyMemory dwAddr, ByVal dwAddr + 1, 4
    If ReadProcessMemory(hProcess, ByVal dwAddr, dwAddr, 4, dwRead) Then
        strName = String(260, Chr(0))
        If ReadProcessMemory(hProcess, ByVal dwAddr, ByVal strName, 260, dwRead) Then
            strName = Left(strName, InStr(strName, Chr(0)) - 1)
            GetProcessCommandLine = strName
        End If
    End If
    NtClose hProcess
End Function
 
Private Sub Form_Load()
    MsgBox GetProcessCommandLine(GetCurrentProcessId())
End Sub
 

saludos.

[vvictoristudio]

Muchas gracias por tu colaboracion sebal23neo, es ke hoy fue ke pude revisar el foro.
me sirvio lo ke me diste... thanks si kieres saber mas hazmelo saber a [email protected]