Animación gif en una aplicación

[WACF]

Como puedo insertar una imagen gif en visual basic 6.0

[pkj]

Para WACF

He encontrado esto:

----------
Se puede cargar el componente Microsoft Internet Controls. Luego ponerlo en pantalla e introducir este codigo en la forma

WebBrowser1.Navigate "C:\Internet\anim.gif"
-----------

Parece ser el unico modo sin usar una DLL externa.
Por lo visto hay una llamada Gif89.dll o algo asi y un ocx llamado marchoso, pero no los he buscado.

El problema es que no se ajusta al tamaño del gif. Debes cargar un gif del mismo tamaño que la ventana WebBrowser1 o apareceran barras de desplazamiento.

El caso es que si tu gif es un adorno y es pequeño te puede hacer el apaño.

Saludos

[David]

Bienvenido al foro.

Mensajes transladados a un nuevo tema desde:
http://www.forosdelweb.com/f69/puedo...-6-0-a-184878/

Saludos.

[pkj]

He encontrado otro método para hacerlo sin WebBrowser ni librerias externas, pero el resultado no es muy profesional.
Se extraen todos los fotogramas del gif, se crean tantos controles image como hagan falta y se cargan los fotogramas.
Con un Timer los vá mostrando/ocultando para simular la animación.
Problemas:
1 - Un parpadeo cuando acaba una secuencia y vuelve a empezar.
2 - Los gifs con transparencias o imágenes de diferentes tamaños no se reproducen bien.

Las pruebas que he hecho demuestran que, dependiendo del gif cargado, la visualización puede ser desde muy mala hasta perfecta, pasando por todas las demás calificaciones.

De momento os dejo esta versión que al menos funciona. La version original me daba error en alguna línea y haciendo lo mismo en 4 líneas no lo dá. Aún no lo he llegado a entender. ¡Ah! y le faltaba un End If a la sub del timer

He incluido los comentarios, si no del creador al menos de quien la publicó, en inglés y con traducción google para que mas o menos os entereis.

Hay que crear un formulario con 2 cosas:
Un control Image (Image1) CON EL VALOR INDEX = 0
osea una matriz de controles Image con el nombre Image1
Un Timer (Timer1)

Y como código ponemos esto:
NOTA: Del código solo hay que cambiar el camino y nombre del gif que quieres cargar.
NOTA2: No se me permite un mensaje tan largo. La Sub del Timer1 la pondré en otro mensaje a continuación.

Código :

Option Explicit
 
Dim NumberOfTimesToRepeatSequence As Long
Dim RepeatedCount As Long
Dim MaxCnt As Integer
Dim ImgCnt As Integer
 
Private Sub Form_Load()
On Error GoTo Form_LoadError
 
Image1(0).Left = 0
Image1(0).Top = 0
 
'place the path to the gif you want to animate here
'lugar de la ruta de acceso al GIF que desea animar aquí
Call DecodeGif("C:\FicheroGifAnimado.gif")
'PONER AQUI EL FICHERO GIF
 
Exit Sub
 
Form_LoadError:
MsgBox Err.Description
End Sub
 
Private Sub DecodeGif(PathToGifFile As String)
On Error GoTo DecodeGifError
 
'declare procedural variables
'Declarar variables de procedimiento
Dim FNumb As Integer
Dim GifBuffer As String
Dim GifHeader As String
Dim SectionStart As Long
Dim SectionEnd As Long
Dim SectionMarker As String
Dim ImageCount As Integer
Dim I As Integer
Dim NewPicBuff As String
Dim ImageHeader As String
Dim DisplayTime As Long
Dim LftOffSet As Long
Dim TopOffSet As Long
 
'make sure we have something to work with
'asegurarnos de que tenemos algo con que trabajar
If Dir(PathToGifFile) = vbNullString Then
  MsgBox "Dónde está el GIF!?"
  Exit Sub
End If
 
'disable timer
'temporizador desactivar
Timer1.Enabled = False
 
'if you were to change this demo so other gifs could be displayed in this array then you would need to unload all but the origional
'Si tuviera que cambiar esta demostración para que los gifs otras podrían ser mostradas en esta matriz, entonces usted tendría que descargar todos, pero el original
For I = 1 To Image1.Count - 1
  Unload Image1(I)
Next I
 
'set value(s)
'valor de referencia (s)
SectionMarker = Chr(0) & "!ù"
SectionStart = 1
 
'open our gif, read it in, close it out
'abrir nuestro gif, leído en, cerca de fuera
FNumb = FreeFile
Open PathToGifFile For Binary As #FNumb
GifBuffer = Input(FileLen(PathToGifFile), #FNumb)
Close #FNumb
 
'get where this (the header info) ends
'llegar a donde esta (la información de encabezado) termina
SectionEnd = InStr(SectionStart, GifBuffer, SectionMarker) + Len(SectionMarker) - 2
 
'retrieve the header
'recuperar la cabecera
GifHeader = Left(GifBuffer, SectionEnd)
 
'set where the next section starts at
'establecida en la siguiente sección se inicia en
SectionStart = SectionEnd + 2
 
'check the length of the header for extended information
'control de la longitud de la cabecera de información ampliada
If Len(GifHeader) > 127 Then
  NumberOfTimesToRepeatSequence = Asc(Mid(GifHeader, 127, 1))
  NumberOfTimesToRepeatSequence = NumberOfTimesToRepeatSequence * 256
  NumberOfTimesToRepeatSequence = NumberOfTimesToRepeatSequence + Asc(Mid(GifHeader, 126, 1))
Else
  NumberOfTimesToRepeatSequence = 0 'bucle infinito
End If
 
'now run through file an decode each frame
'ahora se ejecutan a través de un archivo de decodificar cada fotograma
Do While SectionEnd <> Len(SectionMarker)
 
'increase the count of images we have by 1
'aumentar el recuento de las imágenes que tenemos antes del 1 de
ImageCount = ImageCount + 1
 
'find out where the next section ends
'saber dónde termina la sección siguiente
SectionEnd = InStr(SectionStart, GifBuffer, SectionMarker) + Len(SectionMarker)
 
'check to make sure we have some information to use
'Asegúrese de que tenemos algo de información para uso
If SectionEnd > Len(SectionMarker) Then
 
  'create a single frame gif from this information
  'crear un gif solo cuadro de esta información
  NewPicBuff = GifHeader & Mid(GifBuffer, SectionStart - 1, SectionEnd - SectionStart)
  
  'now write it to file so we can use the load picture function on it
  'Ahora escribe a un archivo para que podamos usar la función de imagen de carga en ella
  FNumb = FreeFile
  Open App.Path & "\temp.gif" For Binary As #FNumb
  Put #FNumb, 1, NewPicBuff
  Close #FNumb
  
  'now extract some information about the file we just saved
  'ahora extraer alguna información sobre el archivo que acaba de guardar
  ImageHeader = Left(Mid(GifBuffer, SectionStart - 1, SectionEnd - SectionStart), 16)
  
  
  'now calcualte the time that the image we just saved is to be displayed
  'Ahora calcualte el momento en que la imagen que acaba de guardar se mostrará
  DisplayTime = Asc(Mid(ImageHeader, 5, 1))
  DisplayTime = DisplayTime * 256
  DisplayTime = DisplayTime + Asc(Mid(ImageHeader, 4, 1))
  DisplayTime = DisplayTime * 10
  
  'check to see if we have more than one image
  'verificación para ver si tenemos más de una imagen
  If ImageCount > 1 Then
  
    'retrieve offsets
    'Recuperar las compensaciones
    LftOffSet = Asc(Mid(ImageHeader, 10, 1))
    LftOffSet = LftOffSet * 256
    LftOffSet = LftOffSet + Asc(Mid(ImageHeader, 9, 1))
    TopOffSet = Asc(Mid(ImageHeader, 12, 1))
    TopOffSet = TopOffSet * 256
    TopOffSet = TopOffSet + Asc(Mid(ImageHeader, 11, 1))
    
    'load a new control and set its properties
    'carga un nuevo control y establecer sus propiedades
    Load Image1(ImageCount - 1)
    Image1(ImageCount - 1).ZOrder 0
    Image1(ImageCount - 1).Left = Image1(0).Left + (LftOffSet * 15)
    Image1(ImageCount - 1).Top = Image1(0).Top + (TopOffSet * 15)
    
  End If
  
  'set the amount of time that this frame of the gif image is to be displayed for and load the image
  'establecer la cantidad de tiempo que este marco de la imagen GIF es que se muestra a favor y cargar la imagen de
  Image1(ImageCount - 1).Tag = DisplayTime
  Image1(ImageCount - 1).Picture = LoadPicture(App.Path & "\temp.gif")
  
  'don't need it anymore so kill it
  'No lo necesitamos más y lo eliminamos
  Kill App.Path & "\temp.gif"
  
  SectionStart = SectionEnd
  
End If
 
Loop
 
If SectionStart < Len(GifBuffer) Then
 
  'create a single frame gif from this information
  'crear un gif solo cuadro de esta información
  NewPicBuff = GifHeader & Mid(GifBuffer, SectionStart - 1, Len(GifBuffer) - SectionStart)
  
  'now write it to file so we can use the load picture function on it
  'Ahora escribe a un archivo para que podamos usar la función de imagen de carga en ella
  FNumb = FreeFile
  Open App.Path & "\temp.gif" For Binary As #FNumb
  Put #FNumb, 1, NewPicBuff
  Close #FNumb
  
  'now extract some information about the file we just saved
  'ahora extraer alguna información sobre el archivo que acaba de guardar
  ImageHeader = Left(Mid(GifBuffer, SectionStart - 1, Len(GifBuffer) - SectionStart), 16)
  
  'now calcualte the time that the image we just saved is to be displayed
  'Ahora calcualte el momento en que la imagen que acaba de guardar se mostrará
  DisplayTime = Asc(Mid(ImageHeader, 5, 1))
  DisplayTime = DisplayTime * 256
  DisplayTime = DisplayTime + Asc(Mid(ImageHeader, 4, 1))
  DisplayTime = DisplayTime * 10
  
  'check to see if we have more than one image
  'verificación para ver si tenemos más de una imagen
  If ImageCount > 1 Then
  
    'retrieve offsets
    'Recuperar las compensaciones
    LftOffSet = Asc(Mid(ImageHeader, 10, 1))
    LftOffSet = LftOffSet * 256
    LftOffSet = LftOffSet + Asc(Mid(ImageHeader, 9, 1))
    TopOffSet = Asc(Mid(ImageHeader, 12, 1))
    TopOffSet = TopOffSet * 256
    TopOffSet = TopOffSet + Asc(Mid(ImageHeader, 11, 1))
    
    'load a new control and set its properties
    'carga un nuevo control y establecer sus propiedades
    Load Image1(ImageCount - 1)
    Image1(ImageCount - 1).ZOrder 0
    Image1(ImageCount - 1).Left = Image1(0).Left + (LftOffSet * 15)
    Image1(ImageCount - 1).Top = Image1(0).Top + (TopOffSet * 15)
  
  End If
  
  'set the amount of time that this frame of the gif image is to be displayed for and load the image
  'establecer la cantidad de tiempo que este marco de la imagen GIF es que se muestra a favor y cargar la imagen de
  Image1(ImageCount - 1).Tag = DisplayTime
  Image1(ImageCount - 1).Picture = LoadPicture(App.Path & "\temp.gif")
  
  'don't need it anymore so kill it
  'No lo necesitamos más y lo eliminamos
  Kill App.Path & "\temp.gif"
  
End If
 
'set our variables that we will use to keep track of which frame of the animation we are on
'conjunto nuestras variables que vamos a utilizar para hacer un seguimiento de qué fotograma de la animación que estamos en
ImgCnt = 0
MaxCnt = Image1.Count - 1
 
'set up the timer
'configurar el reloj
Timer1.Interval = CInt(Image1(0).Tag)
Timer1.Enabled = True
 
Exit Sub
DecodeGifError:
 
MsgBox Err.Description
 
End Sub
 

continuará...

[pkj]

Ahí vá la sub que faltaba...

Código :

Private Sub Timer1_Timer()
 
On Error GoTo Timer1_TimerError
 
'increment,show, and set the next timers interval
'incremento de, mostrar y ajustar el temporizador de intervalos siguiente
ImgCnt = ImgCnt + 1
Image1(ImgCnt).Visible = True
Timer1.Interval = CInt(Image1(ImgCnt).Tag)
 
'for gifs that have a moving animation each frame is offset from the first frame by some amount so you need to make sure that the old frame is not
'Gifs para que tengan una animación en movimiento cada cuadro se desplaza desde el primer fotograma de una cierta cantidad por lo que necesita para asegurarse de que el marco de edad no es
'shown because you would get one image overlaid on another (or in some cases next to each other).
'que se muestra porque se van a obtener una imagen superpuesta sobre otra (o en algunos casos junto a la otra).
If ImgCnt = 0 Then
 
  'for images with offsets you need to do this
  'para las imágenes con las compensaciones que tiene que hacer este
  Image1(MaxCnt).Visible = False
 
Else
 
  'for images with offsets you need to do this
  'para las imágenes con las compensaciones que tiene que hacer este
  Image1(ImgCnt - 1).Visible = False
  
  'check to see if we have reached the end of the animation
  'comprobar si hemos llegado al final de la animación
  If ImgCnt = MaxCnt Then
  
    'reset the counter to before the first element since the first thing we do when we enter this sub is to increment the element counter
    'restablecer el contador a antes del primer elemento ya que lo primero que hacemos cuando entramos en este subprograma es incrementar el contador de elemento
    ImgCnt = -1
    
    'this can be removed for continious play but since it was decoded above...
    'Esto se puede quitar para jugar, pero continuas desde que fue descifrado por encima de ...
    If NumberOfTimesToRepeatSequence = 0 Then
    
      DoEvents
  
    Else
  
      'increment the number of times this animation has played and then check to see if we have reached the limit and if we have then disable the timer
      'incrementar el número de veces que ha jugado esta animación y luego comprobar si hemos llegado al límite y si tenemos, entonces, desactivar el temporizador de
      RepeatedCount = RepeatedCount + 1
      If RepeatedCount > NumberOfTimesToRepeatSequence Then Timer1.Enabled = False
    
    End If
 
  End If
End If
Exit Sub
 
Timer1_TimerError:
MsgBox Err.Description
 
End Sub
 

Saludos by PKJ

[seba123neo]

mas o menos como este:

Reproducir un Gif animado sin utilizar un Ocx

saludos.

[pkj]

Voy a intentar explicar yo mismo el funcionamiento del código que mostré anteriormente, al menos lo que crea necesario, para quien no se aclare.

Como mi inglés es muy básico no puedo limitarme a traducirlo bién.

Para calentar comenzaré por el timer que es facilito. Para la sub más gorda necesitaré tiempo.

Código :

Private Sub Timer1_Timer()
 
On Error GoTo Timer1_TimerError
 
' imgcnt contiene el numero de index del control image que vamos a mostrar.
' cada vez que entramos en este timer se incrementa el contador
ImgCnt = ImgCnt + 1
'y así mostramos una imagen diferente a la actual
Image1(ImgCnt).Visible = True
' y fijamos el tiempo que se tiene que esperar antes de volver a entrar a este timer para mostrar otra imagen.
Timer1.Interval = CInt(Image1(ImgCnt).Tag)
 
' si es la primera imagen del gif
If ImgCnt = 0 Then
 
' ocultamos la ultima imagen de la matriz
  Image1(MaxCnt).Visible = False
 
' ahora se me ocurre: si solo hay una imagen [image(0)] en el gif ¿que sucedera? se ocultará siempre, ¿no?
' asi de primeras creo que se generará una animación con los images (0) y (1), y dará error al intentar mostrar image(1) si no existe. Si existe y está vacio o no da error solo notaremos quizá un parpadeo.
 
Else
 
  ' si no es la primera ocultamos la anterior
  Image1(ImgCnt - 1).Visible = False
  
  ' si hemos llegado a la última imagen del gif
  If ImgCnt = MaxCnt Then
  
    'restablecer el contador a antes del primer elemento ya que lo primero que hacemos cuando entramos en este subprograma es incrementar el contador de elemento
    ImgCnt = -1
  ' Nota: si miramos la sub DecodeGif veremos que hay un fallo, ya que se inicializa la variable ImgCnt con valor 0 en lugar de con valor -1, lo que hace que la primera vez que entramos al timer no se muestra la imagen 0, sino la imagen 1, saltandonos un fotograma.
    
    ' si este valor es 0 significa que se repite la animación indefinidamente
    If NumberOfTimesToRepeatSequence = 0 Then
      ' en ese caso se deja un poco de tiempo de proceso para refrescar la imagen y tal
      DoEvents
 
    Else
 
      ' si hay un límite de repeticiones se lleva la cuenta
      RepeatedCount = RepeatedCount + 1
      ' y si se supera se detiene el timer para finalizar la animación
      If RepeatedCount > NumberOfTimesToRepeatSequence Then Timer1.Enabled = False
    
    End If
 
  End If
End If
Exit Sub
 
Timer1_TimerError:
MsgBox Err.Description
 
End Sub
 

Saludos by PKJ

[pkj]

Nota: Esta explicación es en respuesta a una petición de un compañero del foro.
Como podéis imaginar hay muchas cosas que no he estudiado en profundidad y no podré explicar, como el formato interno de un fichero gif, pero intentaré dar una aproximación.

Código :

Option Explicit
Dim NumberOfTimesToRepeatSequence As Long
Dim RepeatedCount As Long
Dim MaxCnt As Integer
Dim ImgCnt As Integer
Private Sub Form_Load()
  On Error GoTo Form_LoadError
  Image1(0).Left = 0
  Image1(0).Top = 0
  'lugar de la ruta de acceso al GIF que desea animar aquí
  Call DecodeGif("C:\FicheroGifAnimado.gif")
  'PONER AQUI EL FICHERO GIF
  Exit Sub
Form_LoadError:
  MsgBox Err.Description
End Sub
 
Public Sub DecodeGif(PathToGifFile As String)
 
  ' si hay errores saltamos a la etiqueta DecodeGifError
  On Error GoTo DecodeGifError
  
  'Declaramos las variables
  Dim FNumb As Integer
  Dim GifBuffer As String
  Dim GifHeader As String
  Dim SectionStart As Long
  Dim SectionEnd As Long
  Dim SectionMarker As String
  Dim ImageCount As Integer
  Dim i As Integer
  Dim NewPicBuff As String
  Dim ImageHeader As String
  Dim DisplayTime As Long
  Dim LftOffSet As Long
  Dim TopOffSet As Long
  
  ' comprobamos básicamente si existe el fichero contenido en la variable PathToGifFile
  If Dir(PathToGifFile) = vbNullString Then
    MsgBox "Dónde está el GIF!?"
    ' si no lo encuentra salimos
    Exit Sub
  End If
  
  'detenemos el timer y cualquier animación que pueda estar en marcha
  Timer1.Enabled = False
  
  ' eliminamos las imágenes existentes por si ya hemos mostrado antes otra animación
  For i = 1 To Image1.Count - 1
    Unload Image1(i)
  Next i
  ' solo dejamos la imagen (0) como base para crear mas
  
  ' nos aseguramos de que el control image no va a cambiar de tamaño para adaptarse al tamaño de la imagen
  Image1(0).Stretch = False
  'set value(s)
  
  'valor de referencia (s)
  SectionMarker = Chr(0) & "!ù"
  ' Esto imagino que es algo técnico sobre el formato de un fichero gif.
  ' Posiblemente son caracteres que encontraremos precediendo a cada imagen o algo así.
 
  ' Puntero que iremos usando para guardar la posicion de comienzo de cada seccion con la que trabajemos
  SectionStart = 1
  
  ' el sistema nos dá un numero de fichero que no se está usando en otro open en este momento
  FNumb = FreeFile  ' <--- Esto es mejor que esto ---> FNumb = 1
 
  'abrimos el fichero gif
  Open PathToGifFile For Binary As #FNumb
 
  ' leemos todo el fichero y lo cargamos en un string llamado GifBuffer
  GifBuffer = Input(FileLen(PathToGifFile), #FNumb)
  ' y lo cerramos. 
  Close #FNumb
  
  ' Buscamos el final del encabezado del fichero gif usando los caracteres de sectionmarker
  SectionEnd = InStr(SectionStart, GifBuffer, SectionMarker) + Len(SectionMarker) - 2
  
  'guardamos esa parte del comienzo del gif (encabezado-header) que contendrá datos sobre el gif...
  GifHeader = Left(GifBuffer, SectionEnd)
 
  ' guardamos la posición de inicio de la primera imagen
  SectionStart = SectionEnd + 2
  
  'según la longitud del encabezado calculamos si el gif es continuo o se repite un numero limitado de veces
  If Len(GifHeader) > 127 Then
    ' si es mayor que 127 extraemos la cantidad de ciclos que se va a repetir con la formula:
    ' ((Numero ascii del caracter 127) * 256) + Numero ascii del caracter 126
    NumberOfTimesToRepeatSequence = Asc(Mid(GifHeader, 127, 1))
    NumberOfTimesToRepeatSequence = NumberOfTimesToRepeatSequence * 256
    NumberOfTimesToRepeatSequence = NumberOfTimesToRepeatSequence + Asc(Mid(GifHeader, 126, 1))
  Else
    ' si el encabezado no es mayor de 127 es que el gif se repite continuamente
    NumberOfTimesToRepeatSequence = 0 'bucle infinito
  End If
  
  
  ' aqui extraemos las imagenes
 
  ' esto no se como funciona exactamente pero hace un bucle mientras queden imagenes que extraer
  Do While SectionEnd <> Len(SectionMarker)
  
  'llevamos un contador de imagenes extraidas para crear los controles image
  ImageCount = ImageCount + 1
  
  'para saber dónde termina la sección
  SectionEnd = InStr(SectionStart, GifBuffer, SectionMarker) + Len(SectionMarker)
  
  'Nos aseguramos de que hay alguna imagen en el gif
  If SectionEnd > Len(SectionMarker) Then
  
    'capturamos el trozo marcado y lo precedemos con el encabezado del fichero Gif (imagino que para que mantenga el formato al guardarlo como imagen individual)
    NewPicBuff = GifHeader & Mid(GifBuffer, SectionStart - 1, SectionEnd - SectionStart)
    
    'Ahora se escribe la imagen a un archivo para poder cargarla como nosotros queremos hacerlo
    FNumb = FreeFile
    Open App.Path & "\temp.gif" For Binary As #FNumb
    Put #FNumb, 1, NewPicBuff
    Close #FNumb
    
    'ahora guardamos los 16 primeros caracteres de cada imagen que nos dirán su duración, etc
    ImageHeader = Left(Mid(GifBuffer, SectionStart - 1, SectionEnd - SectionStart), 16)
    
    'Ahora calculamos la duración de la imagen actual con una formula que usa el cuarto y el quinto de esos 16 caracteres guardados
    DisplayTime = Asc(Mid(ImageHeader, 5, 1))
    DisplayTime = DisplayTime * 256
    DisplayTime = DisplayTime + Asc(Mid(ImageHeader, 4, 1))
    DisplayTime = DisplayTime * 10
    
    ' si no es la primera imagen que guardamos...
    If ImageCount > 1 Then
 
      ' calculamos la posición de la nueva imagen dentro del formulario usando para ello los caracteres 9,10,11 y 12 de los 16 de la cabecera de la imagen.
      LftOffSet = Asc(Mid(ImageHeader, 10, 1))
      LftOffSet = LftOffSet * 256
      LftOffSet = LftOffSet + Asc(Mid(ImageHeader, 9, 1))
 
      TopOffSet = Asc(Mid(ImageHeader, 12, 1))
      TopOffSet = TopOffSet * 256
      TopOffSet = TopOffSet + Asc(Mid(ImageHeader, 11, 1))
 
      'carga un nuevo control image y establece sus propiedades
      Load Image1(ImageCount - 1)
 
      Image1(ImageCount - 1).ZOrder 0  ' zorder nunca he entendido como funciona (ni usado)
 
      Image1(ImageCount - 1).Left = Image1(0).Left + (LftOffSet * 15)
      Image1(ImageCount - 1).Top = Image1(0).Top + (TopOffSet * 15)
      
    End If
    
    ' Añado esto para evitar que se cuele un valor de interval no válido.
    If DisplayTime < 0 Then DisplayTime = 0
    If DisplayTime > 65535 Then DisplayTime = 65535
    ' creo que ya no es necesario pero al principio me pasaba y por seguridad lo dejo.
 
    
    'guardamos en la propiedad Tag el tiempo que debe mostrarse la imagen
    Image1(ImageCount - 1).Tag = DisplayTime
 
    ' cargamos la imagen que habíamos guardado en un fichero
    Image1(ImageCount - 1).Picture = LoadPicture(App.Path & "\temp.gif")
    
    'la imagen ya no hace falta y se elimina
    Kill App.Path & "\temp.gif"
    
    ' nos colocamos en posicion para comenzar con la siguiente imagen a cargar
    SectionStart = SectionEnd
    
  End If
  
  ' y asi tantas veces como imagenes haya
  Loop
 
  ' si aun quedan datos en el fichero creamos una última imagen con eso
  If SectionStart < Len(GifBuffer) Then
  
    NewPicBuff = GifHeader & Mid(GifBuffer, SectionStart - 1, Len(GifBuffer) - SectionStart)
    
    ' el proceso es igual que antes asi que quito comentarios.
 
    FNumb = FreeFile
    Open App.Path & "\temp.gif" For Binary As #FNumb
    Put #FNumb, 1, NewPicBuff
    Close #FNumb
    
    ImageHeader = Left(Mid(GifBuffer, SectionStart - 1, Len(GifBuffer) - SectionStart), 16)
    
    DisplayTime = Asc(Mid(ImageHeader, 5, 1))
    DisplayTime = DisplayTime * 256
    DisplayTime = DisplayTime + Asc(Mid(ImageHeader, 4, 1))
    DisplayTime = DisplayTime * 10
 
    If ImageCount > 1 Then
    
      LftOffSet = Asc(Mid(ImageHeader, 10, 1))
      LftOffSet = LftOffSet * 256
      LftOffSet = LftOffSet + Asc(Mid(ImageHeader, 9, 1))
 
      TopOffSet = Asc(Mid(ImageHeader, 12, 1))
      TopOffSet = TopOffSet * 256
      TopOffSet = TopOffSet + Asc(Mid(ImageHeader, 11, 1))
      
      Load Image1(ImageCount - 1)
      Image1(ImageCount - 1).ZOrder 0
      Image1(ImageCount - 1).Left = Image1(0).Left + (LftOffSet * 15)
      Image1(ImageCount - 1).Top = Image1(0).Top + (TopOffSet * 15)
    
    End If
    
    If DisplayTime < 0 Then DisplayTime = 0
    If DisplayTime > 65535 Then DisplayTime = 65535
    
    Image1(ImageCount - 1).Tag = DisplayTime
    Image1(ImageCount - 1).Picture = LoadPicture(App.Path & "\temp.gif")
    Kill App.Path & "\temp.gif"
    
  End If
  
  ' reiniciamos el contador de imagenes mostradas en el timer
  ImgCnt = -1
  ' y guardamos el numero de imagenes totales
  MaxCnt = Image1.Count - 1
    
  ' muestro ya la primera imagen
  Image1(0).Visible = True
  ' esto creo que tambien sobra.
  ' lo puse para que no se saltase la primera imagen pero creo que se arregló al poner ImgCnt = - 1
 
  'configurar el timer con la duración de la primera imagen
  Timer1.Interval = CInt(Image1(0).Tag)
  'y para finalizar activamos el timer para comenzar la animacion
  Timer1.Enabled = True
  Exit Sub
 
DecodeGifError:
  ' esto lo añadi para saltarme un error
  If Image1.Count > 0 And Err.Number = 50003 Then
    Unload Image1(Image1.Count - 1)
    ImageCount = ImageCount - 1
  Else
    MsgBox Err.Number & " - " & Err.Description
  End If
  Err.Clear
  
  ' Añado esto para extraer todos los
  ' fotogramas que pueda aun con un error
  Resume Next
End Sub
 

Creo que eso es todo.

Saludos