Mover Mouse Con PictureBox

[Jhonjhon_123]

Hola!
Bueno, tengo un codigo que me hace una captura de pantalla y la carga en el Picture1, lo que quiero hacer es que al hace click en el Picture1, me haga un click en la pantalla real correspondiente a la imagen cargada
Como ago eso??
Unas de las apis que conosco son:
SetCursorPos, GetCursorPos, pero no se como tomar las coordenadas del picture1 y convertirlas deauerdo a la resolucion de pantalla
Gracias!

[pkj]

Creo que lo que pides se saca así:

Código vb:

Private Sub Picture1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
  Dim PosRealX As Single
  Dim PosRealY As Single
  Dim Difer As Double
 
  Difer = Screen.Width / Picture1.ScaleWidth
  PosRealX = X * Difer
 
  Difer = Screen.Height / Picture1.ScaleHeight
  PosRealY = Y * Difer
 
End Sub
 

Aunque si quieres usar las coordenadas con GetCursorPos creo tienes que dividir el resultado por TwipsPerPixel:

Código vb:

Private Sub Picture1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
  Dim PosRealX As Single
  Dim PosRealY As Single
  Dim Difer As Double
 
  Difer = Screen.Width / Picture1.ScaleWidth
  PosRealX = X * Difer / Screen.TwipsPerPixelX
 
  Difer = Screen.Height / Picture1.ScaleHeight
  PosRealY = Y * Difer / Screen.TwipsPerPixelY
 
End Sub
 

Por cierto, solo sirve con PictureBox. Si usas Images te encontrarás con que no tienen propiedad ScaleHeight y ScaleWidth y no he encontrado equivalente, así que he tenido que aprender primero como escalar una imagen en un picturebox

El problema está en pinchar donde quieres sin mover el ratón.
Yo no he conseguido nada más que pinchar con el botón derecho y desplegar el menú, solo que el menú me aparece debajo del ratón, en lugar de en la ventana donde he pinchado.

Espero que tengas mas suerte. Si lo consigues cuentanos como lo has hecho.

Saludos

[pkj]

El caso es que a poco de empezar se me metió en la cabeza poder manejar la ventana desde el picturebox, me he liado un montón y cuando he acordado había perdido el hilo de tu tema.

En realidad, si solo quieres pinchar en la zona deseada desde el picturebox si que lo he conseguido con SetCursorPos y mouse_event, aunque habría que depurarlo un poco.
Seguramente tú no tengas problemas con eso.

Saludos

[Jhonjhon_123]

Iniciado por pkj

Creo que lo que pides se saca así:

Código vb:

Private Sub Picture1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
  Dim PosRealX As Single
  Dim PosRealY As Single
  Dim Difer As Double
 
  Difer = Screen.Width / Picture1.ScaleWidth
  PosRealX = X * Difer
 
  Difer = Screen.Height / Picture1.ScaleHeight
  PosRealY = Y * Difer
 
End Sub
 

Aunque si quieres usar las coordenadas con GetCursorPos creo tienes que dividir el resultado por TwipsPerPixel:

Código vb:

Private Sub Picture1_MouseDown(Button As Integer, Shift As Integer, X As Single, Y As Single)
  Dim PosRealX As Single
  Dim PosRealY As Single
  Dim Difer As Double
 
  Difer = Screen.Width / Picture1.ScaleWidth
  PosRealX = X * Difer / Screen.TwipsPerPixelX
 
  Difer = Screen.Height / Picture1.ScaleHeight
  PosRealY = Y * Difer / Screen.TwipsPerPixelY
 
End Sub
 

Por cierto, solo sirve con PictureBox. Si usas Images te encontrarás con que no tienen propiedad ScaleHeight y ScaleWidth y no he encontrado equivalente, así que he tenido que aprender primero como escalar una imagen en un picturebox

El problema está en pinchar donde quieres sin mover el ratón.
Yo no he conseguido nada más que pinchar con el botón derecho y desplegar el menú, solo que el menú me aparece debajo del ratón, en lugar de en la ventana donde he pinchado.

Espero que tengas mas suerte. Si lo consigues cuentanos como lo has hecho.

Saludos

Listo! tengo el Sig code:

Código:

Private Declare Function SetCursorPos Lib "user32.dll" _
(ByVal x As Long, ByVal y As Long) As Long

Private Declare Sub mouse_event Lib "user32" (ByVal dwFlags As Long, _
                                            ByVal dx As Long, _
                                            ByVal dy As Long, _
                                            ByVal cButtons As Long, _
                                            ByVal dwExtraInfo As Long)
    
 Const MOUSEEVENTF_ABSOLUTE = &H8000 '  movimiento absoluto
 Const MOUSEEVENTF_LEFTDOWN = &H2 '  botón izquierdo presionado
 Const MOUSEEVENTF_LEFTUP = &H4 '  botón izquierdo soltado
 Const MOUSEEVENTF_MIDDLEDOWN = &H20 '  botón central presionado
 Const MOUSEEVENTF_MIDDLEUP = &H40 ' botón central soltado
 Const MOUSEEVENTF_MOVE = &H1 '  movimiento del mouse
 Const MOUSEEVENTF_RIGHTDOWN = &H8 '  botón derecho presionado
 Const MOUSEEVENTF_RIGHTUP = &H10 '  botón derecho soltado


Private Sub Picture1_MouseDown(Button As Integer, Shift As Integer, x As Single, y As Single)
Dim PosRealX As Single
Dim PosRealY As Single
Dim Difer As Double
 
Difer = Screen.Width / Picture1.ScaleWidth
PosRealX = x * Difer / Screen.TwipsPerPixelX
 
Difer = Screen.Height / Picture1.ScaleHeight
PosRealY = y * Difer / Screen.TwipsPerPixelY
  
Call SetCursorPos(PosRealX, PosRealY)

If Button = 1 Then
    Call mouse_event(MOUSEEVENTF_LEFTDOWN, 0&, 0&, 0&, 0&)
    Call mouse_event(MOUSEEVENTF_LEFTUP, 0&, 0&, 0&, 0&)
ElseIf Button = 2 Then
    Call mouse_event(MOUSEEVENTF_RIGHTDOWN, 0&, 0&, 0&, 0&)
    Call mouse_event(MOUSEEVENTF_RIGHTUP, 0&, 0&, 0&, 0&)
End If

End Sub

Ahora supongamos que he pasado las coordenadas a un pc remoto, como comviertolas coordenadas??

[seba123neo]

¿como convertirlas? lo unico que debes hacer es pasarle al servidor las cordenadas X,Y y despues en el servidor pasarle esas coordenadas a la api SetCursorPos y despues a mouse_event para que haga click.

saludos.

[Jhonjhon_123]

Iniciado por seba123neo

¿como convertirlas? lo unico que debes hacer es pasarle al servidor las cordenadas X,Y y despues en el servidor pasarle esas coordenadas a la api SetCursorPos y despues a mouse_event para que haga click.

saludos.

Si, supongo que mis coordenadas no son utiles en otro pc con distinta resolucion.

Si no es haci porfavor corrigeme

[seba123neo]

el tema aca es que la "captura" deberia ser de la pc remota, no de la tuya.

[Jhonjhon_123]

Iniciado por seba123neo

el tema aca es que la "captura" deberia ser de la pc remota, no de la tuya.

Claro, pero esa captura se envia a un pixtureBox en el PC mio, al hacer yo click en mi picture envio las coordenadas al pc remoto, como combierto las coordenadas??

[pkj]

En ese caso lo que tienes que hacer es, en el evento mousedown, mandar el valor de X, Y y Button al pc remoto, puede que incluso picture1.scalewidth y scaleheight porque es este picture el que pinchas. El caso es que es en el PC remoto donde tienes que hacer la conversión con screen.height y screen.width que serán los que marquen la resolución del pc remoto.
Espero que se entienda.

Suerte