Sintaxis para un bucle

[Kottore]

Hola saludos.
La problemática es sencilla; tengo 100 o quizá 1000 etiquetas las cuales quisiera hacer invisibles o visibles con un simple bucle. Cómo sería la sintáxis en Visual Basic???
Hacer algo así sería muy engorroso:

label1.visible =false
label2.visible =false
label3.visible=false
...

En ActionScript lo haría así:

for(k=0;k<100;k++){
this["label"+k]._visible=false;
}


De antemano muchas gracias por sus respuestas.

[David]

Puedes indexar los Labels, y usar el índice:

Código vb:

For I = 0 To Label1.Count - 1
    Label1(I).Visible = False
Next I
 

[pana99]

Hola, otra alternativa es

Código:

Dim ctl As Object
For Each ctl In Me.Controls
   If TypeOf ctl Is Label Then
       ctl.Visible = True
   End If
Next

Espero te sirva

[darkasecas]

Iniciado por pana99

Hola, otra alternativa es

Código:

Dim ctl As Object
For Each ctl In Me.Controls
   If TypeOf ctl Is Label Then
       ctl.Visible = True
   End If
Next

Espero te sirva

Excepto que eso afectaria a todas las label, que posiblemente sean mas aparte de las label1,label2,... labelx que menciona.

[pana99]

si, es como decis.

Esto afecta a todos los labels.
Se podria aprovechar si no tenes los lables como matrix. Y si te afecta alguna que necestias, al final podes correjir su estado

Si las tenes como matriz, es mejor la solucion de David

[Kottore]

Genial genial!!!

Muchísimas gracias por todas las respuestas.
Ara mismo me dio resultado pero no puedo aplicarlo en una función :(

Private Sub Boton1_Click()
fncPrueba (1) 'Acá puede ir desde el 0 al 99
End Sub

Private Sub fncPrueba(varOpc)
label(varOpc).visible = False
End Sub

Alguna idea??

[pkj]

Creo que te ha faltado el 1.
Ya que no se ha puesto "Visible" con mayuscula creo que tu label se llama Label1

Código :

Private Sub fncPrueba(varOpc)
  label1(varOpc).visible = False
End Sub
 

[Kottore]

Iniciado por pkj

Creo que te ha faltado el 1.
Ya que no se ha puesto "Visible" con mayuscula creo que tu label se llama Label1

Código :

Private Sub fncPrueba(varOpc)
  label1(varOpc).visible = False
End Sub
 

Ah, perdón. Se me olvidó decir que tengo:

label1
label2
...
label99

y la idea es que se lance una función con determinado label a modificar así:

Private Sub Boton1_Click()
fncPrueba (1) 'Acá puede ir desde el 0 al 99
End Sub

Private Sub fncPrueba(varOpc)
label1(varOpc).visible = False
End Sub

pero este método no va.

Alguna otra idea por favor?

[pkj]

Si lo dijiste, el caso es que pensaba que ya habias creado la matriz de labels como te han comentado anteriormente.

Si eliminar todos los labels y crear una matriz es mucho trabajo porque cada label tiene un caption diferente y son muchas, tienes otra opcion:

Código :

Dim F As Integer
For F = 0 To Controls.Count -1
  If Left$(Controls(f).Name, 5) = "Label" Then
    Controls(F).Visible = False
  End If
Next F
 

PD:
Puedes usarlo en una sub como la que has mostrado para ocultar un label por su numero si pones:

Código :

Private Sub fncPrueba(varOpc)
Dim F As Integer
For F = 0 To Controls.Count -1
  If Controls(F).Name = "Label" & varOpc Then
    Controls(F).Visible = False
  End If
Next F
End Sub
 

[Kottore]

Perfecto!!
El este código va a la perfección!!! :

Código:

  Private Sub fncPrueba(varOpc)
      Dim F As Integer
      For F = 0 To Controls.Count -1
         If Controls(F).Name = "Label" & varOpc Then
          Controls(F).Visible = False
        End If
      Next F
  End Sub

Muchas gracias por la ayuda!
Todo va bien bien. Por aquí seguiré reportandome para cualquier cosa. Saludos

[David]

Una alternativa a recorrer todos los controles es usar CallByName:

Código vb:

Private Sub fncPrueba(varOpc As Integer)
    CallByName(Me, "Label" & varOpc, vbGet).Visible = False
End Sub