Ver HTML de sitio en VB6

[piojoman]

Me gustaria saber como cargo en un textbox o label el codigo html de una direccion web. Se que en .net se puede hacer con el control webbrowser.documenttext o algo asi, pero en vb6 esta propiedad no nos proporciona la misma informacion y no se como seguir!!! alguien tiene idea de como lograrlo???

El resultado a conseguir es el mismo que cuando presionamos en "ver codigo fuente" de los exploradores web, de hecho, el control tiene esa opcion pero no se como cargar los datos en un control como label o textbox en tiempo de ejecucion!!!

[vbx3m]

Es sencillo, utiliza el control Inet y escribes este codigo:

Text1.Text = Inet1.OpenURL("http://www.forosdelweb.com")

[piojoman]

excelentemente gracias por la pronta respuesta, nunca se me habia ocurrido ir por el control Inet, ya lo estaba despedazando al webbrowser, pero no terminaba de darme los datos que realmente necesitaba, mediante la propiedad .document, asi que me viene barbaro que me hayas dado la solucion para poder continuar con lo mas sencillo!!!

Muchas gracias por todo!!!

[seba123neo]

Hola,no hace falta el control inet...

Código:

Option Explicit
Public Declare Function InternetOpen Lib "wininet.dll" Alias "InternetOpenA" (ByVal sAgent As String, ByVal lAccessType As Long, ByVal sProxyName As String, ByVal sProxyBypass As String, ByVal lFlags As Long) As Long
Public Declare Function InternetOpenUrl Lib "wininet.dll" Alias "InternetOpenUrlA" (ByVal hInternetSession As Long, ByVal sURL As String, ByVal sHeaders As String, ByVal lHeadersLength As Long, ByVal lFlags As Long, ByVal lContext As Long) As Long
Public Declare Function InternetReadFile Lib "wininet.dll" (ByVal hFile As Long, ByVal sBuffer As String, ByVal lNumBytesToRead As Long, lNumberOfBytesRead As Long) As Integer
Public Declare Function InternetCloseHandle Lib "wininet.dll" (ByVal hInet As Long) As Integer

Public Const IF_FROM_CACHE = &H1000000
Public Const IF_MAKE_PERSISTENT = &H2000000
Public Const IF_NO_CACHE_WRITE = &H4000000
     
Private Const BUFFER_LEN = 256


Public Function GetUrlSource(sURL As String) As String
    Dim sBuffer As String * BUFFER_LEN, iResult As Integer, sData As String
    Dim hInternet As Long, hSession As Long, lReturn As Long

    'get the handle of the current internet connection
    hSession = InternetOpen("vb wininet", 1, vbNullString, vbNullString, 0)
    'get the handle of the url
    If hSession Then hInternet = InternetOpenUrl(hSession, sURL, vbNullString, 0, IF_NO_CACHE_WRITE, 0)
    'if we have the handle, then start reading the web page
    If hInternet Then
        'get the first chunk & buffer it.
        iResult = InternetReadFile(hInternet, sBuffer, BUFFER_LEN, lReturn)
        sData = sBuffer
        'if there's more data then keep reading it into the buffer
        Do While lReturn <> 0
            iResult = InternetReadFile(hInternet, sBuffer, BUFFER_LEN, lReturn)
            sData = sData + Mid(sBuffer, 1, lReturn)
        Loop
    End If
 
    'close the URL
    iResult = InternetCloseHandle(hInternet)

    GetUrlSource = sData
End Function

se usa asi:

Código:

Text1.Text = GetUrlSource("http://www.google.com")

saludos.

[piojoman]

gracias tambien a ti seba123neo !!!

Probe los dos metodos y dan igual resultado. Pero tengo una pregunta técnica.

Mi soft debe abrir constantemente sitios webs y leer muchos de su tag, similar a un lector de noticias RSS pero sin necesariamente de estas, aunque algunas la sean. El problema reside en que el sitio recibe muchas visitar diarias y los servers no son los mejores y con ambos metodos que me dieron consigo entrar a los sitios pero a veces tardan mas de lo deseado, mi progunta seria...¿que deberia hacer yo para poder conseguir el codigo html de forma rapida y que menos perjudique al server? o sea, la forma mas conveniente para esta tarea...

Probe con el metodo de seba123neo modificandolo para que no cargue toda la pagina sino hasta donde necesito eliminando el ciclo While por un For pero eso no representa mayor velocidad real aunque para mi deberia lograrlo...

Alguien tiene alguna sugerencia por favor!!!!