[SOLUCIONADO] Shell y devolución de codigos

[oskarrr]

En una pequeña aplicación en vb6 que estoy haciendo, necesito llamar a otra aplicación externa. El problema es que shell no me devuelve el código de salida de la aplicación externa, sino el ID del proceso. El código que uso es:

Dim CodigodeSalida As Integer
CodigodeSalida=Shell ("c:/miprogramaexterno.exe,1)
Msgbox CodigodeSalida

Y, como digo me muestra en un mensaje el ID del proceso que se ejecutó con shell, pero no el código de salida de la aplicación externa a la que llama. No he visto soluciones en la ayuda con shell. Alguna idea?

[erbuson]

Podrías explicar un poco mas a que te refieres cuando dices el CODIGO DE SALIDA, ¿ Se trata de alguna respuesta del programa ?, ¿ a saber como termino ?.

Existen programas que al salir del mismo devuelven un código de error o un codigo de que termino bien ¿ te refieres a esto ?

[oskarrr]

Exacto, así es. Uso una aplicación externa, concretamente pdftotext.exe, para pasar de pdf a texto plano y trabajarlo en mi aplicación en vb6, y el programa devuelve 0 si todo ha ido bien y otros diferentes códigos si ha habido algún error.

[erbuson]

Veras, yo tuve una necesidad similar, y te dejo aqui el código del módulo que utilizo desde hace unos años y hasta ahora funciona a la perfección.

Código vb:

Option Explicit
 
Private Type STARTUPINFO
    cb As Long
    lpReserved As String
    lpDesktop As String
    lpTitle As String
    dwX As Long
    dwY As Long
    dwXSize As Long
    dwYSize As Long
    dwXCountChars As Long
    dwYCountChars As Long
    dwFillAttribute As Long
    dwFlags As Long
    wShowWindow As Integer
    cbReserved2 As Integer
    lpReserved2 As Long
    hStdInput As Long
    hStdOutput As Long
    hStdError As Long
End Type
 
Private Type PROCESS_INFORMATION
    hProcess As Long
    hThread As Long
    dwProcessId As Long
    dwThreadId As Long
End Type
 
Private Declare Function WaitForSingleObject Lib "kernel32" (ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long
 
Private Declare Function CreateProcessA Lib "kernel32" (ByVal _
    lpApplicationName As Long, ByVal lpCommandLine As String, ByVal _
    lpProcessAttributes As Long, ByVal lpThreadAttributes As Long, _
    ByVal bInheritHandles As Long, ByVal dwCreationFlags As Long, _
    ByVal lpEnvironment As Long, ByVal lpCurrentDirectory As Long, _
    lpStartupInfo As STARTUPINFO, lpProcessInformation As _
    PROCESS_INFORMATION) As Long
 
 
Private Declare Function CloseHandle Lib "kernel32" (ByVal hObject As Long) As Long
Private Declare Function GetExitCodeProcess Lib "kernel32" (ByVal hProcess As Long, lpExitCode As Long) As Long
 
Private Const NORMAL_PRIORITY_CLASS = &H20&
Private Const HIGH_PRIORITY_CLASS = &H80
 
Private Const INFINITE = -1&
 
Public Function ExecCmd(cmdline As String) As Long
    Dim proc As PROCESS_INFORMATION
    Dim start As STARTUPINFO
    Dim ret As Long
    start.cb = Len(start)
    start.dwFlags = &H1
    start.wShowWindow = 0
    ret = CreateProcessA(0&, cmdline, 0&, 0&, 1&, HIGH_PRIORITY_CLASS, 0&, 0&, start, proc)
    'Espera a que finalice la aplicación lanzada y devuelve su código de error
    ret = WaitForSingleObject(proc.hProcess, INFINITE)
    Call GetExitCodeProcess(proc.hProcess, ret)
    Call CloseHandle(proc.hThread)
    Call CloseHandle(proc.hProcess)
    ExecCmd = ret
End Function
 

En mi caso, la siguiente funcion forma parte del módulo pero fue por mi necesidad, puede servirte de ejemplo, esto es lo que debes adaptar a tu sistema:

Código vb:

Public Function ErrorDeNIF(ByVal QueNif As String) As Integer
  Dim Retorno As Long
  Retorno = ExecCmd("java -jar valnif.jar " & QueNif)
  Select Case Retorno
    Case Is = 0:  ErrorDeNIF = 0  ' Correcto
    Case Is = 1:  ErrorDeNIF = 1  ' Incorrecto o no encontró valnif.jar
    Case Is = -1: ErrorDeNIF = 2  ' Java no se ha ejecutado
  End Select
End Function
 

Espero te sirva tanto como a mi

Saludos

[oskarrr]

Gracias. Funciona a la perfección. Espera a que acabe la aplicación externa y devuelve el código sin problemas. Y muy fácil de usar. Gracias