Sacar el logon de windows

[magam]

Hola, necesito migrar una aplocicacion hecha en Paradox 10 a VB6 el programa comienza tomando el nombre de usuario (por ejemplo cuando muchas personas usan una misma pc cada una tiene su nombre de usuario y password), necesito saber si existe alguna opcion para sacar este nombre.
Gracias.

[Insomnia]

Hola

Puedes utilizar la API GetUserName, declaras la API en un módulo y la funcion para obtener el nombre.

Declaración de la API

Código:

'API para obtener el usuario actual
Declare Function GetUserName Lib "advapi32.dll" Alias "GetUserNameA" _
    (ByVal lpbuffer As String, nSize As Long) As Long

Función

Código:

Public Function UsuarioActual() As String
    'Esta función devuelve el nombre del Usuario
    Dim sBuffer As String
    Dim lSize As Long
    Dim sUsuario As String

    sBuffer = Space$(260)
    lSize = Len(sBuffer)
    Call GetUserName(sBuffer, lSize)
    If lSize > 0 Then
        sUsuario = Left$(sBuffer, lSize)
        'Quitarle el CHR$(0) del final...
        lSize = InStr(sUsuario, Chr$(0))
        If lSize Then
            sUsuario = Left$(sUsuario, lSize - 1)
        End If
    Else
        sUsuario = ""
    End If
    UsuarioActual = sUsuario
    
End Function

Luego en el proyecto cada vez que llames a la función UsuarioActual devolvera el nombre de usuario que ha iniciado sesión en el equipo.

--Saludos--

[magam]

Muchas gracias!!!
Estoy aprendiendo este lenguaje migrando otro que hice en otro lenguaje, gracias!