Que no salga menu al pulsar Botón Drcho

[sagutxo]

Salu2. Es posible que al pulsar el botón Drcho. del raton sobre un campo de texto no salga el menu típico de windows, copiar, pegar, ... .

Muchas gracias.

[seba123neo]

hola,proba con esto:

en un modulo pone:

Option Explicit

Public Declare Function SetWindowLong Lib "user32" Alias _
"SetWindowLongA" (ByVal hWnd As Long, ByVal nIndex As Long, _
ByVal dwNewLong As Long) As Long

Public Declare Function CallWindowProc Lib "user32" _
Alias "CallWindowProcA" (ByVal lpPrevWndFunc As Long, _
ByVal hWnd As Long, ByVal Msg As Long, ByVal wParam As Long, _
ByVal lParam As Long) As Long

Public Const GWL_WNDPROC = (-4)

Public Const WM_CONTEXTMENU = &H7B

Global lpPrevWndProc As Long
Global gHW As Long

Public Sub Hook()
lpPrevWndProc = SetWindowLong(gHW, GWL_WNDPROC, _
AddressOf gWindowProc)
End Sub

Public Sub Unhook()
Dim temp As Long
temp = SetWindowLong(gHW, GWL_WNDPROC, lpPrevWndProc)
End Sub

Public Function gWindowProc(ByVal hWnd As Long, ByVal Msg As Long, _
ByVal wParam As Long, ByVal lParam As Long) As Long
If Msg = WM_CONTEXTMENU Then
Debug.Print "Intercepted WM_CONTEXTMENU at " & Now
gWindowProc = True
Else
gWindowProc = CallWindowProc(lpPrevWndProc, hWnd, Msg, wParam, _
lParam)
End If
End Function

en el formulario con el textbox pone:

Private Sub Form_Load()
gHW = Text1.hWnd
Hook
End Sub

Private Sub Form_Unload(Cancel As Integer)
Unhook
End Sub

saludos.

[sagutxo]

Muchas gracias por ayudarme pero este código me da un error de compilacion

Código:

lpPrevWndProc = SetWindowLong(gHW, GWL_WNDPROC, _ 
AddressOf gWindowProc)

Uso no válido del operador AddressOf

[sagutxo]

Ya he conseguido compilarlo, pero me sigue saliendo el menu :(

[sagutxo]

Conseguido . Muchísimas grácias, sin tu código no lo hubiera conseguido.