Obtener datos de creación y modificación de archivos sin necesidad de APIs

[Tano Mendoza]

Como obtener datos de creación, modificación y acceso a archivos en forma simple:

1 - Crea un formulario.
2 - Haz una referencia al objeto del sistema de archivos,
para ello abre el menú Proyecto/Referencias...
y selecciona Microsoft Scripting Runtime (ScrRun.dll)

3 - Crea los siguientes objetos:
Text1 (TextBox)
Creado (Label)
Modificado (Label)
Accedido (Label)
Buscar (CommandButton)
Salir (CommandButton)
Mensaje (Label)

Pega el siguiente código :

Option Explicit
Private Handler As FileSystemObject

'Haz una referencia al objeto del sistema de archivos,
'para ello abre el menú Proyecto/Referencias...
'y selecciona Microsoft Scripting Runtime (ScrRun.dll)

Private Sub Form_Load()
' Crear la referencia al File System Object (objeto del sistema de archivos)
Set Handler = New FileSystemObject

'Centrar formulario
Move (Screen.Width - Width) / 2, (Screen.Height - Height) / 2

End Sub



Private Sub Buscar_Click(Index As Integer)
' Manipular ficheros
Dim FileRef As File ' Objeto para acceder a las propiedades de los ficheros
Dim NombreArchivo As String
Dim sinfo As String
Creado.Caption = ""
Accedido.Caption = ""
Modificado.Caption = ""
Mensaje.Visible = False

NombreArchivo = Trim(Text1.Text)
On Error GoTo Salida
Set FileRef = Handler.GetFile(NombreArchivo)
' Si el objeto tiene información, mostrarla
If Not (FileRef Is Nothing) Then
Creado.Caption = FileRef.DateCreated
Accedido.Caption = FileRef.DateLastAccessed
Modificado.Caption = FileRef.DateLastModified
End If
On Error GoTo 0
Exit Sub

Salida:
Mensaje.Visible = True
On Error GoTo 0

End Sub

Private Sub Salir_Click()
Set Handler = Nothing
End
End Sub

[[EX3]]

Iniciado por Tano Mendoza

2 - Haz una referencia al objeto del sistema de archivos,
para ello abre el menú Proyecto/Referencias...
y selecciona Microsoft Scripting Runtime (ScrRun.dll)

Obtener datos de creación y modificación de archivos sin necesidad de APIs?
No se si lo sabras pero una DLL es un API y la ScrRun.dll aunque sea un componente ActiveX no deja de ser un API como tal... dicho de otra forma, tu ejemplo obtiene los datos mediante un API, asi que el titulo de tu post no seria correcto.

Salu2...

[matarasky]

'creado
MsgBox(File.GetCreationTime(ruta))
'modificado
MsgBox(FileSystem.FileDateTime(ruta))

[franko1809]

No me aparecen esas propiedades(GetCreationTime y FileDateTime) ya agregue la referencia y la setie.

[hugo180486]

Este es un ejemplo adaptalo a tus necesidades...

Comenta por favor si te sirvio, funciona para mas tipos de archivo no solo txt...

Código vb:

Private Sub cmd_Boton_Click()
    Consultar_Archivo ("C:\XXXXX.txt") 
End Sub
Private Sub Consultar_Archivo(Byval Path As String)
  
  
    'Variable de tipo FileSystemObject y File
  
    Dim o_Fso As New FileSystemObject
    Dim Archivo As File
  
    ' Lee las propiedades del archivo mediante GetFile
    Set Archivo = o_Fso.GetFile(Path)
  
       
    'Visualiza el resultado: Creación ,acceso y modificado etc..
    MsgBox "Fecha de creación del archivo: " & Format(Archivo.DateCreated), vbInformation
    MsgBox "Fecha de modificación : " & Format(Archivo.DateLastModified), vbInformation
    MsgBox "Fecha de del último acceso: " & Format(Archivo.DateLastAccessed), vbInformation
    MsgBox "Tamaño del archivo : " & Format(CLng(Archivo.Size) / 1024) & " MB", vbInformation
    MsgBox "Tipo de archivo : " & Format(Archivo.Type), vbInformation
       
       
    ' Elimina las variables de objeto
    Set Archivo = Nothing
    Set o_Fso = Nothing
  
  
End Sub
 

[matarasky]

Iniciado por franko1809

No me aparecen esas propiedades(GetCreationTime y FileDateTime) ya agregue la referencia y la setie.

arriba de la clase pone
Imports System.IO

[franko1809]

Funciono bien, solo que devuelve el tamaño del archivo en kb y no en MB, gracias.

[erbuson]

Iniciado por matarasky

arriba de la clase pone
Imports System.IO

Hola, sólo para aclarar este punto, has respondido con instrucciones de NET y estamos en el foro de VB Clasico 6.0

Es un simple comentario, para evitar confusiones en futuras consultas sobre este post.

Saludos