guardar como_?

[dieguicho]

hola gente!!!
les cuento mi problema
tengo en un directorio archivos... hasta ahi ok
como puedo descargarlos con otro nombre? ej. Session.SessionID como nombre del archivo?
pero que no se modifique el archivo sino solo como una "copia"

es con fso no?
cualquiera manita me viene de pelos porque estoy en 0

saludos!

[u_goldman]

Qué tipo de archivos son?
Son para descarga?

Efectivamente con el fso puedes hacer una copia de ellos y cambiarles el nombre...pero para descargarlos

archivo= "archivo.xxx"
archivo2= "otro_nombre.xxx"

path= Server.MapPath("carpeta\")
path2= "copias\"

fso.CopyFile path & archivo, path & path2 & archivo2,true

<script language=javascript>
document.location.href= '<%=path2 & "/" & archivo2%>'
</script>

[dieguicho]

perfecto!
y como puedo hacer para borrarlo una vez que se descargó?
asi no queda todo duplicado pero con otro nombre.
si otra persona desea descargar el archivo que se haga todo el fso denuevo, no importa.

son todo tipo de archivos jpg, gif, doc, pdf, etc

gracias!

[u_goldman]

No se si habrá una manera en javascript de determinar si se terminó la descarga, lo que podrías hacer es en la ventana, poner una forma que capture el nuevo nombre del archivo y poner un botón de regresar, mándalo primero a un asp que borre el archivo fso.deletefile y después redireccionas...bueno, es lo que se me ocurre

Salu2,

[AlZuwaga]

Fijate este código.. puede servirte.
Originalmente está escrito para forzar la descarga de archivos, pero puede serte de utilidad


<%
'8***********************************************8
' Jason Withrow - For ASP101 July 2001
' This page forces the save as dialogue to prevent
' files from being opened in the browser.
'
' [email protected]
'8***********************************************8

Response.Buffer = True
Dim strFilePath, strFileSize, strFileName

Const adTypeBinary = 1

strFilePath = Request.QueryString("File")
strFileSize = Request.QueryString("Size")
strFileName = Request.QueryString("Name")

Response.Clear

'8*******************************8
' Requires MDAC 2.5 to be stable
' I recommend MDAC 2.6 or 2.7
'8*******************************8
Set objStream = Server.CreateObject("ADODB.Stream")
objStream.Open
objStream.Type = adTypeBinary
objStream.LoadFromFile Server.MapPath(strFilePath)

strFileType = lcase(Right(strFileName, 4))

' Feel Free to Add Your Own Content-Types Here
Select Case strFileType
Case ".asf"
ContentType = "video/x-ms-asf"
Case ".avi"
ContentType = "video/avi"
Case ".doc"
ContentType = "application/msword"
Case ".zip"
ContentType = "application/zip"
Case ".xls"
ContentType = "application/vnd.ms-excel"
Case ".gif"
ContentType = "image/gif"
Case ".jpg", "jpeg"
ContentType = "image/jpeg"
Case ".wav"
ContentType = "audio/wav"
Case ".mp3"
ContentType = "audio/mpeg3"
Case ".mpg", "mpeg"
ContentType = "video/mpeg"
Case ".rtf"
ContentType = "application/rtf"
Case ".htm", "html"
ContentType = "text/html"
Case ".asp"
ContentType = "text/asp"
Case Else
'Handle All Other Files
ContentType = "application/octet-stream"
End Select


Response.AddHeader "Content-Disposition", "attachment; filename=" & strFileName
Response.AddHeader "Content-Length", strFileSize
' In a Perfect World, Your Client would also have UTF-8 as the default
' In Their Browser
Response.Charset = "UTF-8"
Response.ContentType = ContentType

Response.BinaryWrite objStream.Read
Response.Flush

objStream.Close
Set objStream = Nothing
%>


Lo guardás como download.asp y los enlaces de los archivos a bajar los hacés así:

<a href="download.asp?File=archivo_a_bajar.doc&Name=<% = Session.SessionID %>.doc&Size=123456">Bajar archivo</a>

Dónde..
File es el nombre del archivo a bajar
Name es el nombre que le vas a dar al archivo
Size es opcional y es el tamaño que tiene para que el cuadrito de descarga del explorador pueda calcular la tasa de transferencia, tiempo restante, etc.

[dieguicho]

gracias!

[AlZuwaga]

de nada... pero sirvió?

[dieguicho]

clarooo
solo cambie esta linea
Response.AddHeader "Content-Disposition", "attachment; filename=" & strFileName

y le puse el nuevo nombre en strFileName