SELECT TOP con número variable

[Bravenap]

Muy buenas.

ALTER PROCEDURE PA_LibroDelDia
(
@nDias int
)
AS
BEGIN
DECLARE @posi int
SET @posi = @nDias % (SELECT COUNT(*) FROM Libros)
SELECT TOP @posi * FROM Libros
END

Por qué me dice: Línea 9: sintaxis incorrecta cerca de 'posi'

Gracias.

[Developer9]

talvez deberías concatenar el string del select, almacenarlo en una variable nvarchar y mandar a ejecutar lo almacenado

[Mithrandir]

Seguramente la cifra del TOP no sea algo que puedas usar en variables.

Tu caso es un ambiente perfectamente controlado donde el SQL dinámico es permitido. Prueba esto:

ALTER PROCEDURE PA_LibroDelDia
(
@nDias int
)
AS
BEGIN
DECLARE @posi int
DECLARE @sql NVarChar(500)
SET @posi = @nDias % (SELECT COUNT(*) FROM Libros)
SET @sql='SELECT TOP ' + Convert(NVarChar, @posi) + ' * FROM Libros'
EXEC sp_executesql @sql
END

[Andres95]

comentario:
la version 2005 de SQL Server incluye como mejora de T-SQL el uso de una expresion para el valor del TOP.
Esta padre no? ya no se requieren trucos para hacer algo que debe ser sencillo... jejeje

[Developer9]

Y como quedaría?

[Andres95]

Código:

SELECT TOP (@posi) * FROM Libros

Tambien se puede...

Código:

SELECT TOP (Select count(*) from OtraTabla) * FROM Libros

[Bravenap]

Perdón por no contestar, no he recibido los mensajes de aviso de respuesta.

Bien, la solución estaba por usar SQL dinámico ya que tengo SQL Server 2000. Funciona bien, pero me ha surgido un problema al intentar darle una vuelta de tuerca al asunto. Si intento que también la tabla sobre la que se hacen las consultas se establezca dinámicamente me empieza a dar errores de sintaxis junto a EXECUTE:

Código:

ALTER PROCEDURE PA_LibroDelDia
(
	@nDias int,
	@tabla varchar(50)
)
AS
BEGIN
	DECLARE @vSQL varchar(1000), @posi int
	SELECT @vSQL = '(' + CONVERT(varchar,@nDias) + ' % (SELECT COUNT(*) FROM ' + @tabla + ') )+1'
	SELECT @posi = EXECUTE(@vSQL)
	SELECT @vSQL = 'SELECT TOP 1 tope.*  FROM (SELECT TOP ' + CONVERT(varchar,@posi) + ' * FROM ' + @tabla + ' ORDER BY id) AS tope ORDER BY id DESC'
	
	EXECUTE(@vSQL)
END

[Andres95]

debido a que el execute se ejecuta en otro contexto diferente al sp que lo está llamando... no puedes compartir ni regresar variables....

para eso tendrias que hacer una tabla temporal y grabar ahi el valor obtenido desde el execute y luego en el sp obtener ese valor.

con tu ejemplo quedaria mas o menos asi...

Código:

DECLARE @vSQL varchar(1000), @posi int, @valor int

If Object_ID ('tempdb..#tmpValor') is not null
	Drop table #tmpValor 

create table #tmpValor (valor int) 

Execute ('Insert into #tmpValor(valor) Select count(*) from ' + @Tabla )

If (Select count(*) from #tmpValor)> 0
Begin
	Select Top 1 @valor = valor from #tmpValor 		
	Set @posi = @nDias % @valor
	Execute ('SELECT TOP 1 tope.*  FROM (SELECT TOP ' + CONVERT(varchar,@posi) + ' * FROM ' + @tabla + ' ORDER BY id) AS tope ORDER BY id DESC')
End

If Object_ID ('tempdb..#tmpValor') is not null
	Drop table #tmpValor

[Bravenap]

Entiendo. Muchas gracias, voy a probarlo.

Un saludo.

[Mithrandir]

EXEC (@sql) sucks!

sp_executesql te permite el intercambio de variables entre otras monerías.

[Andres95]

intercambio ??
como seria para que te regrese un valor en una variable??

[Mithrandir]

Un ejemplo del BOL vale más que mil palabras (digo, teclazos ):

Código:

DECLARE @IntVariable INT
DECLARE @SQLString NVARCHAR(500)
DECLARE @ParmDefinition NVARCHAR(500)

/* Build the SQL string once.*/
SET @SQLString =
     N'SELECT * FROM pubs.dbo.employee WHERE job_lvl = @level'
SET @ParmDefinition = N'@level tinyint'
/* Execute the string with the first parameter value. */
SET @IntVariable = 35
EXECUTE sp_executesql @SQLString, @ParmDefinition,
                      @level = @IntVariable
/* Execute the same string with the second parameter value. */
SET @IntVariable = 32
EXECUTE sp_executesql @SQLString, @ParmDefinition,
                      @level = @IntVariable

[Andres95]

bueno de hecho, le envias valores...
pero no te regresa nada.. a excepcion de los result sets.
por ejemplo si quisiera saber la cuenta de esos registros??
3 y 1 respectivamente... sin usar una temporal... como seria??

[Mithrandir]

Usando variables de salida dentro de la llamada. Si mal no recuerdo alguna vez lo hice funcionar, aunque no recuerdo ni por donde...

EXECUTE sp_executesql @SQLString, @ParmDefinition, @level OUTPUT

[Developer9]

Las variables de salida las tienes que declarar dentro del procedimientos como output, y no necesitas especificar valor alguno en la llamada al procedimiento

[Andres95]

pues les comento porque ya lo he buscado y no le encontre...
si tienen un ejemplo seria muy bueno... jejjeje
y asi me quitaria por fin esas latosas tablas temporales...
un saludo