Obtener datos de varias hojas excel

[pixelmaniac]

Buenas.
Necesito sacar de varias hojas excel algunos datos.
El nombre de las hojas excel van aumentando progresivamente 1.xls, 2.xls, 3.xls ....
Cada hoja excel tiene 10 páginas de donde hay que sacar 3 datos de varias celdas fijas.
Nombre empresa - A1
CIF - B5
Ingresos - C4

La idea sería desde la excel donde se van a recoger todos los datos pulsar un boton que lleva todo el codigo.
Este botón abrirá el archivo 1 e ira recorriendo las 10 páginas copiando los 3 datos de cada página a la hoja1 de la excel en una hoja que llevará de cabecerá
Nombre - CIF - Ingresos
Así se irán rellenando las filas con los datos de las x excel por lo que habría de filas:

x excel * 10 hojas -> 10x

No se si lo he explicado muy claro.
Gracias

[mrocf]

Hola! pixelmaniac. Podrías utilizar lo siguiente:

Código PHP:

  Sub Colectar_Info() 
'------------------- 
' By Cacho Rodríguez 
------------------- 
Dim myBook$, myWsh As Worksheet, shDatos As Worksheet, i As Long 
 
myBook = Dir(ThisWorkbook.Path & "\*.xls") 
If myBook = "" Then 
  MsgBox "Sin libros de extensión xls en" & vbLf & _ 
    "la carpeta " & ThisWorkbook.Path & "." 
  Exit Sub 
End If 
 
Set shDatos = Workbooks.Add(xlWBATWorksheet).ActiveSheet 
shDatos.[a1:d1] = Array("Libro -> hoja", "Nombre empresa", "CIF", "Ingresos") 
i = 1 
Application.ScreenUpdating = False 
Application.AutomationSecurity = msoAutomationSecurityForceDisable 
 
Do 
  If myBook <> ThisWorkbook.Name And Right(myBook, 3) = "xls" Then 
    Workbooks.Open ThisWorkbook.Path & "\" & myBook, , True 
    For Each myWsh In ActiveWorkbook.Sheets 
      i = 1 + i 
      shDatos.Cells(i, "a").Resize(, 4) = _ 
        Array(ActiveWorkbook.Name & " -> " & myWsh.Name, myWsh.[a1], myWsh.[b5], myWsh.[c4]) 
    Next 
    ActiveWorkbook.Close False 
  End If 
 
  myBook = Dir 
Loop Until myBook = "" 
 
Application.AutomationSecurity = msoAutomationSecurityLow 
Application.ScreenUpdating = True 
End Sub  
   

¿Te sirve la idea?...
Saludos, Cacho R.