Obtener color de pixel de la pantalla de windows???

[milomdq]

Buenas!
Alguien sabe como se podria obtener el color de un pixel de la pantalla de windows fuera del programa en ejecucion??

Yo lo hacia con un picturebox por ejemplo y me tiraba en color en hexadecimal en un text.
Pero esta vez necesito hacerlo fuera de lo que seria el form..
Alguien sabe como se puede hacer??

Gracias!!

[seba123neo]

Hola, proba esto:

Código vb:

Option Explicit
 
Private Type POINTAPI
    x As Long
    y As Long
End Type
 
Private Declare Function GetPixel Lib "gdi32" (ByVal hdc As Long, ByVal x As Long, ByVal y As Long) As Long
Private Declare Function GetCursorPos Lib "user32" (lpPoint As POINTAPI) As Long
Private Declare Function GetWindowDC Lib "user32" (ByVal hwnd As Long) As Long
 
Private Sub Form_Load()
    Timer1.Interval = 100
End Sub
 
Private Sub Timer1_Timer()
    Dim tPOS As POINTAPI
    Dim sTmp As String
    Dim lColor As Long
    Dim lDC As Long
    lDC = GetWindowDC(0)
    Call GetCursorPos(tPOS)
    lColor = GetPixel(lDC, tPOS.x, tPOS.y)
    Me.BackColor = lColor
    sTmp = Right$("000000" & Hex(lColor), 6)
    Me.Caption = "R:" & Right$(sTmp, 2) & " G:" & Mid$(sTmp, 3, 2) & " B:" & Left$(sTmp, 2)
End Sub
 

saludos.

[milomdq]

uhh seba, sos un capo... respondiste a mi pregunta!
Muchisimas gracias!
Saludos!

[joj9]

Una preguntilla, y no habría alguna manera de hacer eso pero sin un timer??? sino que directamente lo haga al mover el raton???
esk para el evento mousemove se tiene que indicar sobre que objeto se va ha mover (Ej: picture1_mousemove), y si es para toda la pantalla, o todo el formulario dificil...
Aver si alguien podría ayudarme.

Muchas gracias de antemano! :)

[pkj]

No está muy claro lo que preguntas.
La sub la puedes usar cuando y como quieras. No necesitas un timer.
Puedes llamarla desde el mousemove o desde el click de cualquier objeto de tu formulario.
Solo tienes que renombrar la sub y usarla donde la necesites.
Aunque también se puede convertir en función y que devuelva el valor:
Nota: Las declaraciones de las funciones y la variable de tipo pointapi hay que copiarlas del mensaje anterior.

Código vb:

Private Function MiraColorPixel() As Long
    Dim tPOS As POINTAPI
    Dim lColor As Long
    Dim lDC As Long
    lDC = GetWindowDC(0)
    Call GetCursorPos(tPOS)
    MiraColorPixel = GetPixel(lDC, tPOS.X, tPOS.Y)
End Function
 

2 Pictures. Cargamos una imagen en Picture1 y al pasar el ratón cambia el color de Picture2.

Código vb:

Private Sub Picture1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
  Dim ColorPixel As Long
  Dim sTmp As String
  ColorPixel = MiraColorPixel
  sTmp = Right$("000000" & Hex(ColorPixel), 6)
  Me.Caption = "R:" & Right$(sTmp, 2) & " G:" & Mid$(sTmp, 3, 2) & " B:" & Left$(sTmp, 2)
  Picture2.BackColor = ColorPixel
End Sub
 

¿Es eso lo que quieres hacer?

[joj9]

Sorry. Fallo al escribir el mensaje.

[joj9]

Gracias por responder.
Lo que quiero hacer es exactamente lo del 2º codigo pero que no esté obligado a pasar el raton por la picture1, sino que pueda hacerlo por cualquier parte del form, o por cualquier parte de la pantalla si puede ser tambien.
Porque ya se que se puede usar como funcion, como pusiste en el primer codigo, de tal forma que quedaría así:

Código:

Private Function MiraColorPixel() As Long
    Dim tPOS As POINTAPI
    Dim lColor As Long
    Dim lDC As Long
    lDC = GetWindowDC(0)
    Call GetCursorPos(tPOS)
    MiraColorPixel = GetPixel(lDC, tPOS.X, tPOS.Y)
End Function

Private Sub picture1_MouseMove(Button As Integer, Shift As Integer, X As Single, Y As Single)
    Picture2.BackColor = MiraColorPixel
End Sub

pero seguiría restringido a la picture1 ("picture1_mousemove"), y amí lo que me interesa no es que esté restringido el movimiento a picture1 sinó a todo el form o a la pantalla entera.

[pkj]

Sigo sin llegar a aclararme de lo que quieres hacer.
El código de seba123neo funciona en cualquier parte de la pantalla.
Si lo que quieres es mirar cualquier pixel sin llevar el cursor hasta él, imagino que solo tienes que conseguir primero las coordenadas del punto que quieres mirar y luego hacer algo así:

Código vb:

Private Function MiraColorPixel(byval X as long, byVal Y As Long) As Long
    Dim lDC As Long
    lDC = GetWindowDC(0)
    MiraColorPixel = GetPixel(lDC, X, Y)
End Function
 

ColorPixel=MiraColorPixel (X,Y)

[joj9]

Claro que funciona en cualquier lugar de la pantalla, pero utilizando un timer, y lo que yo quiero es sin utilizar el timer, al igual que lo hago con 2 picturebox, sin timer, para toda la pantalla sin timer. :)

[pkj]

Por eso no me entraba a mi en la cabeza.
Osea, quieres lo que había pero sin timer. Simplemente.
Pues no se. Si te vale un timer hecho en un control de usuario, que no hay que insertarlo en el form, eso si lo he visto alguna vez.
En última instancia puedes hacer una sub "sin salida" y llamarla al inicio.

Código vb:

Sub MiraPixels()
Inicio:
  Picture2.BackColor = MiraColorPixel
  DoEvents
  Goto Inicio
End Sub
 

Igual funciona...

[joj9]

Prefiero usar un Timer antes que el Goto, ya que el goto no me gusta usarlo nunca en programación...
Así que bueno, usare el timer :)
Y muchas gracias de todas formas pkj!!! ;)

[pkj]

El GoTo siempre se puede cambiar por un Do Loop. Total, para hacer un bucle infinto no se necesita poner mucho empeño... aparecen solos

Que haya suerte.

[cvaz]

tengo una duda..
¿¿ como seria si quisiera sacar un promedio del color de una imagen pequeña... (masomenos 100px x100px) ??


se vuelve complicado por que hay que tener en cuenta los porcentajes de RGB? comparandolo con el numero en hexadecimal.. o es mas simple.. ???